Go Back   Home > Forums > >
Home Forums Rules Articles diyAudio Store Blogs Gallery Wiki Register Donations FAQ Calendar Search Today's Posts Mark Forums Read

Software Tools SPICE, PCB CAD, speaker design and measurement software, calculators

Better power MOSFET models in LTSpice
Better power MOSFET models in LTSpice
Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 24th October 2015, 04:45 PM   #111
keantoken is offline keantoken  United States
diyAudio Member
 
keantoken's Avatar
 
Join Date: Aug 2006
Location: Texas
The VDMOS equations in LTSpice aren't quite the same as the EKV equations. This does mean the LTspice VDMOS model isn't quite as good at modeling the subthreshold region as the EKV model, although it is still a giant step forward.
__________________
The Kmultiplier rail filter! -=- The Simple Kuartlotron Superbuffer!
Need something built, repaired or modded? PM me and ask what I can do!
  Reply With Quote
Old 5th December 2015, 03:50 AM   #112
2 picoDumbs is offline 2 picoDumbs  Australia
diyAudio Member
 
2 picoDumbs's Avatar
 
Join Date: Sep 2013
Quote:
Originally Posted by keantoken View Post
Hello. Finally I am able to make an update. Here are models for the Alfet/Exicon/Semelab 10x20 and 20x20 lateral MOSFETs. These models might not be absolutely perfect, but they've really been through the wringer! These are even more special because they use inline calculation to accurately model temperature effects.

The first set of models with the 'Tjp' suffix use the Tjp parameter to adjust the model for a specific temperature.

To use these models, you will have to add to your simulation the parameter:

.param Tjp=Temp

to your schematic. 'Temp' is the global variable LTSpice uses for temperature. It is 27C by default. If you want to run the simulation with these models at 75C instead, use

.param Tjp=75C

The next set of models with the 75C suffix are fixed at 75C and don't use or require the Tjp parameter. There are drop-in models and don't need any special treatment.

