Vacuum Tube SPICE Models

[DIYspaceW]

OKKK! Does anyone have a working model for the nutube?

 

[jazbo8]

Try this:

.SUBCKT NU6P1 1 2 3
+params: MU= 18.10 EX= 4.080 KG1=4270851.9 KP=451.94 KVB= 4.2 VCT= 0.00 RGI=330k CCG=9.1P CGP=2.5P CCP=4.3P
E1 7 0 VALUE= 
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))} 
RE1 7 0 1G 
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1} 
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER 
C1 2 3 {CCG} ; CATHODE-GRID 
C2 2 1 {CGP} ; GRID=PLATE 
C3 1 3 {CCP} ; CATHODE-PLATE 
D3 5 3 DX ; FOR GRID CURRENT 
R1 2 5 {RGI} ; FOR GRID CURRENT 
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) 
.ENDS

 

[DIYspaceW]

Works perfect! Thank you!

 

[mcl2k6]

Hi!

Does any of you have a model for triode strapped 6J1P 7pin Russian mini pentode?
I've got a bunch of them, and would see if it is useful for anything...

Thank you!

 

[RajkoM]

6J1P is identical to 6AK5. I have triode spice model for 6AK5, if you need ....

 

[jazbo8]

Please see Vacuum Tube SPICE Models

 

[mcl2k6]

Thank you RajkoM, jazbo8!

 

[caglio]

6CM8 spice model

Hi at all! Someone have a spice model of 6cm8 triode pentode tube? The triode is very similar a half 12ax7, but the sharp cut off pentode I dont know similar...
Please help me

 

[jazbo8]

If you can trace the pentode curves for the 6CM8, I can make the SPICE model for you. For the triode, just use the 12AX7 model.

 

[caglio]

the datasheet have the curve, is enought?
http://www.mif.pg.gda.pl/homepages/frank/sheets/137/6/6CM8.pdf

 

[jazbo8]

No, I need the triode-connected curve for the pentode to make the model.

 

[RajkoM]

jazbo, triode-connected curve is on page 8 of atached PDF

 

[jazbo8]

I think that's for the triode section...

 

[RajkoM]

I see

 

[caglio]

yes page 8 is for triode section.
I have utracer and next days can trace the curve.

 

[jazbo8]

Great, we will wait for the triode-connected curves.

 

[caglio]

have you some preferencies for working condition and tensions?

 

[jazbo8]

Vp = 0 to 300V
Pdiss < 2W (probably limit Ip < 30mA)
Vg = 0 to -10V in 1V steps

with G2 directly connected to the plate.

 

[khutch04]

Does anyone have a model for the following dual pentode compactrons or have an opinion on what single pentode models might be close enough?

6AR11
6BV11
6BN11

I'll keep looking on my own but if anyone has one, thanks!!

 

[jazbo8]

6BN11 SPICE Model

*
* Generic pentode model: 6BN11_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sat Nov 01 18:19:03 2014
*                Plate
*                | Screen Grid
*                | |  Control Grid
*                | |  |  Cathode
*                | |  |  |
.SUBCKT 6BN11_AN A G2 G1 K
BGG   GG   0 V=V(G1,K)+0.80333486
BM1   M1   0 V=(0.016690499*(URAMP(V(G2,K))+1e-10))**-1.028498
BM2   M2   0 V=(0.59323756*(URAMP(V(GG)+URAMP(V(G2,K))/24.370897)))**2.528498
BP    P    0 V=0.0032099434*(URAMP(V(GG)+URAMP(V(G2,K))/41.081176))**1.5
BIK   IK   0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0021774044*V(M1)*V(M2)
BIG   IG   0 V=0.0016049717*URAMP(V(G1,K))**1.5*(URAMP(V(G1,K))/(URAMP(V(A,K))+URAMP(V(G1,K)))*1.2+0.4)
BIK2  IK2  0 V=V(IK,IG)*(1-0.4*(EXP(-URAMP(V(A,K))/URAMP(V(G2,K))*15)-EXP(-15)))
BIG2T IG2T 0 V=V(IK2)*(0.75853563*(1-URAMP(V(A,K))/(URAMP(V(A,K))+10))**1.5+0.24146437)
BIK3  IK3  0 V=V(IK2)*(URAMP(V(A,K))+3175)/(URAMP(V(G2,K))+3175)
BIK4  IK4  0 V=V(IK3)-URAMP(V(IK3)-(0.001722887*(URAMP(V(A,K))+URAMP(URAMP(V(G2,K))-URAMP(V(A,K))))**1.5))
BIP   IP   0 V=URAMP(V(IK4,IG2T)-URAMP(V(IK4,IG2T)-(0.001722887*URAMP(V(A,K))**1.5)))
BIAK  A    K I=V(IP)+1e-10*V(A,K)
BIG2  G2   K I=URAMP(V(IK4,IP))
BIGK  G1   K I=V(IG)
* CAPS
CGA   G1  A  0.03p
CGK   G1  K  7.2p
C12   G1  G2 4.8p
CAK   A   K  2.8p
.ENDS