Hi all.
Having exhausted the searches with Google, I turn once again to the collective intelligence.
6GK5 - EC88 - E180F
Thanks in advance.
Having exhausted the searches with Google, I turn once again to the collective intelligence.
6GK5 - EC88 - E180F
Thanks in advance.
Code:
* 6GK5_GE LTSpice model
* Modified Koren model (5 parameters) 0.541547mA
* Traced by Wayne Clay 12-21-2012 using Curve Captor v0.9.1
* from General Electric data sheet
.subckt 6GK5_GE P G K
Bp P K I=(0.1613820387m)*uramp(V(P,K)*ln(1.0+exp((2.74630225)+(2.74630225)*(110.0938181)*V(G,K)/sqrt((5.036113112k)+(V(P,K))**2)))/(2.74630225))**(1.055422106)
Cgk G K 5.7p ; 0.7p added
Cpk P K 3.7p ; 0.2p added
Cgp G P 0.72p ; 0.2p added
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 6GK5_GE
and this one... 😉
Code:
* 6GK5_GE-GP LTSpice model
* Koren model(5 parameters): mean fit error 0.249882mA
* Traced by Wayne Clay 12-21-2012 using Curve Captor v0.9.1
* from General Electric data sheet grid-plate transfer curves
.subckt 6GK5_GE-GP P G K
Bp P K I=(0.1452046509m)*uramp(V(P,K)*ln(1.0+exp((2.802767885)+(2.802767885)*(107.6098728)*V(G,K)/sqrt((5.497494886k)+(V(P,K))**2)))/(2.802767885))**(1.077094947)
Cgk G K 5.7p ; 0.7p added
Cpk P K 3.7p ; 0.2p added
Cgp G P 0.72p ; 0.2p added
.ends 6GK5_GE-GP
EC88:
If you have trouble with convergence with this model, try adding a reversed bias diode from grid to cathode.
Code:
* ---------------------------------------------------------------------
* EC88 UHF triode LTSpice model
* Modified Koren model (8 parameters) mean fit error 0.199402mA
* Traced by Wayne Clay on 09/09/2007 using Curve Captor v0.9.1
* from La RadioTechnque data sheet
* ---------------------------------------------------------------------
.subckt EC88 P G K
Bp P K I=(0.1461968258m)*uramp(V(P,K)*ln(1.0+(-0.1091553585)+exp
+ ((2.636947214)+(2.636947214)*((76.1162895)+(-3207.840539m)*V(G,K))*
+ V(G,K)/sqrt((62.88763962)**2+(V(P,K)-(26.31911466))**2)))/
+ (2.636947214))**(1.054580966)
Cgp G P 2.4p ; 0.7p added
Cgk G K 4.5p ; 0.7p added
Cpk P K 0.255p ; 0.2p added
.ends EC88
If you have trouble with convergence with this model, try adding a reversed bias diode from grid to cathode.
Last edited:
Got this one from reVintage a while back.
Code:
.SUBCKT E180F 1 4 2 3
+ PARAMS: MU= 56.00 EX= 1.350 KG1= 250.0 KP=6709.19 KC= 850
+ KVB= 7.9 VCT= 0.00 RGI=2k
+ CCG=8.5P CPG1=0.03P CCP=3P
RE1 7 0 1G
RE2 8 3 1G
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
G2 8 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KC*(2.5708-ATAN(V(1,3)/KVB))}
E2 8 4 VALUE={0}
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CPG1} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
- Status
- Not open for further replies.
- Home
- Amplifiers
- Tubes / Valves
- LTSpice models needed