• WARNING: Tube/Valve amplifiers use potentially LETHAL HIGH VOLTAGES.
    Building, troubleshooting and testing of these amplifiers should only be
    performed by someone who is thoroughly familiar with
    the safety precautions around high voltages.

Vacuum Tube SPICE Models

Hi all,

here the E82CC according the Philips data sheet, freshly cooked with my i5 model.
The i5 offers an improved convergence performance.

BR Adrian

PS: Note that the Philips E82CC is a long plate construction (plate length is approx. 15mm). Other E82CC/ECC82/12AU7 constructions (short plate) may behave quite different in terms of Ig and also regarding Ia at high Va values (island effect).

Code:
*E82CC LTspice model based on the generic triode model from Adrian Immler, version i5
*A version log is at the end of this file
*Params fitted to the Philips datasheet by Adrian Immler, Nov. 2021
*The high fit quality is presented at adrianimmler.simplesite.com
*History's best of tube decribing art (plus some new ideas) is merged to this new approach.
*@ neg. Vg, Ia accuracy is similar to Koren models, and unrivaled for remote cutoff triodes
*@ small neg. Vg, the "Anlauf" current is considered.
*@ pos. Vg, Ig and Ia accuracy is on a unrivaled level (including neg. Va range!)
*This offers new simulation possibilities like grid resistor bias, backward plate modulated stages,
*Audion radio circuits, low voltage amps, guitar distortion stages or pulsed stages.
*             PH=electrode construction used by Philips (approx. 15mm plate length)
*             |    anode (plate)
*             |    | grid
*             |    | | cathode
*             |    | | |
.subckt E82CC.PHi5 A G K
+ params:
*Parameters for space charge current Is (100% assigned to Ia @ Vg < 0)
+ mu   = 20.22 ;Determines the voltage gain @ constant Ia
+ rad  = 5k5   ;Differential anode resistance, set @ Iad and Vg=0V
+ Vct  = 0.55  ;Offsets the Ia-traces on the Va axis. Electrode material's contact potential
+ kp   = 75.9  ;Mimics the island effect
+ xs   = 1.5   ;Determines the curve of the Ia traces. Typically between 1.2 and 1.8
+ kIsr = 3m    ;Va-indepedent part of the Is reduction when gridcurrent occurs
+ kvdg  = 400  ;Va-depedent part of the Is reduction when gridcurrent occurs
*
*Parameters for assigning the space charge current to Ia and Ig @ Vg > 0
+ kB   = 0.28  ;Describes how fast Ia drops to zero when Va approaches zero.
+ radl = 480   ;Differential resistance for the Ia emission limit @ very small Va and Vg > 0
+ tsh  = 10    ;Ia transmission sharpness from 1th to 2nd Ia area. Keep between 3 and 20. Start with 20.
+ xl   = 1.2   ;Exponent for the emission limit
*
*Parameters of the grid-cathode vacuum diode
+ kg = 5k6     ;Inverse scaling factor for the Va independent part of Ig (caution - interacts with xg!)
+ Vctg = 0.7   ;Offsets the log Ig-traces on the Vg axis. Electrode material's contact potential
+ xg   = 1.65  ;Determines the curve of the Ig slope versus (positive) Vg and Va >> 0
+ VT   = 0.1   ;Log(Ig) slope @ Vg<0. VT=k/q*Tk (cathodes absolute temp, typically 1150K)
+ rTr  = 0.8   ;ratio of VT for Igr. Typically 0.8
+ kVT=0        ;Va dependant koeff. of VT
+ gft1 = 0     ;reduces the steering voltage around Vg=-Vg0, for finetuning purposes
+ gft1a= 0     ;reduces the steering voltage around Vg=-Vg=. Effect decreases with 1/(1+kB*Va)
+ gft2 = 0     ;finetunes the Igr drop @ incrasing Va and around Vg=-Vg0
*
*Parameters for the caps
+ cag  = 1p5   ;From datasheet
+ cak  = 0p5   ;From datasheet
+ cgk  = 1p6   ;From datasheet
*
*special purpose parameters
+ os = 1       ;Overall scaling factor, if a user wishes to simulate manufacturing tolerances
+ murc = 10    ;Mu of the remote cutoff triode
+ ksrc = 10G   ;Inverse Iarc gain factor for the remote cuttoff triode
+ kprc = 1k    ;Mimics the island effect for the remote cotoff triode
+ Vbatt = 0    ;heater battery voltage for direct heated battery triodes

