It's probably easiest to swap the leads at the output tubes' grids. By that I mean...
Now N024 should connect to C1, and N006 should connect to C2.
Does that make sense?
- Disconnect the lead from the plate of U2 (lead connecting to C1)
- Disconnect the lead from the junction of R9. R6 and R5 (lead connecting to C2)
- Connect the lead from the plate of U2 to C2 (instead of to C1)
- Connect the lead from the jct of R9, R6, R5 to C1 (instead of to C2)
Now N024 should connect to C1, and N006 should connect to C2.
Does that make sense?
Last edited:
Unfortunately the Hammond data sheet doesn't shew any polarity marks.
So reversing primary or secondary leads is the way out. Looks like the secondary end leads are easiest.
For the split load 12AU7 driver I got much better results with both sections paralleled, driving PP 6L6GCs in a very similar circuit.
That was at the beginning of time tho, just after the earth cooled. Those two monoblock amps still run.
So reversing primary or secondary leads is the way out. Looks like the secondary end leads are easiest.
For the split load 12AU7 driver I got much better results with both sections paralleled, driving PP 6L6GCs in a very similar circuit.
That was at the beginning of time tho, just after the earth cooled. Those two monoblock amps still run.
Yep! Easy peasy. I somehow wound up full of whiskey tonight, so I'll run that down tomorrow AM and report back. Thanks, as always, rongon.
Huh. So, just to clarify, you ran 2 12AU7 tubes for the stereo amp with both sections paralleled per side?
I thought this is a stereo amp (two channels on one chassis)...
If you want to redesign the amp for a beefier driver, you could use a 12BH7A, 6GU7, ECC99, 6N6P or 5687 instead of the 12AU7. They all run with higher plate current, lower rp, higher gm for more oomph. They also all require more heater current and dissipate more power. But would the improvement be enough to be readily audible in normal use? The 12AU7 cathodyne is drawing 5mA plate current, which should be enough to charge the UL 6L6GC grid capacitance.
Anybody know offhand what the input C of a UL-wired 6L6GC is? I think the triode input C is only about 100pF at the very most, so the UL input C should be a bit lower than that. Maybe 60pF at the very most? According to calculations, if the driving stage needs to swing a 50V peak 50kHz signal into 60pF, the necessary charge current is about 1mA. The 12AU7 is set up to be able to sink 5X that. Is that enough, or am I missing something?
--
If you want to redesign the amp for a beefier driver, you could use a 12BH7A, 6GU7, ECC99, 6N6P or 5687 instead of the 12AU7. They all run with higher plate current, lower rp, higher gm for more oomph. They also all require more heater current and dissipate more power. But would the improvement be enough to be readily audible in normal use? The 12AU7 cathodyne is drawing 5mA plate current, which should be enough to charge the UL 6L6GC grid capacitance.
Anybody know offhand what the input C of a UL-wired 6L6GC is? I think the triode input C is only about 100pF at the very most, so the UL input C should be a bit lower than that. Maybe 60pF at the very most? According to calculations, if the driving stage needs to swing a 50V peak 50kHz signal into 60pF, the necessary charge current is about 1mA. The 12AU7 is set up to be able to sink 5X that. Is that enough, or am I missing something?
--
Last edited:
They are two monoblocks. Detailed information was given in posts 12 & 17.
And ignored, as usual.
Not really interested in making a change. Just wanted to understand what jhstewart9 meant.
Sorry. Did not intend to ignore. I have a habit of getting focused on things and shutting out competing ideas. Ask Mrs. Annan. She'll tell you.
Kofi
I think I was misunderstanding what everyone's saying.
I went back and read thru the thread, and saw that your design is a single chassis, stereo amp. I assume you're using one 12AX7, one 12AU7 and four 6L6s.
Back near the beginning of this thread, jhstewart9 made some good points about power transformer winding resistance that never got replied to. I just wanted to say yes, good points there. The B+ may come out lower than calculated. It looks like the Antek toroids often give you higher heater voltages than expected.
Kofi, at some point will you be posting a new version of the schematic with real-life measured voltages? I always like to compare the final results to the simulations. My two, simple designs from simulations (a headphone amp and a phono preamp) came out very close to the predictions, but that's only two designs so far...
I hope Adrian Immler doesn't mind, but since I really like his models, and he has created 12AX7, 12AU7 and 6L6GC models, I'll take this opportunity to post them here, in case you want to run your simulation with them to get a second opinion.
12AX7:
12AU7 (actually Philips E82CC):
12AX7:
Code:
*12AX7 LTspice model based on the generic triode model from Adrian Immler, version i4
*A version log is at the end of this file
*selection out of 5 new burnt-in Tung-Sol tubes and measurements done in May 2020
*Params fitted to the measured values by Adrian Immler, June 2020
*The high fit quality is presented at adrianimmler.simplesite.com
*History's best of tube decribing art (plus some new ideas) is merged to this new approach.
*@ neg. Vg, Ia accuracy is similar to Koren or Ayumi models.
*@ small neg. Vg, the "Anlauf" current is considered.
*@ pos. Vg, Ig and Ia accuracy is on a unrivaled level.
*This offers new simulation possibilities like bias point setting with MOhm grid resistor,
*Audion radio circuits, low voltage amps, guitar distortion stages or pulsed stages.
* anode (plate)
* | grid
* | | cathode
* | | |
.subckt 12AX7.TSi4 A G K
.params
*Parameters for the space charge current @ Vg <= 0
+ mu = 94.3 ;Determines the voltage gain @ constant Ia
+ rad = 39k2 ;Differential anode resistance, set @ Iad and Vg=0V
+ Vct = 0.28 ;Offsets the Ia-traces on the Va axis. Electrode material's contact potential
+ kp = 950 ;Mimics the island effect
+ xs = 1.5 ;Determines the curve of the Ia traces. Typically between 1.2 and 1.8
*
*Parameters for assigning the space charge current to Ia and Ig @ Vg > 0
+ kB = 0.9 ;Describes how fast Ia drops to zero when Va approaches zero.
+ radl = 750 ;Differential resistance for the Ia emission limit @ very small Va and Vg > 0
+ tsh = 12 ;Ia transmission sharpness from 1th to 2nd Ia area. Keep between 3 and 20. Start with 20.
+ xl = 1.5 ;Exponent for the emission limit
*
*Parameters of the grid-cathode vacuum diode
+ kvdg = 450 ;virtual vacuumdiode. Causes an Ia reduction @ Ig > 0.
+ kg = 5k2 ;Inverse scaling factor for the Va independent part of Ig (caution - interacts with xg!)
+ Vctg = 0.1 ;Offsets the log Ig-traces on the Vg axis. Electrode material's contact potential
+ xg = 1.5 ;Determines the curve of the Ig slope versus (positive) Vg and Va >> 0
+ VT = 0.1 ;Log(Ig) slope @ Vg<0. VT=k/q*Tk (cathodes absolute temp, typically 1150K)
+ Vft2 = -0.1 gft2 = 0;finetunes the gridcurrent @ low Va and Vg near zero
*
*Parameters for the caps
+ cag = 1p7 ;From datasheet
+ cak = 0p34 ;From datasheet
+ cgk = 1p6 ;From datasheet
*
*special purpose parameters
+ os = 1 ;Overall scaling factor, if a user wishes to simulate manufacturing tolerances
*
*Calculated parameters
+ Iad = 100/rad ;Ia where the anode a.c. resistance is set according to rad.
+ ks = pow(mu/(rad*xs*Iad**(1-1/xs)),-xs) ;Reduces the unwished xs influence to the Ia slope
+ ksnom = pow(mu/(rad*1.5*Iad**(1-1/1.5)),-1.5) ;Sub-equation for calculating Vg0
+ Vg0 = Vct + (Iad*ks)**(1/xs) - (Iad*ksnom)**(2/3) ;Reduces the xs influence to Vct.
+ kl = pow(1/(radl*xl*Ild**(1-1/xl)),-xl) ;Reduces the xl influence to the Ia slope @ small Va
+ Ild = sqrt(radl)*1m ;Current where the Il a.c. resistance is set according to radl.
*
*Space charge current model
Bggi GGi 0 V=v(Gi,K)+Vg0 ;Effective internal grid voltage.
Bahc Ahc 0 V=uramp(v(A,K)) ;Anode voltage, hard cut to zero @ neg. value
Bst St 0 V=uramp(max(v(GGi)+v(A,K)/(mu), v(A,K)/kp*ln(1+exp(kp*(1/mu+v(GGi)/(1+v(Ahc)))))));Steering volt.
Bs Ai K I=os/ks*pow(v(St),xs) ;Langmuir-Childs law for the space charge current Is
*
*Anode current limit @ small Va
.func smin(z,y,k) {pow(pow(z+1f, -k)+pow(y+1f, -k), -1/k)} ;Min-function with smooth trans.
Ra A Ai 1
Bgl Gi A I=min(i(Ra)-smin(1/kl*pow(v(Ahc),xl),i(Ra),tsh),i(Bgvd)*exp(4*v(G,K))) ;Ia emission limit
*
*Grid model
Bvdg G Gi I=1/kvdg*pwrs(v(G,Gi),1.5) ;Reduces the internal effective grid voltage when Ig rises
Rgip G Gi 1G ;avoids some warnings
.func Ivd(Vvd, kvd, xvd, VTvd) {if(Vvd < 3, 1/kvd*pow(VTvd*xvd*ln(1+exp(Vvd/VTvd/xvd)),xvd), 1/kvd*pow(Vvd, xvd))} ;Vacuum diode function
Bgvd Gi K I=Ivd(v(G,K) + Vctg - uramp(-v(A,K)/mu), kg/os, xg, VT)
.func ft2() {gft2*(1-tanh(3*(v(G,K)+Vft2)))} ;Finetuning-func. improves ig-fit @ Vg near -0.5V, low Va.
Bgr Gi Ai I=ivd(v(GGi),ks/os, xs, 0.8*VT)/(1+ft2()+kB*v(Ahc));Is reflection to grid when Va approaches zero
Bs0 Ai K I=ivd(v(GGi),ks/os, xs, 0.8*VT)/(1+ft2()) - os/ks*pow(v(GGi),xs) ;Compensates neg Ia @ small Va and Vg near zero
*
*Caps
C1 A G {cag}
C2 A K {cak}
C3 G K {cgk}
.end
*
*Version log
*i1 :Initial version
*i2 :Pin order changed to the more common order „A G K“ (Thanks to Markus Gyger for his tip)
*i3 :bugfix of the Ivd-function: now also usable for larger Vvd
*i4: Rgi replaced by a virtual vacuum diode (better convergence). ft1 deleted (no longer needed)
;2 new prarams for Ig finetuning @ Va and Vg near zero. New emission skaling factor ke for aging etc.12AU7 (actually Philips E82CC):
Code:
*E82CC LTspice model based on the generic triode model from Adrian Immler, version i4
*A version log is at the end of this file
*Params fitted to Philips datasheet by Adrian Immler, Dec. 2020
*The high fit quality is presented at adrianimmler.simplesite.com
*History's best of tube decribing art (plus some new ideas) is merged to this new approach.
*@ neg. Vg, Ia accuracy is similar to Koren or Ayumi models.
*@ small neg. Vg, the "Anlauf" current is considered.
*@ pos. Vg, Ig and Ia accuracy is on a unrivaled level.
*This offers new simulation possibilities like bias point setting with MOhm grid resistor,
*Audion radio circuits, low voltage amps, guitar distortion stages or pulsed stages.
* anode (plate)
* | grid
* | | cathode
* | | |
.subckt E82CC.PHi4 A G K
.params
*Parameters for the space charge current @ Vg <= 0
+ mu = 20.22;Determines the voltage gain @ constant Ia
+ rad = 5k5 ;Differential anode resistance, set @ Iad and Vg=0V
+ Vct = 0.55 ;Offsets the Ia-traces on the Va axis. Electrode material's contact potential
+ kp = 75.9 ;Mimics the island effect
+ xs = 1.5 ;Determines the curve of the Ia traces. Typically between 1.2 and 1.8
*
*Parameters for assigning the space charge current to Ia and Ig @ Vg > 0
+ kB = 0.33 ;Describes how fast Ia drops to zero when Va approaches zero.
+ radl = 557 ;Differential resistance for the Ia emission limit @ very small Va and Vg > 0
+ tsh = 4 ;Ia transmission sharpness from 1th to 2nd Ia area. Keep between 3 and 20. Start with 20.
+ xl = 1.2 ;Exponent for the emission limit
*
*Parameters of the grid-cathode vacuum diode
+ kvdg = 100 ;virtual vacuumdiode. Causes an Ia reduction @ Ig > 0.
+ kg = 3k86 ;Inverse scaling factor for the Va independent part of Ig (caution - interacts with xg!)
+ Vctg = 0.5 ;Offsets the log Ig-traces on the Vg axis. Electrode material's contact potential
+ xg = 1.5 ;Determines the curve of the Ig slope versus (positive) Vg and Va >> 0
+ VT = 0.1 ;Log(Ig) slope @ Vg<0. VT=k/q*Tk (cathodes absolute temp, typically 1150K)
+ kVT=0 ;Va dependant koeff. of VT
+ Vft2 = 0 gft2 = 0 ;finetunes the gridcurrent @ low Va and Vg near zero
*
*Parameters for the caps
+ cag = 1p5 ;From datasheet
+ cak = 0p5 ;From datasheet
+ cgk = 1p6 ;From datasheet
*
*special purpose parameters
+ os = 1 ;Overall scaling factor, if a user wishes to simulate manufacturing tolerances
*
*Calculated parameters
+ Iad = 100/rad ;Ia where the anode a.c. resistance is set according to rad.
+ ks = pow(mu/(rad*xs*Iad**(1-1/xs)),-xs) ;Reduces the unwished xs influence to the Ia slope
+ ksnom = pow(mu/(rad*1.5*Iad**(1-1/1.5)),-1.5) ;Sub-equation for calculating Vg0
+ Vg0 = Vct + (Iad*ks)**(1/xs) - (Iad*ksnom)**(2/3) ;Reduces the xs influence to Vct.
+ kl = pow(1/(radl*xl*Ild**(1-1/xl)),-xl) ;Reduces the xl influence to the Ia slope @ small Va
+ Ild = sqrt(radl)*1m ;Current where the Il a.c. resistance is set according to radl.
*
*Space charge current model
Bggi GGi 0 V=v(Gi,K)+Vg0 ;Effective internal grid voltage.
Bahc Ahc 0 V=uramp(v(A,K)) ;Anode voltage, hard cut to zero @ neg. value
Bst St 0 V=uramp(max(v(GGi)+v(A,K)/(mu), v(A,K)/kp*ln(1+exp(kp*(1/mu+v(GGi)/(1+v(Ahc)))))));Steering volt.
Bs Ai K I=os/ks*pow(v(St),xs) ;Langmuir-Childs law for the space charge current Is
*
*Anode current limit @ small Va
.func smin(z,y,k) {pow(pow(z+1f, -k)+pow(y+1f, -k), -1/k)} ;Min-function with smooth trans.
Ra A Ai 1
Bgl Gi A I=min(i(Ra)-smin(1/kl*pow(v(Ahc),xl),i(Ra),tsh),i(Bgvd)*exp(4*v(G,K))) ;Ia emission limit
*
*Grid model
Bvdg G Gi I=1/kvdg*pwrs(v(G,Gi),1.5) ;Reduces the internal effective grid voltage when Ig rises
Rgip G Gi 1G ;avoids some warnings
Cvdg G Gi 0p1;this small cap improves convergence
.func fVT() {VT*exp(-kVT*sqrt(v(A,K)))}
.func Ivd(Vvd, kvd, xvd, VTvd) {if(Vvd < 3, 1/kvd*pow(VTvd*xvd*ln(1+exp(Vvd/VTvd/xvd)),xvd), 1/kvd*pow(Vvd, xvd))} ;Vacuum diode function
Bgvd Gi K I=Ivd(v(G,K) + Vctg, kg/os, xg, fVT())
.func ft2() {gft2*(1-tanh(3*(v(G,K)+Vft2)))} ;Finetuning-func. improves ig-fit @ Vg near -0.5V, low Va.
Bgr Gi Ai I=ivd(v(GGi),ks/os, xs, 1.1*VT)/(1+ft2()+kB*v(Ahc));Is reflection to grid when Va approaches zero
Bs0 Ai K I=ivd(v(GGi),ks/os, xs, 1.1*VT)/(1+ft2()) - os/ks*pow(v(GGi),xs) ;Compensates neg Ia @ small Va and Vg near zero
*
*Caps
C1 A G {cag}
C2 A K {cak}
C3 G K {cgk}
.end
*
*Version log
*i1 :Initial version
*i2 :Pin order changed to the more common order "A G K" (Thanks to Markus Gyger for his tip)
*i3 :bugfix of the Ivd-function: now also usable for larger Vvd
*i4: Rgi replaced by a virtual vacuum diode (better convergence). ft1 deleted (no longer needed)
;2 new prarams for Ig finetuning @ Va and Vg near zero. New emission skaling factor ke for aging etc.And 6L6GC (GE):
Code:
*6L6GC LTspice model based on the generic tetrode/pentode model from Adrian Immler, version i3f, Jan. 2020
*i3f means FIXED i3 version. The model works now also for selfbiased stages, cathode followers and the like.
*A version log is at the end of this file
*Params fitted to the GE datasheet by Adrian Immler, October 2019
*The high fit quality is presented at adrianimmler.simplesite.com
*This model is an enhancement of Adrians generic triode model to achieve tetrode/pentode behaviour.
*Hence, it is also suitable when the tetrode/pentode is "triode connected".
*Convenient for power beam as well as for small signal tetrodes/pentodes (just play with radl!).
*
* plate (in this model, "anode" means the internal virtual triode anode)
* | grid2
* | | grid1
* | | | cathode
* | | | |
.subckt 6L6GC_i3f P G2 G1 K
+ params:
*Parameters for the space charge current @ Vg <= 0
+ mu1 = 10 ;Determines the voltage gain @ constant Ia
+ rad = 1k21 ;Differential anode resistance, set @ Iad and Vg=0V
+ Vct = 0.97 ;Offsets the Ia-traces on the Va axis. Electrode material's contact potential
+ kp = 38 ;Mimics the island effect
+ xs = 1.4 ;Determines the curve of the Ia traces. Typically between 1.2 and 1.8
*
*Parameters for assigning the space charge current to Ia and Ig @ Vg > 0 and small Va
+ kB1 = 0.10 ;Describes how fast Ia drops to zero when Va approaches zero.
+ radl = 340 ;Differential resistance for the Ia emission limit @ very small Va and Vg > 0
+ tsh = 8 ;Ia transmission sharpness from 1th to 2nd Ia area. Keep between 3 and 20. Start with 20.
+ xl = 1.4 ;Exponent for the emission limit
*
*Parameters of the grid-cathode vacuum diode
+ Rg1i = 40 ;Internal grid1 resistor. Causes an Is reduction @ Ig > 0.
+ kg1 = 930 ;Inverse scaling factor for the Va independent part of Ig (caution - interacts with xg!)
+ Vctg1 = 1.2;Offsets the log Ig-traces on the Vg axis. Electrode material's contact potential
+ xg1 = 1.0 ;Determines the curve of the Ig slope versus (positive) Vg and Va >> 0
+ VT = 0.1 ;Log(Ig) slope @ Vg<0. VT=k/q*Tk (cathodes absolute temp, typically 1150K)
*
*Parameters for the caps
+ cg1p = 0p6 ;From datasheet
+ cg1All= 10p ;From datasheet
+ cpAll = 6p5 ;From datasheet
*
*Parameters to enhance the triode model to a pentode model
+ mu2 = 24 ;1/mu2 is the fraction of Vp which together with Vg2i builds the virtual Triode-Anode Voltage
+ kB2 = 0.25 ;Describes how fast Ip drops to zero when Vp approaches zero.
+ Rg2i = 200 ;Internal grid2 resistor. Causes an Is reduction when Ig2 increases while Vp drops
+ fr2 = 52m5 ;determines the residual ig2 fraction @ high Va values
+ ftfr2 = 1m2 ;if fr2 showes a Vg2 dependancy, this can be considered with this parameter
*
*Parameters to mimic the secondary emission (inspired from Derk Reefmans approach)
+ co = 0.9 ;decribes the crossover region (Ise drop when Va increase). between 0 and 9
+ Vse=65 a=0 ;Va where the sec. emission is strongest. a=related Vg1 coefficient
+ Ise0=2m2 b=0.22m ;sec. emission peak current @ Vg=0. b=related Vg1 coefficient
+ Vg2ref = 250 ;Vg2 where the following coeffficients has no influence to the emission effect:
+ c = 4m ;Vg2 coefficient of a
+ d = 7.7m ;exp Vg2 coefficient of Ise0
+ e = -0.8u ;Vg2 coeff. of b
*
*Calculated parameters
+ Iad = 100/rad ;Ia where the anode a.c. resistance is set according to rad.
+ ks = pow(mu1/(rad*xs*Iad**(1-1/xs)),-xs) ;Reduces the unwished xs influence to the Ia slope
+ ksnom = pow(mu1/(rad*1.5*Iad**(1-1/1.5)),-1.5) ;Sub-equation for calculating Vg0
+ Vg0 = Vct + (Iad*ks)**(1/xs) - (Iad*ksnom)**(2/3) ;Reduces the xs influence to Vct.
+ kl = pow(1/(radl*xl*Ild**(1-1/xl)),-xl) ;Reduces the xl influence to the Ia slope @ small Va
+ Ild = sqrt(radl)*1m ;Current where the limited anode a.c. resistance is set according to radl.
*
*Space charge current model
Bggi GG1i 0 V=v(G1i,K)+Vg0 ;Effective internal grid voltage.
Bahc Ahc 0 V=uramp(v(P,K)/mu2+v(G2i,K)) ;voltage of the virtual triode anode, hard cut to zero
Bst St 0 V=max(v(GG1i)+v(Ahc)/(mu1), v(Ahc)/kp*ln(1+exp(kp*(1/mu1+v(GG1i)/(1+v(Ahc))))));Steering volt.
Bs Ai K I=ft1()/ks*pow(v(St),xs) ;Langmuir-Childs law for the space charge current Is
.func ft1() {1+(1+tanh(4*v(GG1i)))/38} ;Finetuning-function for better overall fit at pos Vg
*
*Anode current limit @ small Va
.func smin(w,y,n) {pow(pow(w+1f, -n)+pow(y+1f, -n), -1/n)} ;Min-function with smooth trans.
Ra A Ai 1
Bpl G2i P I=i(Rp) - smin(1/kl*pow(v(P,K),xl),i(Rp),tsh);Ia emission limit
*
*Grid model
Rg1i G1 G1i {Rg1i} ;Internal grid resistor for "Ia-reduction" @ Vg > 0
.func Ivd(Vvd, kvd, xvd, VTvd) {1/kvd*pow(VTvd*xvd*ln(1+exp(Vvd/VTvd/xvd)),xvd)} ;Vacuum diode function
Bg1vd G1 K I=Ivd(v(G1,K)+Vctg1-1m*sqrt(v(Ahc)), kg1, xg1, VT) ;Grid-cathode vacuum diode
.func ft2() {7*(1-tanh(3*(v(G1,K)+Vg0)))} ;Finetuning-func. improves ig-fit @ Vg near -0.5V, low Va.
Bg1r G1i Ai I=ft1()*ivd(v(GG1i),ks, xs, 0.8*VT)/(1+ft2()+kB1*v(Ahc));Is reflection to grid when Va appr. zero
Bs0 Ai K I=ft1()*ivd(v(GG1i),ks, xs, 0.8*VT)/(1+ft2()) - ft1()/ks*pow(v(GG1i),xs) ;Compensates neg Ia
*@ small Va and Vg near zero
*
*additional model parts necessary for a pentode
Rg2i G2 G2i {Rg2i}
Rp P A 1
Bg2r G2i A I=i(Ra)*((1-frg2())/(1+kB2*max(0,v(P,K))) ) ; Va dependable ig2 part, reflected from the plate
Bg2f G2 A I=i(Ra)*frg2() ; Va independable ig2 part. Not to lead this current over Rg2i improves convergence
.func frg2() {fr2*exp(ftfr2*(v(G2,K)-250))}
*model for secondary emission effect
*nomalizing function nf(sh) ensures that the peak of y=x*(1-tanh(sh(x-1)) is always at x=1 while sh=0..9
.func nf(z) {609m/z + 293m + 107m*z - 5.71m*z*z}
.func sh() {pow(co,2)} ;results in a more linear control of the cross over region with the param co
Bsee G2 P I=Ise()*nf(sh())*x()*(1-tanh(sh()*(nf(sh())*x()-1))) / (nf(sh())*(1-tanh(sh()*(nf(sh())-1))))
.func Ise() {smin(uramp(Isef() - bf()*v(G1,K)),0.98*i(Rp),2)} ;avoides neg. Iplate caused by strong sec. em.
.func x() {v(P,K)/(1m+uramp(Vse-af()*v(G1,K)))}; moves the sec emission peak to the wanted voltage Vsep
.func af() {a + c*(v(G2,K)-Vg2ref)}
.func Isef() {Ise0 * exp(d*(v(G2,K)-Vg2ref))}
.func bf() {b + e*((v(G2,K)-Vg2ref))}
*
*Caps
C1 G1 P {cg1p} ;from datasheet
C2 G1 K {cg1All/2} ;most datasheets gives a cap "g1 to all except plate". As this model does not consider the
*heater or the ambient as further electrodes for parasitic caps, best way is to assume this " g1 to all" cap
*as it would be half to cathode and half to g2.
C3 G1 G2 {cg1All/2}
C4 P K {cpAll/2} ;most datasheets gives a cap "plate to all except g1". As this model does not consider the
*heater or the ambient as further electrodes for parasitic caps, best way is to assume this " plate to all" cap
*as it would be half to cathode and half to g2.
C5 P G2 {cpAll/2}
.ends
*
*Version log
*i1 :Initial version
*i2 :Pin order changed to the more common order "P G2 G1 K" (Thanks to Markus Gyger for his tip)
*i3 :residual ig2 @ large Va introduced; 2nd emission effect introduced; Va indep. grid current parts no longer lead over internal grid resistors for better convergence
*i3f : Major Bug Fixed. Some Grid/Plate voltages has been refered to GND instead of cathodeWelp, that did the trick, folks! Swapped the leads and feedback is working like a charm. Thanks to all for all your help and patience!
I have a few things still to do:
I should note that the feedback really made a huge difference. It sounds really, really nice to me right now and wound up still loud enough to drive the family from the home, so extra bonus points for that. Very big bass presence but still sounds well-balanced.
I also started messing around with some different open-source PCB design software last night called KiCAD (I normally use Eagle CAD, but the free version prohibits boards past a certain size). I think I need to be done with point-to-point wiring for the rest of my life and would like to see if I can whip up a PCB for this guy. I've made smaller ones before for some Baby Huey builds (CCS boards) and thought I might try for a bigger board with all the components.
More to come soon and thanks a million.
Kofi
I have a few things still to do:
- B+ is sitting at about 440VDC, so I'm planning to change the 25R wirewounds I added to each leg of the PSU secondary to 50R jobs to being the voltage down to about 400. I'm guessing I could live with the 440V B+, but I think it's a little too high
- I'm currently running the 6L6GCs at about 55mA each (wound up with 600R cathode resistors instead of 510R). I found the right combination of parallel resistors and wattage rating now so I'll fit them sometime tonight / tomorrow. This will bring the B+ down a little, but I'll still need to bring the B+ down with some resistance, I believe.
- I have to make a 12V supply for the VU meters (this will provide power for both the backlights and the VU buffer circuit). Probably won't get to this until later in the week.
- I need to correct some of the worst wiring offenses and ensure all panels are safety grounded
I should note that the feedback really made a huge difference. It sounds really, really nice to me right now and wound up still loud enough to drive the family from the home, so extra bonus points for that. Very big bass presence but still sounds well-balanced.
I also started messing around with some different open-source PCB design software last night called KiCAD (I normally use Eagle CAD, but the free version prohibits boards past a certain size). I think I need to be done with point-to-point wiring for the rest of my life and would like to see if I can whip up a PCB for this guy. I've made smaller ones before for some Baby Huey builds (CCS boards) and thought I might try for a bigger board with all the components.
More to come soon and thanks a million.
Kofi
Congrats!
I don't think there's anything wrong with running the amp with a 440V B+. 6L6GC has a max plate dissipation of 30W, and you're running them at about 22W each (440V - about 40V cathode bias = 400V plate-cathode, and Ip = 55mA, so 400V * 0.055A = 22W). I think that should be perfectly fine. Or are you trying to bring the B+ down so you can run the 6L6s at lower voltage/higher current so they stay in class A operation longer? If so, bear in mind that you'll lose a couple watts of output power. That might be OK, though. It might sound better to you that way. Or you might not notice a difference. At this point, the only way to know for sure would be to experiment and measure.
As for PCBs... I would put the driver stage on a PCB, sure, but I'm nervous about putting octal power output tubes on a PCB, especially with cathode bias resistors. I'd put the 6L6s in chassis-mount sockets with the big heat-producing parts mounted so they can breathe. But certainly the 12AX7 and 12AU7 can live on a PCB.
Oh, and maybe you'd want to use jhstewart9's idea of paralleling the driver tubes, using one 12AX7 and one 12AU7 per channel, paralleled. You'd need to half the value of the plate and cathode load resistors, and of course make sure the power supply can deliver the doubled current (which it probably can). Otherwise it's very straightforward. The gain (mu) would remain the same, but the transconductance of the 12AX7 would be doubled (good for driving the feedback loop) and also for the 12AU7 (the additional current and halved rp would allow it to drive the 6L6s more effectively). All good stuff, although you may find the current design is good enough. Just musing...
I don't think there's anything wrong with running the amp with a 440V B+. 6L6GC has a max plate dissipation of 30W, and you're running them at about 22W each (440V - about 40V cathode bias = 400V plate-cathode, and Ip = 55mA, so 400V * 0.055A = 22W). I think that should be perfectly fine. Or are you trying to bring the B+ down so you can run the 6L6s at lower voltage/higher current so they stay in class A operation longer? If so, bear in mind that you'll lose a couple watts of output power. That might be OK, though. It might sound better to you that way. Or you might not notice a difference. At this point, the only way to know for sure would be to experiment and measure.
As for PCBs... I would put the driver stage on a PCB, sure, but I'm nervous about putting octal power output tubes on a PCB, especially with cathode bias resistors. I'd put the 6L6s in chassis-mount sockets with the big heat-producing parts mounted so they can breathe. But certainly the 12AX7 and 12AU7 can live on a PCB.
Oh, and maybe you'd want to use jhstewart9's idea of paralleling the driver tubes, using one 12AX7 and one 12AU7 per channel, paralleled. You'd need to half the value of the plate and cathode load resistors, and of course make sure the power supply can deliver the doubled current (which it probably can). Otherwise it's very straightforward. The gain (mu) would remain the same, but the transconductance of the 12AX7 would be doubled (good for driving the feedback loop) and also for the 12AU7 (the additional current and halved rp would allow it to drive the 6L6s more effectively). All good stuff, although you may find the current design is good enough. Just musing...
Last edited:
Well done mate, glad you got there in the end. Rongon above makes some valid points, OP valves at about 75% max OP is about right for longevity. Are your capacitors within their max wkg voltage? If so your 440v B+/HT may not be such a big issue.
Andy.
Andy.
Huh-- so, good news, then. I'll just run it at 440V. All caps are rated for 450V - 500V, so I should be good there. I'll have to check the heaters to make sure we're not too far over voltage, but I love the 'just leave it alone' method!
Thanks for the advice on the PCB. The power tubes are really easy to wire, so it's the little guys that present the biggest challenge to my patience anyway. I'm still noodling around in KiCAD, but it works about the same as Eagle, so it should not be a tough learning curve.
I'll definitely look into paralleling the driver tubes-- appreciate the guidance on the load resistor values.
I'll start working on the 12V supply and building out the VU buffers sometime tonight and will post results shortly.
Thanks so much!
Kofi
Thanks, man! Yep-- all PSU and smoothing caps are 450V or better. Really appreciate all the help. Once I finish up some of the nits I'll post final voltages and some hot pixxx.
Kofi
Great work , Kofi. For the driver PCB, you may consider the cheap ebay pcb I posted on another forum - it should be very easily adaptable for your front end too.
I got the board some time back for $5ish shipped, and it looks slick with Black mask and gold finish.
https://audiokarma.org/forums/index...t-of-st-35-transformers.989631/#post-15460068
I got the board some time back for $5ish shipped, and it looks slick with Black mask and gold finish.
https://audiokarma.org/forums/index...t-of-st-35-transformers.989631/#post-15460068
Cool! I'll take a look a this one for sure.
I successfully wired the VU meters and I'm experiencing some odd behavior. They seem to get 'stuck' initially and don't move for a bit. A quick blast of volume gets the right one going, but the left one only seems to start moving around when it feels like it. Once they get going, they stay going, however.
I've used these meters before and wound up taking the signal from the speaker binding posts (built a simple cap network for a buffer) and it worked perfectly. I'm now using this VU buffer kit and taking the signal from the output of the volume pot.
I'll fiddle around with it a bit later today but was wondering if anyone had experienced this or had some advice.
More to come.
Kofi
So, it looks like there may be some issues with the TL072 op amp getting into 'lockout', which looks to be some kind of over / under voltage protection scheme that is occasionally preventing current from reaching the chip. Not sure if that's the whole issue, but both meters have been non-responsive at first turn on followed by one or both starting to work at some point during play.
I may fiddle with the PSU for the buffer circuit a bit but might also try the OPA2132PA as a drop-in replacement for the TL072.
Any thoughts?
Kofi
I may fiddle with the PSU for the buffer circuit a bit but might also try the OPA2132PA as a drop-in replacement for the TL072.
Any thoughts?
Kofi