Cool!
I presume I need to change a line in this bit of code?
# SPL curves + Sound Power --------------------------------------------------------------
set bmargin at screen 0.4
set lmargin at screen 0.712
set palette defined (0 "#404040", 4 "#200080", 12 "#208020", 30 "#a0a0a0")
unset colorbox
set yrange [-30:6]
set ytics 3 in #auto
set mytics 3
set ylabel "dB SPL (".R_NORM_ANGLE."° normalized)" offset 0,0
unset format y
plot "polars_norm.txt" u 1:2:3 w l lw 1 not,\
"spower_norm.txt" u 1:2 w l dt "-" lc rgb "black" lw 2 not
set multiplot next
Hold on, I yet haven't had a chance to do it but I'll post the modified script later today.I presume I need to change a line in this bit of code?
You take it seriously! I like that 🙂First horn [...] is in the glue press.
Wouldn't do it any other way haha!
Ensuring alignment and a tight bond on so many pieces was a bit nerve wrecking. For anyone else going this route I highly recommend using super tacky construction glue. The initial hook you get from the tacky glue is very useful when it comes to aligning the petals in the throat. But make sure to use clear tape on any aligment jigs you might use to avoid them sticking to the waveguide.
Ensuring alignment and a tight bond on so many pieces was a bit nerve wrecking. For anyone else going this route I highly recommend using super tacky construction glue. The initial hook you get from the tacky glue is very useful when it comes to aligning the petals in the throat. But make sure to use clear tape on any aligment jigs you might use to avoid them sticking to the waveguide.
So I gather you didn't use the provided assembly jig, right? Is that not the way making it easier?
I certainly did. And it was very handy. But my print tolerances were all over the place, so i had to use all the tricks to ensure a good fit. (I don't have permanent access to a printer, so I've used three different printers with more than 4 different PLA filaments)
Last edited:
Here you go. You just need to set GnuplotCode in your Report definition, and of course disable any normalization as well.I'll post the modified script later today.
It's possible to set the SPL range to fixed or automatic (see SPL_0, SPL_1 and the instructions in the file).
load 'static.txt'
load 'param.txt'
SPL_0 = 20 # [dB]; set to R_MIN_SPL for automatic range
SPL_1 = 70 # [dB]; set to R_MAX_SPL for automatic range
set terminal pngcairo mono size R_W,R_H font "Arial,10"
set output R_FILE.'.png'
set multiplot layout 2,3 \
margins 0.06,0.96,0.08,0.93 \
spacing 0.1,0.03 \
title R_TITLE font "Arial,14" noenhanced
set label R_DIM at screen 0.07,0.94 font "Arial,10"
set label LINE_1 at screen 0.05,0.35
set label LINE_2 at screen 0.05,0.32
set label LINE_3 at screen 0.05,0.29
set label LINE_4 at screen 0.05,0.26
set style line 40 lc rgb 0xb0b0b0 lt 1 lw 1
set key left top
# profile sketch
set bmargin at screen 0.4
set yrange [0:R_MAX_R]
set size ratio -1
set ytics 50 out nomirror
unset ylabel
unset xtics
set border 2
plot 'coords.txt' u 1:2 w l lc rgb 0x000000 lw 1 not, 0 w l dt '- . ' lt 2 not
# Polar Map -----------------------------------------------------------------------------
set bmargin at screen 0.4
set rmargin at screen 0.64
set logscale x
set size noratio 1,1
set border 31
set ytics in auto
set contour base
set view map
unset surface
set style textbox noborder opaque
set cntrparam level discrete 6,3,2,1,-1,-2,-3,-4,-5,-6,-9,-12,-15
set cntrlabel start -1 interval -1 font "Arial,9"
set grid xtics mxtics ytics mytics #ls 40 back
set xtics auto
set xtics add ("" 200, "" 500, "" 1000, "" 5000, "" 10000, "" 15000, "" 20000) in nomirror
set format y "%.0f°"
set xrange [200:20000]
set yrange [0:R_MAX_ANGLE]
set ytics 15
set mytics 3
set ylabel "Polar map (".R_NORM_ANGLE."° normalized) [dB SPL]" offset -2,0
splot "pmap.txt" u 2:1:3 w l not, "" u 2:1:3 w labels boxed not
# SPL curves + Sound Power --------------------------------------------------------------
set bmargin at screen 0.4
set lmargin at screen 0.712
set palette defined (0 "#404040", 4 "#200080", 12 "#208020", 30 "#a0a0a0")
unset colorbox
set yrange [SPL_0:SPL_1]
set ytics 5 in #auto
set mytics 5
set ylabel "dB SPL" offset 0,0
unset format y
plot "polars.txt" u 1:2:3 w l lw 1 not,\
"spower.txt" u 1:2 w l dt "-" lc rgb "black" lw 2 not
set multiplot next
# Throat Impedance
set tmargin at screen 0.38
set rmargin at screen 0.64
set xlabel "Frequency [Hz]"
set xtics add ("200" 200, "500" 500, "1k" 1000, "5k" 5000, "10k" 10000, "" 15000, "20k" 20000)
set yrange [0:2]
set ytics ("0" 0, "0.2" 0.2, "0.5" 0.5, "1" 1, "1.5" 1.5)
set ylabel "Throat Impedance" offset -1,0
plot "radimp.txt" u 1:2 w l lw 1 lc rgb "black" t "Re", "" u 1:3 w l lw 1 t "Im"
# DI, etc.
set tmargin at screen 0.38
set lmargin at screen 0.712
set yrange [0:20]
set ytics ("0" 0, "5" 5, "10" 10, "15" 15)
set ylabel "Directivity Index [dB]" offset -1,0
plot "DI.txt" u 1:2 w l lw 1 t "on-axis", \
"" u 1:3 w l lw 2 t "10 deg", \
"" u 1:4 w l lw 1 t "20 deg"
unset multiplot
ABEC outputs the file "Spectrum_ABEC.txt", which is then converted by Ath to a set of simple text files read by gnuplot.
It's described in 6.14: http://www.at-horns.eu/release/Ath-4.8.2-UserGuide.pdf#page=60
It's described in 6.14: http://www.at-horns.eu/release/Ath-4.8.2-UserGuide.pdf#page=60
I cant install gniuplot on the VM a run ATH on... but ATH is involved with -r extension - this means I can not move the files to OSX and run gnuplot from there...
//
//
You can take the files intended for gnuplot (simply all the *.txt files in the 'Results' subdirectory, after "ath ... -r" is executed) and run gnuplot anywhere else, but it won't be very convenient.
Last edited:
I dont know enough of win to get why I cant install it in my ARM64 based VM... hence: https://www.diyaudio.com/community/threads/gnuplot-in-vm-on-mac-x86-64.413839/#post-7708319
//
//
Thanks, Marcel. Unfortunately, I'm not quite there yet. I put the new GNU script in the right folder and I added it to the GnuplotCode in the Report definition.Here you go. You just need to set GnuplotCode in your Report definition, and of course disable any normalization as well.
It's possible to set the SPL range to fixed or automatic (see SPL_0, SPL_1 and the instructions in the file).
View attachment 1321597
ATH is now using this script. In the first run, I didn't see any SPL data. The default SPL range is 20 to 70. I then set the SPL range to automatic, and now I get the results below. However, the SPL results are still normalized. You said "[...] and of course disable any normalization as well". Where do I do that? I went through the GNU code and the only place where normalization is mentioned is in regards to the polar map. Should this be configured elsewhere?
In the ABEC Observation Script if you already have the project or in the Ath Script if not or re run it. Remove NormAngle = from the Ath script or comment out NormalizingAngle= in the ABEC script, rerun the observsations and save the ABEC spectrum again to avoid the data already normalized on entry.Should this be configured elsewhere?
As fluid says. BTW, the polar map will always be normalized I think (at 10deg, which is the default value, IIRC). To change this would require some modifications of the Ath code.
- You can also change the way the elements are driven - the default is constant acceleration. Sometimes it's handy to use constant velocity. This is set in the ABEC observation script. For normalized results, this makes no difference of course.
In the Ath script, this can also be set:
- You can also change the way the elements are driven - the default is constant acceleration. Sometimes it's handy to use constant velocity. This is set in the ABEC observation script. For normalized results, this makes no difference of course.
In the Ath script, this can also be set:
Code:
ABEC.DrivingType = 1 ; constant driving: 1=acceleration, 2=velocity
ABEC.DrivingValue = 100 ; use much lower value for velocity
Last edited:
Thanks, guys!
I simply put a [ ; ] in front of [NormAngle = 10], that did the trick.
Now marvel at this beauty!
I simply put a [ ; ] in front of [NormAngle = 10], that did the trick.
Now marvel at this beauty!
- Home
- Loudspeakers
- Multi-Way
- Acoustic Horn Design – The Easy Way (Ath4)