+ Vdrmax = 100 ;max voltage of internal Vg drop, for convergence improvements
*
*Calculated parameters
+ Iad = {100/rad} ;Ia where the anode a.c. resistance is set according to rad.
+ ks = {pow(mu/(rad*xs*Iad**(1-1/xs)),-xs)} ;Reduces the unwished xs influence to the Ia slope
+ ksnom = {pow(mu/(rad*1.5*Iad**(1-1/1.5)),-1.5)} ;Sub-equation for calculating Vg0
+ Vg0 = {Vct + (Iad*ks)**(1/xs) - (Iad*ksnom)**(2/3)} ;Reduces the xs influence to Vct.
+ kl = {pow(1/(radl*xl*Ild**(1-1/xl)),-xl)} ;Reduces the xl influence to the Ia slope @ small Va
+ Ild = {sqrt(radl)*1m} ;Current where the Il a.c. resistance is set according to radl.
*
*Space charge current model
Rak A K 100G ;avoids "floating net" errors
Bft   ft 0 V=1/(1+pow(2*abs(v(G,Ki)+Vg0),3)) ;an auxiliary voltage to finetune the triode around Vg=-Vg0
Bggi GGi 0 V=(v(Gi,Ki)+Vg0)*(1/(1+kIsr*max(0, v(G,Ki)+Vg0))) - gft1*v(ft) - gft1a*v(ft)/(1+kB*v(Ahc)) ;Effective internal grid voltage.
Bahc Ahc 0 V=uramp(v(A,Ki)) ;Anode voltage, hard cut to zero @ neg. value
Bst   St 0 V=uramp(max(v(GGi)+v(A,Ki)/(mu), v(A,Ki)/kp*ln(1+exp(kp*(1/mu+v(GGi)/(1+v(Ahc)))))));Steering volt.
Bs    Ai Ki I=os/ks*pow(v(St),xs) ;Langmuir-Childs law for the space charge current Is
*Bstrc Strc 0 V=uramp(max(v(GGi)+v(Ahc)/(murc), v(Ahc)/kprc*ln(1+exp(kprc*(1/murc+v(GGi)/(1+v(Ahc)))))));FOR REMOTE CUTOFF TUBES ONLY
*Bsrc   Ai Ki I=os/ksrc*pow(v(Strc),xs) ;FOR REMOTE CUTOFF TUBES ONLY
*
*Anode current limit @ small Va
.func smin(z,y,k) {pow(pow(z+1f, -k)+pow(y+1f, -k), -1/k)} ;Min-function with smooth trans.
.func ssmin(z,y,k) {min(min(z,y), smin(z*1.003,y*1.003,k))};smin-function which suppresses small residual differencies
Ra  A Ai 1
Bgl Gi A I=uramp(i(Ra)-ssmin(1/kl*pow(v(Ahc),xl),i(Ra),tsh)) ;Ia emission limit
*
*Grid model
Rgk G K 10G ;avoids "floating net" errors
Bvdg G Gi I=1/kvdg*pow(v(G,Gi),1.5) ;Reduces the internal effective grid voltage when Ig rises
Bcoh G Gi I=pow(uramp(v(G,Gi)-Vdrmax),2) ;A convergence help which softly limits the internal Vg voltage drop.
Rgip G Gi 1G ;avoids some warnings
.func fVT() {VT*exp(-kVT*sqrt(v(A,Ki)))}
.func Ivd(Vvd, kvd, xvd, VTvd)  {if(Vvd < 3, 1/kvd*pow(VTvd*xvd*ln(1+exp(Vvd/VTvd/xvd)),xvd), 1/kvd*pow(Vvd, xvd))} ;Vacuum diode function
Bgvd G Ki I=Ivd(v(G,Ki) + Vctg + min(0,v(A,Ki)/mu), kg/os, xg, fVT()) ;limits the internal Vg for convergence reasons
Bstn Stn 0 V=v(GGi)+min(0,v(A,Ki))/mu ;special steering voltage, sensitive to negative Anodevoltages only
Bgr Gi Ai I= ivd(v(Stn),ks/os, xs, rTr*fVT())/(1+(kB+v(ft)*gft2)*v(Ahc));Is reflection to grid when Va approaches zero
*Bgr Gi Ai I=(ivd(v(Stn),ks/os, xs, rTr*fVT())+os/ksrc*pow(v(GGi),xs))/(1+(kB+v(ft)*gft2)*v(Ahc));FOR REMOTE CUTOFF TUBES ONLY
Bs0 Ai Ki  I=uramp(ivd(v(Stn),ks/os, xs, rTr*fVT()) - os/ks*pow(v(Stn),xs))
Bbatt Ki K V=Vbatt/2 ;for battery heated triodes; Offsets the average cathode potential to the half heater battery voltage
*
*Caps
C1 A G {cag}
C2 A K {cak}
C3 G K {cgk}
.ends
*
*Version log
*i1 :Initial version
*i2 :Pin order changed to the more common order A G K (Thanks to Markus Gyger for his tip)
*i3 :bugfix of the Ivd-function: now also usable for larger Vvd
*i4: Rgi replaced by a virtual vacuum diode (better convergence). ft1 deleted (no longer needed)
;2 new prarams for Ig finetuning @ Va and Vg near zero. New overall skaling factor os for aging etc.
*i5: improved convergence performance. PosVg/NegVa area now correct. Also accurate now for remote cutoff triodes!
 