Code:
*
*		MOSFET VDMOS Models with ksubthres
*
*
*10N20-Tjp VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 10N20-Tjp VDMOS (Rg=60 Vto={0.17-1.6m*(Tjp-25)} Lambda=3m
+ Rs={0.245*(1+2.6m*(Tjp-25))} Kp={1.30/(1+8.3m*(Tjp-25))}
+ Ksubthres={0.095*(1+2.9m*(Tjp-25))} Mtriode=0.3 Rd={0.6*(1+3m*(Tjp-25))}
+ Cgdmax=100p Cgdmin=5p a=0.25 Cgs=600p Cjo=1100p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH150521)
*
*
*
*10P20-Tjp VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 10P20-Tjp VDMOS (pchan Rg=60 Vto={-0.535+1.7m*(Tjp-25)} 
+ Rs={0.37*(1+3.4m*(Tjp-25))} Kp={0.995/(1+6.7m*(Tjp-25))} Rd=0.2
+ Ksubthres={0.12*(1+3.1m*(Tjp-25))} Mtriode=0.4 Lambda=5m
+ Cgdmax=100p Cgdmin=5p a=0.25 Cgs=600p Cjo=1100p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH150521)
*
*
*
*20N20-Tjp VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 20N20-Tjp VDMOS (Rg=30 Vto={0.155-1.6m*(Tjp-25)}
+ Rs={0.12*(1+2.5m*(Tjp-25))} Kp={2.40/(1+7.4m*(Tjp-25))}
+ Ksubthres={0.09*(1+1m*(Tjp-25))} Mtriode=0.3  Rd=0.16 Lambda=3m
+ Cgdmax=200p Cgdmin=10p a=0.25 Cgs=1200p Cjo=2200p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH150521)
*
*
*
*20P20-Tjp VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 20P20-Tjp VDMOS (pchan Rg=30 Vto={-0.61+2.2m*(Tjp-25)} 
+ Rs={0.17*(1+2.0m*(Tjp-25))} Kp={1.85/(1+8.4m*(Tjp-25))} 
+ Ksubthres={0.105*(1+5m*(Tjp-25))} Mtriode=0.35 Rd=0.05 Lambda=5m
+ Cgdmax=200p Cgdmin=10p a=0.25 Cgs=1200p Cjo=2200p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH150521)
*
*
**************************************************************
*10N20-75C VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 10N20-75C VDMOS (Rg=60 Vto=0.09 Lambda=3m 
+ Rs=0.277 Kp=0.92 Rd=0.7 Ksubthres=0.11 Mtriode=0.3  
+ Cgdmax=100p Cgdmin=5p a=0.25 Cgs=600p Cjo=1100p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH150521)
*
*
*
*10P20-75C VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 10P20-75C VDMOS (pchan Rg=60 Vto=-0.45 Lambda=5m 
+ Rs=0.432 Kp=0.745 Rd=0.2 Ksubthres=0.14 Mtriode=0.4   
+ Cgdmax=100p Cgdmin=5p a=0.25 Cgs=600p Cjo=1100p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH150521)
*
*
*
*20N20-75C VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 20N20-75C VDMOS(Rg=30 Vto=0.076 Lambda=3m 
+ Rs=0.135 Kp=1.75 Rd=0.16 Ksubthres=0.095 Mtriode=0.3 
+ Cgdmax=200p Cgdmin=10p a=0.25 Cgs=1200p Cjo=2200p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH150521)
*
*
*
*20P20-75C VDMOS with subthreshold (c) Ian Hegglun 21 May 2015
.model 20P20-75C VDMOS (pchan Rg=30 Vto=-0.500 Lambda=5m
+ Rs=0.187 Kp=1.304 Ksubthres=0.13 Mtriode=0.35 Rd=0.05
+ Cgdmax=200p Cgdmin=10p a=0.25 Cgs=1200p Cjo=2200p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH150521)
*
*
********************************************************
How accurate is Cgd Cgs Cjo of 10N20-75C and 10P20-75C, given that data (taken from data sheet) shows ECX10P20 to have roughly twice the capacitance of ECX10N20?
Your values are identical for N and P
__________________
"If you leave this point unattached to some circuitry, an ideal constant current source will emit a small lightning bolt which will travel until it connects to something." Nelson Pass
  Reply With Quote
Old 5th December 2015, 06:00 AM   #113
2 picoDumbs is offline 2 picoDumbs  Australia
diyAudio Member
 
2 picoDumbs's Avatar
 
Join Date: Sep 2013
Actually its probably closer to 1.5x (sorry for any confusion)
__________________
"If you leave this point unattached to some circuitry, an ideal constant current source will emit a small lightning bolt which will travel until it connects to something." Nelson Pass
  Reply With Quote
Old 6th December 2015, 11:26 PM   #114
keantoken is offline keantoken  United States
diyAudio Member
 
keantoken's Avatar
 
Join Date: Aug 2006
Location: Texas
Sorry, it was an oversight. I will post the correct models later.
__________________
The Kmultiplier rail filter! -=- The Simple Kuartlotron Superbuffer!
Need something built, repaired or modded? PM me and ask what I can do!
  Reply With Quote
Old 7th December 2015, 12:50 AM   #115
davidsrsb is offline davidsrsb  Malaysia
diyAudio Member
 
Join Date: Dec 2005
Location: Kuala Lumpur
Well spotted.
This is why simulation often gives unrealistic levels of distortion. N and P or npn and pnp complementary devices are never as close as as most simulation models assume
  Reply With Quote
Old 7th December 2015, 01:14 AM   #116
2 picoDumbs is offline 2 picoDumbs  Australia
diyAudio Member
 
2 picoDumbs's Avatar
 
