And thespice model.
Hmmm...
Attachments
The text is copied directly from my LT spice INC file , and it works for me, Strange..Hmmm...
This is why it's always a good idea to use the code box for models, subckts etc. Click advanced on your reply/post and you'll see the "#" button.The text is copied directly from my LT spice INC file , and it works for me, Strange..
Like this:
Code:
* TML300b LTSpice model corrected by 1/2 heater volt
* Modified Koren model (8 parameters): mean fit error 0,8mA
* Traced by erik 25/12/2013 using Curve Captor v0.9.1
* pentaTJ300B LTSpice model
* pentaEML300b LTSpice model
.subckt pentaEML300b P G K
Bp P K I=(0.1471360425m)*uramp(V(P,K)*ln(1.0+(-0.0836812242)+exp((14.77238937)+(14.77238937)*((4. 010010839)+(0.03955144628m)*V(G,K))*V(G,K)/sqrt((2.786333203e-006)**2+(V(P,K)-(2.303526987))**2)))/(14.77238937))**(1.48386058)
Cgk G K 8.5p ; 0.2p added
Cpk P K 4.6p ; 0.5p added
Cgp G P 15.5p ; 0.5p added
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends pentaEML300b
12U7 LTspice model
Here's a 12U7 model fresh from the oven. I don't have one for the 12K5. I'm assuming you need an LTspice model.
Here's a 12U7 model fresh from the oven. I don't have one for the 12K5. I'm assuming you need an LTspice model.
Code:
* ==============================================================
* 12U7 LTSpice model
* Modified Koren model (8 parameters): mean fit error 0.0424612mA
* Traced by Wayne Clay on 10/19/2017 using Curve Captor v0.9.1 and
* Engauge Digitizer from Sylvania datasheet
.subckt 12U7 P G K
Bp P K I=
+ (0.02785936343m)*uramp(V(P,K)*ln(1.0+(-0.004710347468)+exp((0.5642928568)+
+ (0.5642928568)*((47.72916363)+(-6781.211301m)*V(G,K))*V(G,K)/sqrt((16.01863303)**2+
+ (V(P,K)-(6.398929653))**2)))/(0.5642928568))**(1.155518036)
Cgp G P 2.2p ; 0.7p added (1.5p)
Cgk G K 2.3p ; 0.7p added (1.6p)
Cpk P K 0.6p ; 0.2p added (0.4p)
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 12U7
12U7 model for Tina
This should work in Tina. I don't have Tina on this Linux box, so I can't test it.Oh man! thanks so much! Looking forward to the 12K5 model.
I use Tina.
Best Regards,
Dirk
Code:
*
* 12U7 Spice 3F4 Tina model
* Modified Koren model (8 parameters): mean fit error 0.0424612mA
* Traced by Wayne Clay on 10/19/2017 using Curve Captor v0.9.1 and
* Engauge Digitizer from Sylvania datasheet
* Plate
* | Grid
* | | Cathode
* | | |
.subckt 12U7 P G K
Bp P K I=
+ (0.02785936343m)*uramp(V(P,K)*ln(1.0+(-0.004710347468)+exp((0.5642928568)+
+ (0.5642928568)*((47.72916363)+(-6781.211301m)*V(G,K))*V(G,K)/sqrt((16.01863303)^2+
+ (V(P,K)-(6.398929653))^2)))/(0.5642928568))^(1.155518036)
Cgp G P 2.2p ; 0.7p added (1.5p)
Cgk G K 2.3p ; 0.7p added (1.6p)
Cpk P K 0.6p ; 0.2p added (0.4p)
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 12U7
Last edited:
I'm wondering if there is a 6JC6 pentode model out there anywhere. I can't seem to find one. smoking_amp did post a set of triode curves in another thread:
2 mA/div Vert., 50 V/div. Horiz.
6JC6 triode curves, 0.5 V steps:
6JC6 pentode curves 0.15V steps, 92 Vg2
Here's the best data sheet I could find for 6JC6:
http://rtellason.com/tubedata/6JC6.PDF
https://frank.pocnet.net/sheets/049/6/6JC6.pdf
I can't find much data on this tube type. I'm hoping a model can be put together from these scraps. Thanks in advance.
--
2 mA/div Vert., 50 V/div. Horiz.
6JC6 triode curves, 0.5 V steps:
6JC6 pentode curves 0.15V steps, 92 Vg2
Here's the best data sheet I could find for 6JC6:
http://rtellason.com/tubedata/6JC6.PDF
https://frank.pocnet.net/sheets/049/6/6JC6.pdf
I can't find much data on this tube type. I'm hoping a model can be put together from these scraps. Thanks in advance.
--
Last edited:
Going back to the well... I hope not too many times.
It turns out there's an interesting high mu RF triode called 6J4 (not to be confused with the Russian 6J4P pentode). American 6J4 or 6J4W is the same as 8532 or 8532W. This looks like a very capable little tube. Might be good as the input stage in a phono preamp.
Fortunately, there is a data sheet with triode curves.
https://frank.pocnet.net/sheets/049/8/8532.pdf
I found only one model out there on the innerwebs, but it doesn't look promising to me. Here is that one:
Is that one good enough to be used with confidence?
--
It turns out there's an interesting high mu RF triode called 6J4 (not to be confused with the Russian 6J4P pentode). American 6J4 or 6J4W is the same as 8532 or 8532W. This looks like a very capable little tube. Might be good as the input stage in a phono preamp.
Fortunately, there is a data sheet with triode curves.
https://frank.pocnet.net/sheets/049/8/8532.pdf
I found only one model out there on the innerwebs, but it doesn't look promising to me. Here is that one:
Code:
* 6J4 RF Triode LTspice model
*
.subckt 6J4 1 6 3
+ params: mu=94.8 ex=1.274 kg1=103 kp=153 kvb=792 rgi=2000 vct=.122
+ ccg=5.5p cgp=4.0p ccp=5.0p
e1 7 0 value=
+{v(1,3)/kp*log(1+exp(kp*(1/mu+v(2,3)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1g
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1g
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
v1 5 6 {vct}
d3 6 3 dx
.model dx d(is=1n rs=1 cjo=1pf tt=1n)
.ends
Is that one good enough to be used with confidence?
--
6J4WA/8532 LTspice model
@rongon, try this one, it's fairly close.
@rongon, try this one, it's fairly close.
Code:
* 6J4WA/8532 LTSpice model
* Koren model (5 parameters): mean fit error 0.307023mA
* Traced by Wayne Clay on 10/21/2017 using Curve Captor v0.9.1 and
* Engauge Digitizer from RCA 6J4WA/8532 datasheet
.subckt 6J4WA P G K
Bp P K I=
+ (0.06966747418m)*uramp(V(P,K)*ln(1.0+exp((2.926315606)+
+ (2.926315606)*(72.64172476)*V(G,K)/sqrt((0.1832532151k)+
+ (V(P,K))**2)))/(2.926315606))**(1.252675985)
Cgp G P 4.7p ; 0.7p added (4.0p)
Cgk G K 6.2p ; 0.7p added (5.5p)
Cpk P K 0.44p ; 0.2p added (0.24p)
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 6J4WA
Attachments
12B4 SPICE Model
Code:
*
* Generic triode model: 12B4_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Wed Oct 25 19:11:01 2017
* Anode
* | Grid
* | | Cathode
* | | |
.SUBCKT 12B4_AN A G K
BGG GG 0 V=V(G,K)+0.99633808
BM1 M1 0 V=(0.08624954*(URAMP(V(A,K))+1e-10))**-1.1787665
BM2 M2 0 V=(0.55995921*(URAMP(V(GG)+URAMP(V(A,K))/5.1019494)+1e-10))**2.6787665
BP P 0 V=0.0045829947*(URAMP(V(GG)+URAMP(V(A,K))/9.1112876)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0034496543*V(M1)*V(M2)
BIG IG 0 V=0.0022914974*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0030663387*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 4.8p
CGK G K 5p
CAK A K 1.5p
.ENDS
- Home
- Amplifiers
- Tubes / Valves
- Vacuum Tube SPICE Models