Attachments

  • fit_E82CC.PHi5.jpg
    fit_E82CC.PHi5.jpg
    577.5 KB · Views: 139
Last edited:

Koonw

Member
2013-04-09 9:37 pm
Vg2 should be 125V, see datasheet. Need to adjust screen current. Set the Ia to 125mA, move the top axis down to 125mA, adjust KG2 and KVC to coincide with dotted curve. Turn Knee/Slope and Kink for fine adjustment. Be patient it's very tough for beginner, so feel free to pull the slider to see what it does. You can rebuild the model by copy and paste into PaintKit.



Code:
*** 6JR6 ******************************************
* Created on 12/02/2021 19:27 using paint_kip.jar
* [url=http://www.dmitrynizh.com/tubeparams_image.htm]Model Paint Tools: Trace Tube Parameters over Plate Curves, Interactively[/url]
* Plate Curves image file: 6jr6.png
* Data source link: <plate curves URL>
*----------------------------------------------------------------------------------
.SUBCKT 6JR6 P G2 G K ; LTSpice tetrode.asy pinout
* .SUBCKT 6JR6 P G K G2 ; Koren Pentode Pspice pinout
+ PARAMS: MU=5.28 KG1=1316.68 KP=11.65 KVB=13.44 VCT=-8.081 EX=1.824 KG2=777.87 KNEE=1.539 KVC=1.613
+ KLAM=2.187E-11 KLAMG=7.191E-4 KNEE2=17.46 KNEX=230.21  KNK=2.25E-4 KNG=-110.54 KNPL=1.286E-5 KNSL=0.000945 KNPR=0.007125 KNSR=907.92
+ CCG=22P CGP=0.7P CCP=9P VGOFF=-0.6 IGA=0.001 IGB=0.3 IGC=8 IGEX=2
* Vp_MAX=500 Ip_MAX=600 Vg_step=10 Vg_start=0 Vg_count=15
* X_MIN=46 Y_MIN=48 X_SIZE=733 Y_SIZE=490 FSZ_X=1296 FSZ_Y=736 XYGrid=false
* Rp=1400 Vg_ac=20 P_max=17 Vg_qui=-70 Vp_qui=300 
* showLoadLine=n showIp=y isDHP=n isPP=n isAsymPP=n isUL=n showDissipLimit=y 
* showIg1=y isInputSnapped=y addLocalNFB=n
* XYProjections=n harmonicPlot=y dissipPlot=n 
* UL=0.43 EG2=125 gridLevel2=y addKink=y isTanhKnee=y advSigmoid=n 
*----------------------------------------------------------------------------------
RE1  7 0  1G    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(G2,K)/KP*LOG(1+EXP((1/MU+(VCT+V(G,K))/SQRT(KVB+V(G2,K)*V(G2,K)))*KP))}
RE2  6 0  1G    ; DUMMY SO NODE 6 HAS 2 CONNECTIONS
E2  6 0  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))} ; Kg1 times KIT current
RE21 21 0 1
E21  21 0 VALUE={V(6)/KG1*ATAN((V(P,K)+KNEX)/KNEE)*TANH(V(P,K)/KNEE2)} ; Ip with knee but no slope and no kink
RE22 22 0 1 ; E22: kink curr deviation for plate
E22  22 0 VALUE={V(21)*LIMIT(KNK-V(G,K)*KNG,0,0.3)*(-ATAN((V(P,K)-KNPL)/KNSL)+ATAN((V(P,K)-KNPR)/KNSR))} 
G1   P  K  VALUE={V(21)*(1+KLAMG*V(P,K))+KLAM*V(P,K) + V(22)}
* Alexander Gurskii screen current, see audioXpress 2/2011, with slope and kink added
RE43 43 K 1G ; Dummy
E43  43 G2 VALUE={0} ; Dummy
G2   43 K  VALUE={V(6)/KG2*(KVC-ATAN((V(P,K)+KNEX)/KNEE)*TANH(V(P,K)/KNEE2))/(1+KLAMG*V(P,K))-V(22)}
RCP  P K  1G     ; FOR CONVERGENCE
C1   K G  {CCG}  ; CATHODE-GRID 1
C2   G P  {CGP}  ; GRID 1-PLATE
C3   K P  {CCP}  ; CATHODE-PLATE
RE23 G 0 1G 
GG G K VALUE={(IGA+IGB/(IGC+V(P,K)))*(MU/KG1)*
+(PWR(V(G,K)-VGOFF,IGEX)+PWRS(V(G,K)-VGOFF,IGEX))}
.ENDS
*$
 

