Vacuum Tube SPICE Models

JoeAlders · 2016-12-22 8:35 pm

Looking for an LTspice model for the EL84 (6BQ5).
Any help?

rongon · 2016-12-22 8:53 pm

6BQ5 Ayumi model is in the 'pc tube' library, posted way back at the beginning of this thread.

http://www.diyaudio.com/forums/tubes-valves/243950-vacuum-tube-spice-models.html#post3662623

Please remember that if you re-post any of the Ayumi models, you should include the copyright information. These models are copyrighted by their author.

--

JoeAlders · 2016-12-22 9:05 pm

rongon said:
6BQ5 Ayumi model is in the 'pc tube' library, posted way back at the beginning of this thread.

http://www.diyaudio.com/forums/tubes-valves/243950-vacuum-tube-spice-models.html#post3662623

Please remember that if you re-post any of the Ayumi models, you should include the copyright information. These models are copyrighted by their author.

--

Thanks for your reply. Believe me I indeed plowed through all the pages here but must have overlooked it somewhere.
Leaves me with the question: Where can I download that library?

rongon · 2016-12-22 9:52 pm

You can download the library from Post #2, the one I linked in my previous post.
The file is in .zip format, you have to unpack it before you can use it.

cogsncogs · 2016-12-23 12:55 am

To use the Ayumi models in LTspice, you must change all instances of ^ to **.

JoeAlders · 2016-12-23 9:00 pm

rongon
"You can download the library from Post #2, the one I linked in my previous post.
The file is in .zip format, you have to unpack it before you can use it."

cogsncogs
"To use the Ayumi models in LTspice, you must change all instances of ^ to **. "

Many thanks guys for your help!

JoeAlders · 2016-12-26 3:35 pm

looking for a LTspice model for the Russian 6H13 (6N13).
Did not find it in one of the model libraries.

rongon · 2016-12-26 3:37 pm

How different is 6N13P from 6AS7G or 6080? I know there are 6AS7 and 6080 models available.

--

artosalo · 2016-12-26 6:50 pm

It is similar to 6AS7G model, but here it comes:

*$
*Eugene V. Karpov library
*For tube of manufacture in USSR
.SUBCKT 6N13S 1 2 3 ; P G C (Triode) 31-Agu-2002
+ PARAMS: MU= 2.35 EX= 1.247 KG1= 637.1 KP= 12.40
+ KVB=300.0 VCT=0.0 RGI=1k
+ CCG=8P CGP=10P CCP=3P
E1 7 0 VALUE=
+{V(1,3)/KP*LN(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID;
C2 2 1 {CGP} ; GRID-PLATE;
C3 1 3 {CCP} ; CATHODE-PLATE;
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

JoeAlders · 2016-12-26 9:06 pm

Thank you very much artosalo!!

EL8 · 2016-12-28 1:44 pm

jazbo8 said:
http://www.diyaudio.com/forums/tubes-valves/243950-vacuum-tube-spice-models-11.html#post3992239

What do you mean by "spice format"?

Dear jazbo8,
I am using the PSpice 8.0(student version),the library like as this format then working
*$
.SUBCKT EL34 1 2 3 4 ; P G1 C G2;
+ PARAMS: MU=11 EX=1.32 KG1=650 KG2=4200 KP=60 KVB=28
+ CCG=14P CPG1=.85P CCP=12P RGI=1k
RE1 7 0 1MEG ...............

thx!

jazbo8 · 2016-12-28 3:12 pm

EF50 PSpice Model

Code:

*
* Generic pentode model: EF50_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Tue Jul 15 13:48:26 2014
*               Plate
*               | Screen Grid
*               | |  Control Grid
*               | |  |  Cathode
*               | |  |  |
.SUBCKT EF50_AN A G2 G1 K
.param GG  {(V(G1,K)+0.075140135)}
.param EP  {URAMP(V(A,K))}
.param EG  {URAMP(V(G1,K))}
.param EG2 {URAMP(V(G2,K))}
.param M1  {((0.016755255*EG2)^-1.7905817)}
.param M2  {((0.45584646*URAMP(GG+EG2/32.476589))^3.2905817)}
.param P   {(0.0062465593*URAMP(GG+EG2/71.244579)^1.5)}
.param IK  {(U(GG)*P+(1-U(GG))*0.008577125*M1*M2)}
.param IG  {(0.0031232796*EG^1.5*(EG/(EP+EG)*1.2+0.4))}
.param IK2 {((IK-IG)*(1-0.4*(EXP(-EP/(EG2+1e-10)*15)-EXP(-15))))}
.param IG2T {(IK2*(0.62975016*(1-EP/(EP+10))^1.5+0.37024984))}
.param IK3 {(IK2*(EP+11000)/(EG2+11000))}
.param IK4 {(IK3-URAMP(IK3-(0.0032552566*(EP+URAMP(EG2-EP))^1.5)))}
.param IP  {URAMP(IK4-IG2T-URAMP(IK4-IG2T-(0.0032552566*EP^1.5)))}
BIAK A  K I=IP+1e-10*V(A,K)
BIG2 G2 K I=URAMP(IK4-IP)
BIGK G1 K I=IG
* CAPS
CGA G1 A  0.003p
CGK G1 K  6p
C12 G1 G2 4p
CAK A  K  5.3p
.ENDS

EL8 · 2016-12-29 8:35 am

Dear jazbo8,
Thanks for your support, the library cannot run on my PSpice 8.0,the error message as the attached.

Very interesting,only run on this format.....
.SUBCKT 6AU6_P 1 4 2 3
+ PARAMS: MU=39.3 EX=1.596 KG1=1340 KP=127 KVB=6.6 ; kg2=1000

jazbo8 · 2016-12-29 8:58 am

You need to change the URAMP function to LIMIT in PSpice. Perhaps some PSpice users can help, I am not too versed on the syntax used by PSpice.

EL8 · 2016-12-29 1:44 pm

Thanks !

cogsncogs · 2016-12-29 6:35 pm

This should work in PSpice:

Code:

*
* Generic pentode model: EF50_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Tue Jul 15 13:48:26 2014
*               Plate
*               | Screen Grid
*               | |  Control Grid
*               | |  |  Cathode
*               | |  |  |
.SUBCKT EF50_AN A G2 G1 K
EGG   GG   0 VALUE={V(G1,K)+0.075140135}
EM1   M1   0 VALUE={(0.016755255*(LIMIT(V(G2,K),0,1e16)+1e-10))**-1.7905817}
EM2   M2   0 VALUE={(0.45584646*(LIMIT((V(GG)+LIMIT(V(G2,K),0,1e16)/32.476589),0,1e16)))**3.2905817}
EP    P    0 VALUE={0.0062465593*(LIMIT((V(GG)+LIMIT(V(G2,K),0,1e16)/71.244579),0,1e16))**1.5}
EIK   IK   0 VALUE={STP(V(GG))*V(P)+(1-STP(V(GG)))*0.008577125*V(M1)*V(M2)}
EIG   IG   0 VALUE={0.0031232796*LIMIT(V(G1,K),0,1e16)**1.5*(LIMIT(V(G1,K),0,1e16)/(LIMIT(V(A,K),0,1e16)+LIMIT(V(G1,K),0,1e16))*1.2+0.4)}
EIK2  IK2  0 VALUE={V(IK,IG)*(1-0.4*(EXP(-LIMIT(V(A,K),0,1e16)/LIMIT(V(G2,K),0,1e16)*15)-EXP(-15)))}
EIG2T IG2T 0 VALUE={V(IK2)*(0.62975016*(1-LIMIT(V(A,K),0,1e16)/(LIMIT(V(A,K),0,1e16)+10))**1.5+0.37024984)}
EIK3  IK3  0 VALUE={V(IK2)*(LIMIT(V(A,K),0,1e16)+11000)/(LIMIT(V(G2,K),0,1e16)+11000)}
EIK4  IK4  0 VALUE={V(IK3)-LIMIT(V(IK3)-(0.0032552566*(LIMIT(V(A,K),0,1e16)+LIMIT(LIMIT(V(G2,K),0,1e16)-LIMIT(V(A,K),0,1e16),0,1e16))**1.5),0,1e16)}
EIP   IP   0 VALUE={LIMIT(V(IK4,IG2T)-LIMIT(V(IK4,IG2T)-(0.0032552566*LIMIT(V(A,K),0,1e16)**1.5),0,1e16),0,1e16)}
GIAK  A    K VALUE={V(IP)+1e-10*V(A,K)}
GIG2  G2   K VALUE={LIMIT(V(IK4,IP),0,1e16)}
GIGK  G1   K VALUE={V(IG)}
* CAPS
CGA   G1  A  0.003p
CGK   G1  K  6p
C12   G1  G2 4p
CAK   A   K  5.3p
.ENDS

EL8 · 2016-12-30 7:18 am

cogsncogs said:
This should work in PSpice:

Dear cogsncogs, Thanks for your support, the lib still shown the errors as below

jazbo8 · 2016-12-30 8:15 am

Try this one, we will get it eventually...

Code:

*
* Generic pentode model: EF50_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Tue Jul 15 13:48:26 2014
*               Plate
*               | Screen Grid
*               | |  Control Grid
*               | |  |  Cathode
*               | |  |  |
.SUBCKT EF50_AN A G2 G1 K
.param   GG   0 V=V(G1,K)+0.075140135
.param   M1   0 V=(0.016755255*(LIMIT(V(G2,K),0,1e16)+1e-10))**-1.7905817
.param   M2   0 V=(0.45584646*(LIMIT(V(GG)+LIMIT(V(G2,K),0,1e16)/32.476589,0,1e16)))**3.2905817
.param    P    0 V=0.0062465593*(LIMIT(V(GG)+LIMIT(V(G2,K),0,1e16)/71.244579,0,1e16))**1.5
.param   IK   0 V=IF(V(GG)>0,1,0)*V(P)+(1-IF(V(GG)>0,1,0))*0.008577125*V(M1)*V(M2)
.param   IG   0 V=0.0031232796*LIMIT(V(G1,K),0,1e16)**1.5*(LIMIT(V(G1,K),0,1e16)/(LIMIT(V(A,K),0,1e16)+LIMIT(V(G1,K),0,1e16))*1.2+0.4)
.param  IK2  0 V=V(IK,IG)*(1-0.4*(EXP(-LIMIT(V(A,K),0,1e16)/LIMIT(V(G2,K),0,1e16)*15)-EXP(-15)))
.param IG2T 0 V=V(IK2)*(0.62975016*(1-LIMIT(V(A,K),0,1e16)/(LIMIT(V(A,K),0,1e16)+10))**1.5+0.37024984)
.param  IK3  0 V=V(IK2)*(LIMIT(V(A,K),0,1e16)+11000)/(LIMIT(V(G2,K),0,1e16)+11000)
.param  IK4  0 V=V(IK3)-LIMIT(V(IK3)-(0.0032552566*(LIMIT(V(A,K),0,1e16)+LIMIT(V(G2,K),0,1e16)-LIMIT(V(A,K),0,1e16))**1.5),0,1e16)
.param   IP   0 V=LIMIT(V(IK4,IG2T)-LIMIT(V(IK4,IG2T)-(0.0032552566*LIMIT(V(A,K),0,1e16)**1.5),0,1e16),0,1e16)
BIAK  A    K I=V(IP)+1e-10*V(A,K)
BIG2  G2   K I=LIMIT(V(IK4,IP),0,1e16)
BIGK  G1   K I=V(IG)
* CAPS
CGA   G1  A  0.003p
CGK   G1  K  6p
C12   G1  G2 4p
CAK   A   K  5.3p
.ENDS

EL8 · 2016-12-30 10:29 am

Thanks.

cogsncogs · 2016-12-31 5:32 am

May be a floating point error...
In the model I posted (post 1276) try replacing this line:

Code:

EM1   M1   0 VALUE={(0.016755255*(LIMIT(V(G2,K),0,1e16)+1e-10))**-1.7905817}

with this to see if it will converge:

Code:

EM1   M1   0 VALUE={(0.016755255*(LIMIT(V(G2,K),0,1e16)+1e-03))**-1.7905817}

Vacuum Tube SPICE Models

Member

Member

Member

Member

Member

Member

Member

Member

Member

Member

Member

Ex-Moderator

Member

Ex-Moderator

Member

Member

Member

Attachments

Ex-Moderator

Member

Attachments

Member