Spice 3f4 model of a low voltage direct heated signal level pentode

[wa2ise]

Maybe you could build a DH phono preamp with the below...

Here's a low voltage filament tube CK538DX (crosses with DF650 and CK6419):


*Vacuum Tube filament pentode (voltages referenced to negative (pin 3) end of filament)
.SUBCKT XCK538DX A S G K
*
* Calculate contribution to cathode current
*
*the number at the right end determines sharpness of knee
Bat at 0 V=0.636*ATAN(V(A,K)/1)
*the URAMP(V(S,K)/# mostly determines peak plate current, grid line spacing nearly constant
*the number at the right end determines slope of grid lines (plate resistance)
Bgs gs 0 V=URAMP(V(S,K)/24.8+V(G,K)*0.35+V(A,K)/4000)
*the exponent sets the linearity of grid line spacing, and big impact on peak plate currrent
Bgs2 gs2 0 V=V(gs)^1.84
Bcath cc 0 V=V(gs2)*V(at)
*
* Calculate anode current, grid line spacing adjust and peak plate current
*
Ba A K I=3.335E-4*V(cc)
*
* Calculate screen current
*
Bscrn sc 0 V=V(gs2)*(1.25-V(at))
Bs S K I=0.04000E-2*V(sc)
*
* Grid current (approximation - does not model low va/vs)
*
Bg G K I=(URAMP(V(G,K)+1)^1.5)*50E-6
*
* Capacitances
*
Cg1 G K 2.4p
Cak A K 1.75p

Cg1a G A 0.08p

.ENDS XCK538DX

**********************************************************************************
More spice models:
http://home.netcom.com/~wb2jia/tubes/spice.txt
http://home.netcom.com/~wb2jia/tubes/spice2.txt
http://home.netcom.com/~wb2jia/tubes/spice3.txt
http://home.netcom.com/~wb2jia/tubes/spice4.txt