Join Date: Sep 2013
Quote:
Originally Posted by keantoken View Post
Sorry, it was an oversight. I will post the correct models later.
That would be great.
__________________
"If you leave this point unattached to some circuitry, an ideal constant current source will emit a small lightning bolt which will travel until it connects to something." Nelson Pass
  Reply With Quote
Old 8th December 2015, 08:53 PM   #117
keantoken is offline keantoken  United States
diyAudio Member
 
keantoken's Avatar
 
Join Date: Aug 2006
Location: Texas
Quote:
Originally Posted by davidsrsb View Post
Well spotted.
This is why simulation often gives unrealistic levels of distortion. N and P or npn and pnp complementary devices are never as close as as most simulation models assume
Nowadays it's hard to get N/P copies unless you use those models or use the perfect simulator defaults, so it's actually pretty unlikely to have this problem in simulation. That said, people who make models for audio amps tend to pick matched transistors to base them on, so some of the models floating around match closer than you would expect out of the box. Still, there are a lot of other distortion mechanisms that can dominate even if the transistors are matched. In practice you want to look at more than transistor matching to lower overall distortion in an amplifier.
__________________
The Kmultiplier rail filter! -=- The Simple Kuartlotron Superbuffer!
Need something built, repaired or modded? PM me and ask what I can do!
  Reply With Quote
Old 8th December 2015, 10:17 PM   #118
Bob Cordell is offline Bob Cordell  United States
diyAudio Member
 
Join Date: Sep 2006
Quote:
Originally Posted by keantoken View Post
Nowadays it's hard to get N/P copies unless you use those models or use the perfect simulator defaults, so it's actually pretty unlikely to have this problem in simulation. That said, people who make models for audio amps tend to pick matched transistors to base them on, so some of the models floating around match closer than you would expect out of the box. Still, there are a lot of other distortion mechanisms that can dominate even if the transistors are matched. In practice you want to look at more than transistor matching to lower overall distortion in an amplifier.
Well stated.

Although generalizing can be dangerous, N/P mismatch will often lead more to even-order harmonics. Also, with BJT output stages, people often match for beta, but the degree to which an amplifier is affected by N/P beta mismatch is often a strong function of the output stage topology. For example, a simple 2EF output stage is more affected by beta mismatch than a Triple.

Crossover distortion is one of the most insidious concerns, but the extent to which N/P matching reduces it is hard to predict. One can always say that matching can never hurt.

N/P matching for MOSFETs is more difficult, and usually can't really be done because of the physics of the devices. Matching Vgs of the N and P devices does virtually nothing for distortion in most MOSFET output stages. Note that this is not the same as the issue of matching among like-sex MOSFETs in multiple output pair stages. The more significant issue of N vs P MOSFETs is the amount of transconductance that each has at a given drain current.

Many MOSFET output stages do not employ source resistors because they are really not needed for the same reason as emitter resistors are used in BJT output stages. However, it has been my experience that sometimes adding small-value source resistors of different values for the N and P vertical MOSFET devices can help some. I discuss this in Chapter 11 of my book. It is certainly not a perfect solution, but it can help some. Small value in this context is less than 1 ohm.

Cheers,
Bob
  Reply With Quote
Old 9th December 2015, 05:45 AM   #119
RCruz is offline RCruz  Switzerland
nhinstruments
diyAudio Member
 
RCruz's Avatar
 
Join Date: Sep 2006
Location: Wallis
Better power MOSFET models in LTSpice
__________________
RC
  Reply With Quote
Old 11th December 2015, 02:11 PM   #120
keantoken is offline keantoken  United States
diyAudio Member
 
keantoken's Avatar
 
Join Date: Aug 2006
Location: Texas
Here are the corrected models and the same jig as before.

The use of the Tjp models is explained here:

http://www.diyaudio.com/forums/softw...ml#post4365741

