I wouldn't think so. The 6GK5 (mu=78) has a semi-remote characteristic, whereas the EC86 (mu=68) looks to be much more linear.Is EC86 close enough to 6GK5 to make simulations meaningful using the former model?
Code:
* ==============================================================
* 6GK5_GE3 LTSpice model
* Koren model (5 parameters) 0.557424mA
* Traced by Wayne Clay on 10-22-2017 using Curve Captor v0.9.1
* and Engauge Digtizer from General Electric data sheet
* ==============================================================
.subckt 6GK5 P G K
Bp P K I=
+ (0.1277399601m)*uramp(V(P,K)*ln(1.0+exp((2.811393856)+
+ (2.811393856)*(107.7001159)*V(G,K)/sqrt((5.955534246k)+
+ (V(P,K))**2)))/(2.811393856))**(1.103549843)
Cgp G P 0.72p ; 0.2p added (0.52pf)
Cgk G K 5.7p ; 0.7p added (5.0pf)
Cpk P K 3.7p ; 0.2p added (3.5pf)
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 6GK5
Code:
* ==============================================================
* EC86-mz LTSpice model
* Modified Koren model (8 parameters): mean fit error 0.194568mA
* Traced by Wayne Clay using Curve Captor v0.9.1 on 9/9/2007
* from Mazda Belvu data sheet
* ==============================================================
.subckt EC86 P G K
Bp P K I=
+ (0.05064528145m)*uramp(V(P,K)*ln(1.0+(0.0309350583)+exp((8.049679824)+
+ (8.049679824)*((64.91115818)+(-2065.708305m)*V(G,K))*V(G,K)/sqrt((27.86853425)**2+
+ (V(P,K)-(1.853045956))**2)))/(8.049679824))**(1.270936676)
Cgp G P 2.9p ; 0.7p added
Cgk G K 4.2p ; 0.7p added
Cpk P K 0.74p ; 0.5p added
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends EC86
Attachments
Somehow the Rpk line in the 6GK5 model turned up missing. Corrected below:
Code:
* ==============================================================
* 6GK5_GE3 LTSpice model
* Koren model (5 parameters) 0.557424mA
* Traced by Wayne Clay on 10-22-2017 using Curve Captor v0.9.1
* and Engauge Digtizer from General Electric data sheet
* ==============================================================
.subckt 6GK5 P G K
Bp P K I=
+ (0.1277399601m)*uramp(V(P,K)*ln(1.0+exp((2.811393856)+
+ (2.811393856)*(107.7001159)*V(G,K)/sqrt((5.955534246k)+
+ (V(P,K))**2)))/(2.811393856))**(1.103549843)
Cgp G P 0.72p ; 0.2p added (0.52pf)
Cgk G K 5.7p ; 0.7p added (5.0pf)
Cpk P K 3.7p ; 0.2p added (3.5pf)
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 6GK5
A couple of years ago, I was asking about a model for 12HL7. A couple of models were posted back then, and Ale M. (mogliaa) mentioned having created a triode model for that tube. Ale, if you're out there... I went to your site and couldn't find the 12HL7 spice model you created, or one of your great measurement blog entries for that type. Did you end up saving measurements from any of your 12HL7s?
--
--
These are what I have been using. Don't remember where I got them.
Code:
.subckt 6LU8P 1 2 3 4
+Params: MU=7.81 KP=27.3 KVB=21.4 EX=1.49 KG1=752
E1 7 0 Value = {(V(2,4)/KP)*LN((1+ EXP((KP/MU) + ((KP*(V(3,4)))/(V(2,4))))))}
RE1 7 0 1e12
G1 1 4 VALUE = {(((V(7))**EX)/KG1)*(1+SGN(V(7)))*(ATAN(V(1,4)/KVB))}
RCP 1 4 1e12
C1 3 4 16e-12
C2 1 3 0.5e-12
C3 1 4 9.0e-12
R1 3 5 1000
D3 5 4 dx
.model dx d(is=1e-09 rs=1 cjo=10e-12)
.ends
Code:
.subckt 6LU8T 1 2 3
+Params: MU=58 KP=800 KVB=4500 EX=1.23 KG1=430
E1 7 0 Value = {(V(1,3)/KP)*LN((1+ EXP((KP/MU) + ((KP*(V(2,3)))/(SQRT(KVB+V(1,3)*V(1,3)))))))}
RE1 7 0 1e12
G1 1 3 VALUE = {(((V(7))**EX)/KG1)*(1+SGN(V(7)))}
RCP 1 3 1e12
C1 2 3 7e-12
C2 1 2 6e-12
C3 1 3 2e-12
R1 2 5 2000
D3 5 3 dx
.model dx d(is=1e-09 rs=1 cjo=10e-12)
.ends
Thanks for this. The triode model's working fine, but when I use the pentode model, its screen grid does not draw any current at all.
Here's the .asy I'm using for it:
This is the slightly modified .subckt
Did I make a mistake in the .asy file?
--
Here's the .asy I'm using for it:
Code:
Version 4
SymbolType CELL
LINE Normal -48 0 -48 16
LINE Normal 48 0 48 16
LINE Normal 0 -48 0 -16
LINE Normal -20 -16 20 -16
LINE Normal -20 -12 20 -12
LINE Normal -20 -16 -20 -12
LINE Normal 20 -16 20 -12
LINE Normal 48 0 28 0
LINE Normal 20 0 12 0
LINE Normal 4 0 -4 0
LINE Normal -12 0 -20 0
LINE Normal -28 0 -36 0
LINE Normal -48 16 -28 16
LINE Normal -20 16 -12 16
LINE Normal -4 16 4 16
LINE Normal 12 16 20 16
LINE Normal 28 16 36 16
LINE Normal -24 28 24 28
LINE Normal -32 64 -32 36
LINE Normal -24 28 -32 36
LINE Normal 24 28 32 36
LINE Normal -28 32 28 32
ARC Normal -48 -48 48 48 48 0 -48 0
ARC Normal -48 -32 48 64 -48 16 48 16
WINDOW 0 8 -64 Left 0
WINDOW 3 -24 80 Left 0
SYMATTR Value 6LU8-Pentode
SYMATTR Prefix X
SYMATTR SpiceModel 6LU8-Pentode-Section_jnj.inc
SYMATTR Value2 6LU8-P
PIN 0 -48 NONE 0
PINATTR PinName 1
PINATTR SpiceOrder 1
PIN 48 0 NONE 0
PINATTR PinName 2
PINATTR SpiceOrder 2
PIN -48 16 NONE 0
PINATTR PinName 3
PINATTR SpiceOrder 3
PIN -32 64 NONE 0
PINATTR PinName 4
PINATTR SpiceOrder 4
This is the slightly modified .subckt
Code:
.subckt 6LU8-P 1 2 3 4
+Params: MU=7.81 KP=27.3 KVB=21.4 EX=1.49 KG1=752
E1 7 0 Value = {(V(2,4)/KP)*LN((1+ EXP((KP/MU) + ((KP*(V(3,4)))/(V(2,4))))))}
RE1 7 0 1e12
G1 1 4 VALUE = {(((V(7))**EX)/KG1)*(1+SGN(V(7)))*(ATAN(V(1,4)/KVB))}
RCP 1 4 1e12
C1 3 4 16e-12
C2 1 3 0.5e-12
C3 1 4 9.0e-12
R1 3 5 1000
D3 5 4 dx
.model dx d(is=1e-09 rs=1 cjo=10e-12)
.ends
Did I make a mistake in the .asy file?
--
6LU8 SPICE Models
Triode section:
Pentode section:
Triode section:
Code:
*
* Generic triode model: 6LU8_T_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Fri Aug 14 11:56:38 2015
* Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 6LU8_T_AN A G K
BGG GG 0 V=V(G,K)+0.57614785
BM1 M1 0 V=(0.0010281698*(URAMP(V(A,K))+1e-10))**-0.090049243
BM2 M2 0 V=(0.94336701*(URAMP(V(GG)+URAMP(V(A,K))/55.081359)+1e-10))**1.5900492
BP P 0 V=0.0025474492*(URAMP(V(GG)+URAMP(V(A,K))/58.388049)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0019774266*V(M1)*V(M2)
BIG IG 0 V=0.0012737246*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0013394485*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 6p
CGK G K 7p
CAK A K 2p
.ENDS
Pentode section:
Code:
*
* Generic pentode model: 6LU8_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Tue Aug 04 12:57:12 2015
* Plate
* | Screen Grid
* | | Control Grid
* | | | Cathode
* | | | |
.SUBCKT 6LU8_AN A G2 G1 K
BGG GG 0 V=V(G1,K)+0.63428724
BM1 M1 0 V=(0.1032017*(URAMP(V(G2,K))+1e-10))**-1.2066925
BM2 M2 0 V=(0.5541819*(URAMP(V(GG)+URAMP(V(G2,K))/4.3198716)))**2.7066925
BP P 0 V=0.0033285292*(URAMP(V(GG)+URAMP(V(G2,K))/7.7950427))**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.00255992*V(M1)*V(M2)
BIG IG 0 V=0.0016642646*URAMP(V(G1,K))**1.5*(URAMP(V(G1,K))/(URAMP(V(A,K))+URAMP(V(G1,K)))*1.2+0.4)
BIK2 IK2 0 V=V(IK,IG)*(1-0.4*(EXP(-URAMP(V(A,K))/URAMP(V(G2,K))*15)-EXP(-15)))
BIG2T IG2T 0 V=V(IK2)*(0.952525155*(1-URAMP(V(A,K))/(URAMP(V(A,K))+10))**1.5+0.047474845)
BIK3 IK3 0 V=V(IK2)*(URAMP(V(A,K))+911.25)/(URAMP(V(G2,K))+911.25)
BIK4 IK4 0 V=V(IK3)-URAMP(V(IK3)-(0.0023248963*(URAMP(V(A,K))+URAMP(URAMP(V(G2,K))-URAMP(V(A,K))))**1.5))
BIP IP 0 V=URAMP(V(IK4,IG2T)-URAMP(V(IK4,IG2T)-(0.0023248963*URAMP(V(A,K))**1.5)))
BIAK A K I=V(IP)+1e-10*V(A,K)
BIG2 G2 K I=URAMP(V(IK4,IP))
BIGK G1 K I=V(IG)
* CAPS
CGA G1 A 0.5p
CGK G1 K 9.6p
C12 G1 G2 6.4p
CAK A K 9p
.ENDS
Tube model paint tools developer has some updates, some improvement in pentode with the addition of knee, kink and other like slop (klam, klamg), you may want to download it to see how it compared with other models.
Code:
**** 6P3P ******************************************
* Created on 08/29/2018 08:14 using paint_kip.jar
* [url=http://www.dmitrynizh.com/tubeparams_image.htm]Model Paint Tools: Trace Tube Parameters over Plate Curves, Interactively[/url]
* Plate Curves image file: 6p3p.png
* Data source link: <plate curves URL>
*----------------------------------------------------------------------------------
.SUBCKT 6P3P P G2 G K ; LTSpice tetrode.asy pinout
* .SUBCKT 6P3P P G K G2 ; Koren Pentode Pspice pinout
+ PARAMS: MU=8.5 KG1=2706 KP=36.04 KVB=12.36 VCT=0.2 EX=1.512 KG2=8232 KNEE=34.08 KVC=1.722
+ KLAM=1.125E-7 KLAMG=2.1E-5 KNEE2=20 KNEX=30 KNK=-0.044 KNG=0.006 KNPL=50 KNSL=11 KNPR=120 KNSR=29
+ CCG=11P CGP=1.4P CCP=8.2P RGI=2000.0
* Vp_MAX=440 Ip_MAX=280 Vg_step=5 Vg_start=10 Vg_count=9
* X_MIN=76 Y_MIN=186 X_SIZE=925 Y_SIZE=582 FSZ_X=1550 FSZ_Y=878 XYGrid=false
* Rp=1400 Vg_ac=20 P_max=20 Vg_qui=-10 Vp_qui=300
* showLoadLine=n showIp=y isDHP=n isPP=n isAsymPP=n isUL=n showDissipLimit=y
* showIg1=n isInputSnapped=y addLocalNFB=n
* XYProjections=n harmonicPlot=y dissipPlot=n
* UL=0.43 EG2=250 gridLevel2=n addKink=y isTanhKnee=y advSigmoid=n
*----------------------------------------------------------------------------------
RE1 7 0 1G ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(G2,K)/KP*LOG(1+EXP((1/MU+(VCT+V(G,K))/SQRT(KVB+V(G2,K)*V(G2,K)))*KP))}
RE2 6 0 1G ; DUMMY SO NODE 6 HAS 2 CONNECTIONS
E2 6 0 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))} ; Kg1 times KIT current
RE21 21 0 1
E21 21 0 VALUE={V(6)/KG1*ATAN((V(P,K)+KNEX)/KNEE)*TANH(V(P,K)/KNEE2)} ; Ip with knee but no slope and no kink
RE22 22 0 1 ; E22: kink curr deviation for plate
E22 22 0 VALUE={V(21)*LIMIT(KNK-V(G,K)*KNG,0,0.3)*(-ATAN((V(P,K)-KNPL)/KNSL)+ATAN((V(P,K)-KNPR)/KNSR))}
G1 P K VALUE={V(21)*(1+KLAMG*V(P,K))+KLAM*V(P,K) + V(22)}
* Alexander Gurskii screen current, see audioXpress 2/2011, with slope and kink added
RE43 43 K 1G ; Dummy
E43 43 G2 VALUE={0} ; Dummy
G2 43 K VALUE={V(6)/KG2*(KVC-ATAN((V(P,K)+KNEX)/KNEE)*TANH(V(P,K)/KNEE2))/(1+KLAMG*V(P,K))-V(22)}
RCP P K 1G ; FOR CONVERGENCE
C1 K G {CCG} ; CATHODE-GRID 1
C2 G P {CGP} ; GRID 1-PLATE
C3 K P {CCP} ; CATHODE-PLATE
R1 G 5 {RGI} ; FOR GRID CURRENT
D3 5 K DX ; FOR GRID CURRENT }
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$
* The following triode model is derived from pentode model, see above.
* In the triode model, all spice parameters come directly from the pentode model, except for Kg1,
* which for triode-strapped pentodes is derived from pentode's Kg1, Kg2 and Kvc as
*
* 4Kg1Kg2 / ((2Kvc-Pi)(2Kg1+PiKg2))
**** 6P3P ******************************************
* Created on 08/29/2018 08:14 using paint_kit.jar 4.7
* [url=http://www.dmitrynizh.com/tubeparams_image.htm]Model Paint Tools: Trace Tube Parameters over Plate Curves, Interactively[/url]
* Plate Curves image file: 6p3p.png
* Data source link: <plate curves URL>
*----------------------------------------------------------------------------------
.SUBCKT TRIODE_6P3P 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=11P CGP=1.4P CCP=8.2P RGI=2000
+ MU=8.5 KG1=9428.01 KP=36.04 KVB=12.36 VCT=0.2 EX=1.512
* Vp_MAX=440 Ip_MAX=280 Vg_step=5 Vg_start=10 Vg_count=9
* Rp=1400 Vg_ac=20 P_max=20 Vg_qui=-10 Vp_qui=300
* X_MIN=76 Y_MIN=186 X_SIZE=925 Y_SIZE=582 FSZ_X=1550 FSZ_Y=878 XYGrid=false
* showLoadLine=n showIp=y isDHT=n isPP=n isAsymPP=n showDissipLimit=y
* showIg1=n gridLevel2=n isInputSnapped=y
* XYProjections=n harmonicPlot=y dissipPlot=n
*----------------------------------------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$
Attachments
Last edited:
Hello guys!
Does someone have spice model for nuvistor 8056?
MU 10.46193887
1/MU 0.095584577
EX 1.088364842
KG1 433.3436057
KP 27.37413414
KVB 22
8056 spice model
Code:
* ==============================================================
* 8056 LTSpice model
* Koren model (5 parameters): mean fit error 0.189674mA
* Traced by Wayne Clay on 09/10/2018 using Engauge Digigtizer and
* Curve Captor v0.9.1 from RCA data sheet
* ==============================================================
.subckt 8056 P G K
Bp P K I=(0.0008951966495m)*uramp(V(P,K)*ln(1.0+exp((0.001516064825)+
+ (0.001516064825)*(13903.64913)*V(G,K)/sqrt((0.03408042799k)+
+ (V(P,K))**2)))/(0.001516064825))**(1.053963307)
Cgp G P 2.3p ; 0.2p added (2.1p) Grid to plate
Cgk G K 4.2p ; 0.2p added (4.0p) Grid to cathode, shell and heater
Cpk P K 1.9p ; 0.2p added (1.7p) Plate to cathode, shell and heater
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 8056
Attachments
8056 Ayumi spice model
Code:
*
* Generic triode model: 8056_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Mon Sep 10 19:25:19 2018
* Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 8056_AN A G K
BGG GG 0 V=V(G,K)+0.61332946
BM1 M1 0 V=(0.43018255*(URAMP(V(A,K))+1e-10))**-7.6263159
BM2 M2 0 V=(0.16435986*(URAMP(V(GG)+URAMP(V(A,K))/1.9425245)+1e-10))**9.1263159
BP P 0 V=0.0035864859*(URAMP(V(GG)+URAMP(V(A,K))/11.818728)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*872.07303*V(M1)*V(M2)
BIG IG 0 V=0.001793243*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0022579266*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 2.1p
CGK G K 4p
CAK A K 1.7p
.ENDS
Attachments
- Home
- Amplifiers
- Tubes / Valves
- Vacuum Tube SPICE Models