Attachments

  • 6jr6 paint.jpg
    6jr6 paint.jpg
    407.8 KB · Views: 113
@ cogsncogs & rongon: Thank you, you are welcome!:D

@ Zoran, I guess it is just a question of some small code modifications as it was two years ago to get it compatible for Mirco-Cap.
I shortly googled, there seems to be a free (but limited) Spice version available. I will install it and try to get the i5 running. But that will take some days.

cheers, Adrian
 
Hi probably it is posibile to convert model to PSpice. But it will take to replace some charakters in the script? For instance this is PSpice model of 101D triode.
*
.SUBCKT 101D 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=4.4P CGP=6.4P CCP=2.9P RGI=2000
+ MU=6.24 KG1=9965.8 KP=91.08 KVB=300 VCT=-0.75 EX=1.519
*----------------------------------------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS 101D
*$
*
It starts with 1 2 3 corresponding to P G C. But in Your model numbers are used in script as node-point? I think that first is to exchange A G K with 1 2 3. Then to replace in the script all "doubled" numbers with other nubers?
.
I will try and report.
 

Attachments

  • 101D parameters.png
    101D parameters.png
    361.9 KB · Views: 69
Hi probably it is posibile to convert model to PSpice. But it will take to replace some charakters in the script? For instance this is PSpice model of 101D triode.
(...)
It starts with 1 2 3 corresponding to P G C. But in Your model numbers are used in script as node-point? I think that first is to exchange A G K with 1 2 3. Then to replace in the script all "doubled" numbers with other nubers?
.
I will try and report.

Hi Zoran
I'm in doubt whether Pspice (which is a well established spice simulator) really doesn't support netnames other than numbers. I guess this was only the case for the very original Berkley spice language (if even).
The typical differences in spice dialects are in variants of mathematical terms, like POW(Num, exponent) = Num**exponent and the like.
If any spice code is not understood from Pspice, there will for sure an error message pop up, giving you a hint in which spice line (or even in which mathematical term) the problem is.

This minutes, I tried to get a students (node limited) Pspice Version, but failed because OrCAD wants to see an evidence that I'm a student (which is a loooong time ago when it was true). So, I'm sorry but I can't support you with a Pspice compatible i5 Version... :xeye:

A way would be that you provide me the error messages, but that would be quite inefficient.

Perhaps someone else can translate the relevant spice code terms?

All the best, Adrian
 

Koonw

Member
2013-04-09 9:37 pm
How do you use Ayumi's SPICE model in PSpice?


