I have made a GU50 Pentode model by Ayumi's method with the
following conditions.
*Measured Ep-Ip data from the experimental data of (GU50.xls)
which is located in Next-Tube. Experimental data of vacuum tubes.
*Ayumi's method can handle Vg3=0V only.
The model obtained is as follows:
*
* Generic pentode model: GU50PP
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Mon Oct 07 15:38:35 2013
* Plate
* | Screen Grid
* | | Control Grid
* | | | Cathode
* | | | |
.SUBCKT GU50PP A G2 G1 K
BGG GG 0 V=V(G1,K)+0.99999999
BM1 M1 0 V=(0.095744324*(URAMP(V(G2,K))+1e-10))^-0.93076058
BM2 M2 0 V=(0.61709081*(URAMP(V(GG)+URAMP(V(G2,K))/3.9992887)))^2.4307606
BP P 0 V=0.001292662*(URAMP(V(GG)+URAMP(V(G2,K))/6.4808755))^1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.00082905208*V(M1)*V(M2)
BIG IG 0 V=0.00064633102*URAMP(V(G1,K))^1.5*(URAMP(V(G1,K))/(URAMP(V(A,K))+URAMP(V(G1,K)))*1.2+0.4)
BIK2 IK2 0 V=V(IK,IG)*(1-0.4*(EXP(-URAMP(V(A,K))/URAMP(V(G2,K))*15)-EXP(-15)))
BIG2T IG2T 0 V=V(IK2)*(0.957887127*(1-URAMP(V(A,K))/(URAMP(V(A,K))+10))^1.5+0.042112873)
BIK3 IK3 0 V=V(IK2)*(URAMP(V(A,K))+4395.2)/(URAMP(V(G2,K))+4395.2)
BIK4 IK4 0 V=V(IK3)-URAMP(V(IK3)-(0.00095677822*(URAMP(V(A,K))+URAMP(URAMP(V(G2,K))-URAMP(V(A,K))))^1.5))
BIP IP 0 V=URAMP(V(IK4,IG2T)-URAMP(V(IK4,IG2T)-(0.00095677822*URAMP(V(A,K))^1.5)))
BIAK A K I=V(IP)+1e-10*V(A,K)
BIG2 G2 K I=URAMP(V(IK4,IP))
BIGK G1 K I=V(IG)
* CAPS
CGA G1 A 0.1p
CGK G1 K 0.6p
C12 G1 G2 0.4p
CAK A K 10p
.ENDS
Attachments
GU50 Pentode Model vs Datasheet, Round 2
Using smoking-amp's triode-strapped curves with some minor adjustments, here is the result of the pentode model made with Ayumi's method vs. the datasheet. So the tubes probably came from that factory.
ja2dhc, I thought we are not suppose to post copyrighted material here... Perhaps, you can check with Nakabayashi-son to see if it is ok for us to do so, since I was told once on this very forum that it was not allowed (unless with permission from the copyright holder).
And sorry, I accidentally deleted the Koren spice model vs. the datasheet I posted earlier...
Using smoking-amp's triode-strapped curves with some minor adjustments, here is the result of the pentode model made with Ayumi's method vs. the datasheet. So the tubes probably came from that factory.
ja2dhc, I thought we are not suppose to post copyrighted material here... Perhaps, you can check with Nakabayashi-son to see if it is ok for us to do so, since I was told once on this very forum that it was not allowed (unless with permission from the copyright holder).
And sorry, I accidentally deleted the Koren spice model vs. the datasheet I posted earlier...
An externally hosted image should be here but it was not working when we last tested it.
Last edited:
I have been allowed to post the models derived from Ayumi's method
by him with the following condition.
Don't delete top 3 lines of the model. This parts is copyright
indication of Ayumi.
My version of triode model:
.SUBCKT GU50_T 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=3P CGP=1.4P CCP=1.9P RGI=2000
+ MU=5.8 KG1=870 KP=24 KVB=300 VCT=0.2 EX=1.34
* Vp_MAX=600 Ip_MAX=350 Vg_step=12 Vg_start=12 Vg_count=11
* Rp=4000 Vg_ac=55 P_max=45,2 Vg_qui=-48
* X_MIN=0 Y_MIN=0 X_SIZE=1438 Y_SIZE=838 FSZ_X=1936 FSZ_Y=1055 XYGrid=false
*----------------------------------------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$
taken from curves: diyaudio.com.hr • Pogledaj temu - GU50 amp - Potrebna pomoc
.SUBCKT GU50_T 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=3P CGP=1.4P CCP=1.9P RGI=2000
+ MU=5.8 KG1=870 KP=24 KVB=300 VCT=0.2 EX=1.34
* Vp_MAX=600 Ip_MAX=350 Vg_step=12 Vg_start=12 Vg_count=11
* Rp=4000 Vg_ac=55 P_max=45,2 Vg_qui=-48
* X_MIN=0 Y_MIN=0 X_SIZE=1438 Y_SIZE=838 FSZ_X=1936 FSZ_Y=1055 XYGrid=false
*----------------------------------------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$
taken from curves: diyaudio.com.hr • Pogledaj temu - GU50 amp - Potrebna pomoc
Must be this one from Ulyanov, Ulyanovsk. And it matches up pretty well with the datasheets found here.
Yes, the trademark is the same (the current model on right).
If you put some plus V (like +14 V) on g3, it looks like you can make the tubes conform to the Ayumi model around the knees.
I suspect there is some exponent parameter in the Ayumi model that could also be changed, to adjust the sharpness of the knees.
If you put some plus V (like +14 V) on g3, it looks like you can make the tubes conform to the Ayumi model around the knees.
I suspect there is some exponent parameter in the Ayumi model that could also be changed, to adjust the sharpness of the knees.
Last edited:
I am still learning to use Ayumi's pctube program, so have not messed with changing the model parameters, but you are right, certainly they could be tweaked to fit the curves better after the fact - call it post-curve fitting
Not sure if I'm opening up a can of worms here, but after looking at how the existing Leach/Koren/Ayumi models model the plate current curves near the knee, I haven't been particularly satisfied, and have been looking at developing a new pentode model based on some very simple functions. Having a look at the GU50 curves that were posted here, I calculated the parameters for my prototype model. This took me about half an hour to measure points off the chart and stick them into my spreadsheet. The result is in the attachment. There are some remaining glitches in the process, but I'm slowly getting it refined. If there's any interest in this, please let me know.
Attachments
That's the intention: one model to work for all (most?) pentodes. The idea is that the parameters can be determined quite simply from the published curves, although some final tweaking of parameters will most likely be required for optimum fit. The main drawback, at this point, is that there are more parameters than the Koren model. I have 9 or 10 parameters (depending on the version of the model).
I don't want to hijack this thread, so I'll start a new discussion, probably in the software tools section. It may take a day or two to organize my thoughts.
New topic started here: Oh No! Another Pentode ModelLooking forward to your results!
- Status
- This old topic is closed. If you want to reopen this topic, contact a moderator using the "Report Post" button.