Code:
*
*		MOSFET VDMOS Models with ksubthres
*For 25C
*
*10N20-25 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 10N20-25 VDMOS (Rg=60 Vto={0.17-1.6m*0} Lambda=3m
+ Rs={0.245*(1+2.6m*0)} Kp={1.30/(1+8.3m*0)}
+ Ksubthres={0.095*(1+2.9m*0)} Mtriode=0.3 Rd={0.6*(1+3m*0)}
+ Cgdmax=100p Cgdmin=5p a=0.25 Cgs=600p Cjo=1100p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH151206)
*
*
*
*10P20-25 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 10P20-25 VDMOS (pchan Rg=60 Vto={-0.535+1.7m*0} 
+ Rs={0.37*(1+3.4m*0)} Kp={0.995/(1+6.7m*0)} Rd=0.2
+ Ksubthres={0.12*(1+3.1m*0)} Mtriode=0.4 Lambda=5m
+ Cgdmax=215p Cgdmin=10p a=0.25 Cgs=900p Cjo=1200p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH151206)
*
*
*
*20N20-25 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 20N20-25 VDMOS (Rg=30 Vto={0.155-1.6m*0}
+ Rs={0.12*(1+2.5m*0)} Kp={2.40/(1+7.4m*0)}
+ Ksubthres={0.09*(1+1m*0)} Mtriode=0.3  Rd=0.16 Lambda=3m
+ Cgdmax=200p Cgdmin=10p a=0.25 Cgs=1200p Cjo=2200p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH151206)
*
*
*
*20P20-25 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 20P20-25 VDMOS (pchan Rg=30 Vto={-0.61+2.2m*0} 
+ Rs={0.17*(1+2.0m*0)} Kp={1.85/(1+8.4m*0)} 
+ Ksubthres={0.105*(1+5m*0)} Mtriode=0.35 Rd=0.05 Lambda=5m
+ Cgdmax=430p Cgdmin=20p a=0.25 Cgs=1800p Cjo=2400p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH151206)
*
*
**************************************************************
* For 75C
*
*10N20-75 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 10N20-75 VDMOS (Rg=60 Vto={0.17-1.6m*50} Lambda=3m
+ Rs={0.245*(1+2.6m*50)} Kp={1.30/(1+8.3m*50)}
+ Ksubthres={0.095*(1+2.9m*50)} Mtriode=0.3 Rd={0.6*(1+3m*50)}
+ Cgdmax=100p Cgdmin=5p a=0.25 Cgs=600p Cjo=1100p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH151206)
*
*
*
*10P20-75 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 10P20-75 VDMOS (pchan Rg=60 Vto={-0.535+1.7m*50} 
+ Rs={0.37*(1+3.4m*50)} Kp={0.995/(1+6.7m*50)} Rd=0.2
+ Ksubthres={0.12*(1+3.1m*50)} Mtriode=0.4 Lambda=5m
+ Cgdmax=215p Cgdmin=10p a=0.25 Cgs=900p Cjo=1200p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH151206)
*
*
*
*20N20-75 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 20N20-75 VDMOS (Rg=30 Vto={0.155-1.6m*50}
+ Rs={0.12*(1+2.5m*50)} Kp={2.40/(1+7.4m*50)}
+ Ksubthres={0.09*(1+1m*50)} Mtriode=0.3  Rd=0.16 Lambda=3m
+ Cgdmax=200p Cgdmin=10p a=0.25 Cgs=1200p Cjo=2200p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH151206)
*
*
*
*20P20-75 VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 20P20-75 VDMOS (pchan Rg=30 Vto={-0.61+2.2m*50} 
+ Rs={0.17*(1+2.0m*50)} Kp={1.85/(1+8.4m*50)} 
+ Ksubthres={0.105*(1+5m*50)} Mtriode=0.35 Rd=0.05 Lambda=5m
+ Cgdmax=430p Cgdmin=20p a=0.25 Cgs=1800p Cjo=2400p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH151206)
*
*
********************************************************
*		MOSFET VDMOS-Tjp Models with ksubthres
*
*
*10N20-Tjp VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 10N20-Tjp VDMOS (Rg=60 Vto={0.17-1.6m*(Tjp-25)} Lambda=3m
+ Rs={0.245*(1+2.6m*(Tjp-25))} Kp={1.30/(1+8.3m*(Tjp-25))}
+ Ksubthres={0.095*(1+2.9m*(Tjp-25))} Mtriode=0.3 Rd={0.6*(1+3m*(Tjp-25))}
+ Cgdmax=100p Cgdmin=5p a=0.25 Cgs=600p Cjo=1100p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH151206)
*
*
*
*10P20-Tjp VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 10P20-Tjp VDMOS (pchan Rg=60 Vto={-0.535+1.7m*(Tjp-25)} 
+ Rs={0.37*(1+3.4m*(Tjp-25))} Kp={0.995/(1+6.7m*(Tjp-25))} Rd=0.2
+ Ksubthres={0.12*(1+3.1m*(Tjp-25))} Mtriode=0.4 Lambda=5m
+ Cgdmax=215p Cgdmin=10p a=0.25 Cgs=900p Cjo=1200p  
+ m=0.7 VJ=2.5 IS=4.0E-6 N=2.4 mfg=IH151206)
*
*
*
*20N20-Tjp VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 20N20-Tjp VDMOS (Rg=30 Vto={0.155-1.6m*(Tjp-25)}
+ Rs={0.12*(1+2.5m*(Tjp-25))} Kp={2.40/(1+7.4m*(Tjp-25))}
+ Ksubthres={0.09*(1+1m*(Tjp-25))} Mtriode=0.3  Rd=0.16 Lambda=3m
+ Cgdmax=200p Cgdmin=10p a=0.25 Cgs=1200p Cjo=2200p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH151206)
*
*
*
*20P20-Tjp VDMOS with subthreshold (c) Ian Hegglun 06 Dec 2015
.model 20P20-Tjp VDMOS (pchan Rg=30 Vto={-0.61+2.2m*(Tjp-25)} 
+ Rs={0.17*(1+2.0m*(Tjp-25))} Kp={1.85/(1+8.4m*(Tjp-25))} 
+ Ksubthres={0.105*(1+5m*(Tjp-25))} Mtriode=0.35 Rd=0.05 Lambda=5m
+ Cgdmax=430p Cgdmin=20p a=0.25 Cgs=1800p Cjo=2400p 
+ m=0.7 VJ=2.5 IS=8.0E-6 N=2.4 mfg=IH151206)
*
*
**************************************************************
Attached Files
File Type: txt Hegglun-Lateral-models2.txt (4.3 KB, 240 views)
File Type: asc 20x20-quick.asc (2.1 KB, 157 views)
__________________
The Kmultiplier rail filter! -=- The Simple Kuartlotron Superbuffer!
Need something built, repaired or modded? PM me and ask what I can do!

Last edited by keantoken; 11th December 2015 at 02:19 PM.
  Reply With Quote

Reply


Better power MOSFET models in LTSpiceHide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

Similar Threads
Thread Thread Starter Forum Replies Last Post
LTSpice tube models Osvaldo de Banfield Software Tools 27 26th October 2013 06:04 AM
LTSpice models needed popilin Tubes / Valves 6 25th April 2013 12:08 AM
Adding models in LTSpice danny92 Software Tools 1 13th April 2013 10:05 PM
Ltspice and Valve models Melon Head Software Tools 3 18th October 2009 08:35 AM
2SJ and 2SK Power Mosfet Spice Models Requested alaskanaudio Everything Else 4 14th December 2001 01:14 AM


New To Site? Need Help?

All times are GMT. The time now is 06:56 PM.


Search Engine Optimisation provided by DragonByte SEO (Pro) - vBulletin Mods & Addons Copyright © 2019 DragonByte Technologies Ltd.
Resources saved on this page: MySQL 15.00%
vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2019 DragonByte Technologies Ltd.
Copyright ©1999-2019 diyAudio
Wiki