12at7 Pspice/LTspice compared:


Pspice:

*
* Generic triode model: 12AT7
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sat Mar 8 22:41:07 2008
* Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 12AT7_AN A G K
EGG GG 0 VALUE={V(G,K)+0.67585931}
EM1 M1 0 VALUE={(0.015420581*(MAX(0,(V(A,K)))+1e-10))^-1.768756}
EM2 M2 0 VALUE={(0.45889017*(MAX(0,(V(GG))+MAX(0,(V(A,K)))/35.090106)+1e-10))^3.268756}
EP P 0 VALUE={0.0031809222*(MAX(0,(V(GG))+MAX(0,(V(A,K)))/76.46733)+1e-10)^1.5}
EIK IK 0 VALUE={STP(V(GG))*V(P)+(1-STP(V(GG)))*0.0042575005*V(M1)*V(M2)}
EIG IG 0 VALUE={0.0015904611*MAX(0,(V(G,K)))^1.5*(MAX(0,(V(G,K)))/(MAX(0,(V(A,K)))+MAX(0,(V(G,K))))*1.2+0.4)}
GIAK A K VALUE={MAX(0,(V(IK,IG))-MAX(0,(V(IK,IG))-(0.0016530623*MAX(0,(V(A,K)))^1.5))+1e-10*V(A,K))}
GIGK G K VALUE={V(IG)}
* CAPS
CGA G A 1.5p
CGK G K 2.2p
CAK A K 0.5p
.ENDS



LTSpice:

* Generic triode model: 12AT7
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sat Mar 8 22:41:07 2008
* Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 12AT7 A G K
BGG GG 0 V=V(G,K)+0.67585931
BM1 M1 0 V=(0.015420581*(URAMP(V(A,K))+1e-10))**-1.768756
BM2 M2 0 V=(0.45889017*(URAMP(V(GG)+URAMP(V(A,K))/35.090106)+1e-10))**3.268756
BP P 0 V=0.0031809222*(URAMP(V(GG)+URAMP(V(A,K))/76.46733)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0042575005*V(M1)*V(M2)
BIG IG 0 V=0.0015904611*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0016530623*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 1.5p
CGK G K 2.2p
CAK A K 0.5p
.ENDS
 

Koonw

Member
2013-04-09 9:37 pm
This is LTSpice model for 6F12P modeled by PaintKit, I believe it's in Pspice syntax already adopted from Koren model developed in PSpice and can be used in Micro-cap (which is PSpice compatiable), by following the import procedures without any change of model codes or syntax.


Code:
**** 6F12P_NEW **************************5****************
* Created on 10/19/2021 13:43 using paint_kip.jar
* [url=http://www.dmitrynizh.com/tubeparams_image.htm]Model Paint Tools: Trace Tube Parameters over Plate Curves, Interactively[/url]
* Plate Curves image file: 6f12p-new.png
* Data source link: <plate curves URL>
*----------------------------------------------------------------------------------
.SUBCKT 6F12P P G2 G K ; LTSpice tetrode.asy pinout
* .SUBCKT 6F12P P G K G2 ; Koren Pentode Pspice pinout
+ PARAMS: MU=87.23 KG1=239.95 KP=481.14 KVB=432.8 VCT=0.2871 EX=1.297 KG2=145.63 KNEE=168.15 KVC=1.726
+ KLAM=1.863E-10 KLAMG=5.733E-6  KD=31.03 KC=0.1211 KR1=5.46E-4 KR2=0.02944 KVBG=0.0012 KB1=2.32 KB2=0.11 KB3=2.02 KB4=0.82 KVBGI=0.00416 KNK=0 KNG=0 KNPL=50 KNSL=11 KNPR=120 KNSR=29
+ CCG=6.6P CGP=1.4P CCP=1.9P VGOFF=-0.6 IGA=8.7E-4 IGB=0.129 IGC=6.72 IGEX=2.8
* Vp_MAX=320 Ip_MAX=35 Vg_step=0.5 Vg_start=1 Vg_count=11
* X_MIN=49 Y_MIN=100 X_SIZE=632 Y_SIZE=541 FSZ_X=1296 FSZ_Y=736 XYGrid=false
* Rp=1400 Vg_ac=20 P_max=5 Vg_qui=-1.5 Vp_qui=300
* showLoadLine=n showIp=y isDHP=n isPP=n isAsymPP=n isUL=n showDissipLimit=y
* showIg1=y isInputSnapped=y addLocalNFB=n
* XYProjections=n harmonicPlot=y dissipPlot=n
* UL=0.43 EG2=150 gridLevel2=y addKink=y isTanhKnee=n advSigmoid=y
*----------------------------------------------------------------------------------
RE1  7 0  1G    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(G2,K)/KP*LOG(1+EXP((1/MU+(VCT+V(G,K))/SQRT(KVB+V(G2,K)*V(G2,K)))*KP))}
RE2  6 0  1G    ; DUMMY SO NODE 6 HAS 2 CONNECTIONS
E2  6 0  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))} ; Kg1 times KIT current
E4   8 0  VALUE={V(P,K)/KNEE/(KVBGI+V(6)*KVBG)}
E5  81 0  VALUE={PWR(V(8),KB1)}
E6  82 0  VALUE={PWR(V(8),KB2)}
E7  83 0  VALUE={PWR(V(8),KB3)}
E8   9 0  VALUE={PWR(1-EXP(-V(81)*(KC+KR1*V(82))/(KD+KR2*V(83))),KB4)*1.5708}
RE4  8 0  1
RE5 81 0  1
RE6 82 0  1
RE7 83 0  1
RE8  9 0  1
RE21 21 0 1
E21  21 0 VALUE={V(6)/KG1*V(9)} ; Ip with knee but no slope and no kink
RE22 22 0 1 ; E22: kink curr deviation for plate
E22  22 0 VALUE={V(21)*LIMIT(KNK-V(G,K)*KNG,0,0.3)*(-ATAN((V(P,K)-KNPL)/KNSL)+ATAN((V(P,K)-KNPR)/KNSR))}
G1   P K  VALUE={V(21)*(1+KLAMG*V(P,K))+KLAM*V(P,K) + V(22)}
G2   G2 K  VALUE={V(6)/KG2*(KVC-V(9))/(1+KLAMG*V(P,K)) - V(22)}
RCP  P K  1G     ; FOR CONVERGENCE
C1   K G  {CCG}  ; CATHODE-GRID 1
C2   G P  {CGP}  ; GRID 1-PLATE
C3   K P  {CCP}  ; CATHODE-PLATE
RE23 G 0 1G
GG G K VALUE={(IGA+IGB/(IGC+V(P,K)))*(MU/KG1)*
+(PWR(V(G,K)-VGOFF,IGEX)+PWRS(V(G,K)-VGOFF,IGEX))}
.ENDS
*$
 

Koonw

Member
2013-04-09 9:37 pm
If you're using 6f12p pentode section triode strapped you can use this model: https://www.bartola.co.uk/valves/2019/04/20/6f12p-a-great-russian-valve/
It also includes the newly measured Miller effect capacitance (maybe other model should use the same capacitance):
*
  • 1. total input capacitance measured is 605pF @gain of 39dB (x89.1)
  • 2. From data sheet Cgk=6.6pF. Given Cin=Cgk+(mu+1)*Cag -> Cag = (Cin-Cgk)/(mu+1) =6.64pF
*
If you want to use 6f12p pentode model, try to use my most recent model, in which the strapped triode (tie screen to plate) in sim the result will be same as the above triode model. In other word the above triode model is used to model the my 6f12p pentode model. You should be able to verify both models in sim, but Bartola has not published a pentode model, so you can only compare the triode mode. In real circuit you can only have triode connected pentode, not real triode, if pentode curves varied so does the triode strapped tube.
 

Koonw

Member
2013-04-09 9:37 pm
Here is one verification you can do: edit Cag=6.64p, so capacitance for both model are same and plot the transcient and freq. response.
 

Attachments

  • 6f12p triode strapped model transcient compared.jpg
    6f12p triode strapped model transcient compared.jpg
    238.7 KB · Views: 52
  • 6f12p triode strapped model freq response compared.jpg
    6f12p triode strapped model freq response compared.jpg
    360.5 KB · Views: 45
  • 6f12p model compared.asc
    7.4 KB · Views: 31