SPICE Models for STF3LN80K5 & STP3NK60ZFP

Jump to Latest
#2
Here is one for the STP3NK60Z. I'm sure I got it from the STMicroelectronics website, but that was years ago.

Code: 
* MODELLING FOR STP3NK60Z

.SUBCKT STP3NK60Z 1 2 3
LG 2 4  7.5n
LS 12 3 7.5n
LD 6 1  4.5n
RG 4 5  6.961
RS 9 12 0.119
RD 7 6  2.485
RJ 8 7  0.717E-01
CGS 5 9   0.353E-09
CGD 7 10  0.403E-09
CK  11 7  0.126E-10
DGD 11 7 DGD
DBS 12 6 DBS
DBD  9 7 DBD
MOS  13 5 9 9 MOS L=1u W=1u
E1  10 5 101 0 1
E2  11 5 102 0 1
E3  8 13 POLY(2) 6 8 6 12 0 0 0 0  0.471E-01
G1  0 100 7 5 1u
D1  100 101  DID
D2  102 100  DID
R1  101 0  1MEG
R2  102 0  1MEG

.MODEL MOS NMOS
+ LEVEL = 3
+ VTO   = 5.149
+ PHI   = 0.836
+ IS    = 0.1P
+ JS    = 0
+ THETA = 0.111E-02
+ KP    = 2.401

.MODEL DGD D
+ IS    = 0.1P
+ CJO   = 0.498E-11
+ VJ    = 0.721
+ M     = 0.308
.MODEL DBD D
+ IS    = 0.1P
+ CJO   = 0.692E-12
+ VJ    = 0.717
+ M     = 0.356
.MODEL DBS D
+ IS    = 0.1P
+ BV    = 620
+ N     = 1
+ TT    = 0.283E-06
+ RS    = 0.967E-01
.MODEL DID D
+ IS    = 0.01P
+ RS    = 0
+ BV    = 630

.ENDS STP3NK60Z

* END OF MODELLING
 
#3
Thanks Ray! It seems that the STM website has been updated or purged of some of these models. For example, the links to STM models from the Digikey site are now dead links. STM has relatively few models on their site now - at least that's what I see.
 
#4
Yes, STM used to have a fairly complete set of SPICE models available but now I couldn't even find the one I have.

I did find another potential source for PSpice models, although I didn't take the time to look around. LTspice can use most PSpice models without modification. You might check out this site. Note the link for STMicroelectronics models.

CMOS | PSpice
 
#5
Hi jmotzi,

Try these VDMOS. OK for LT-IV and XVIII.

Code: 
*VDMOS with subthreshold (c) Ian Hegglun
.model STP3N80K5_ VDMOS (Rg=15 Vto={5.6-(11m-1m)*(Temp-25)} Lambda=30m
+ Rs={150m*(1+3.5m*(Temp-25))} Kp={0.55*((Temp+273)/(25+273))**-(2.4-1.5) }
+ Ksubthres={0.2*(1+4m*(Temp-25))} Mtriode={0.3} Rd={2*(1+5m*(Temp-25))}
+ Cgdmax=100p Cgdmin=1p a=0.25 Cgs=130p Cjo=500p m=0.5 Vj=0.75
+ Is=0.25n N=1.3 Eg=1.15 Rb={90m*(1+3m*(Temp-25))}
+ Vds=800 Ron=2.8 Qg=9.5nC mfg=VishIH2102)

*VDMOS with subthreshold (c) Ian Hegglun
.model STP3NK60Z_ VDMOS (Rg=7 Vto={5.2-(10m-1m)*(Temp-25)} Lambda=5m
+ Rs={120m*(1+3.5m*(Temp-25))} Kp={2.5*((Temp+273)/(25+273))**-(2.4-1.5) }
+ Ksubthres={0.2*(1+4m*(Temp-25))} Mtriode={0.2} Rd={3*(1+5m*(Temp-25))}
+ Cgdmax=500p Cgdmin=10p a=0.25 Cgs=350p Cjo=400p m=0.5 Vj=0.75
+ Is=0.25n N=1.3 Eg=1.15 Rb={90m*(1+3m*(Temp-25))}
+ Vds=600 Ron=3.6 Qg=12nC mfg=VishIH2102)
Hopefully good enough for LF. Capacitances are best guess. Body diode very rough (not usually needed). Please let me know if anything needs changing.
 
You must log in or register to reply here.
Top Bottom