• WARNING: Tube/Valve amplifiers use potentially LETHAL HIGH VOLTAGES.
    Building, troubleshooting and testing of these amplifiers should only be
    performed by someone who is thoroughly familiar with
    the safety precautions around high voltages.

Vacuum Tube SPICE Models

Jump to Latest
jazbo8

jazbo8

Ex-Moderator
Joined 2011
Many russian tube datasheets are available at klausmobile, including the 6P36S.

_6p36s.GIF
 
dirkwright

dirkwright

Member
Joined 2011
Please help. I have Tina and I get an error "line 61: missing left parenthesis" in this 6N1P model:

Code: 
*-----------------------------------------------------------------------
* Filename:		6N1P.inc  V1  25/10/97
* Simulator:		PSpice
* Device type:		Triode
* Device model:		Svetlana 6N1P
*
* Author:		Duncan Munro
* Date:			25/10/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT 6N1P A G K

************************************************************************
*
* Anode model
*
* Models reduction in mu at large negative grid voltages
* Models change in Ra with negative grid voltages
* Models limit in Ia with high +Vg and low Va
*
* PARAMETERS
*
*	LIP Conduction limit exponent
*	LIF Conduction limit factor
*	RAF Anode resistance factor for neg grid voltages
*	RAP Anode resistance factor for positive grid voltages
*	MU0 Mu between grid and anode at Vg=0
*	MUR Mu reduction factor for large negative grid voltages
*	EMC Emission coefficient
*	GCF Grid current scale factor
*
************************************************************************

.PARAM LIP 1
.PARAM LIF 1E-3
.PARAM RAF 9E-3
.PARAM RAP 4E-3
.PARAM MU0 38
.PARAM MUR 19E-3
.PARAM EMC 9.6E-6
.PARAM GCF 213E-6
Elim  LI 0  VALUE {PWR(LIMIT{V(A,K),0,1E6},{LIP})*{LIF}}
Erpf  RP 0  VALUE {1+LIMIT{V(G,K),0,-1E6}*{RAF}+LIMIT{V(G,K),0,1E6}*{RAP}}
Egr   GR 0  VALUE {LIMIT{V(G,K),0,1E6}+LIMIT{V(G,K)*(1+V(G,K)*{MUR}),0,-1E6}}
Eem   EM 0  VALUE {LIMIT{V(A,K)*V(RP)+V(GR)*{MU0},0,1E6}}
Eep   EP 0  VALUE {PWR(V(EM),1.5)*{EMC}}
Eel   EL 0  VALUE {LIMIT{V(EP),0,V(LI)}}
Eld   LD 0  VALUE {LIMIT{V(EP)-V(LI),0,1E6}}
Ga    A  K  VALUE {V(EL)}

************************************************************************
*
* Grid current model
*
* Models grid current, along with rise in grid current at low Va
*
************************************************************************
Egf   GF 0  VALUE {PWR(LIMIT{V(G,K),0,1E6},1.5)*{GCF}}
Gg    G  K  VALUE {(V(GF)+V(LD))}

*
* Capacitances
*
Cgk	G	K	2.4p
Cga	A	G	3.9p
Cak	A	K	0.7p

.ENDS

I can't find an error. Any help is appreciated. Thanks.
 
dirkwright

dirkwright

Member
Joined 2011
jazbo8 said:
Try this one instead.
Click to expand...

Thanks, but Tina doesn't like the "**" in it. I tried to replace all of them with EXP but it still doesn't work.

Code: 
*
* Generic triode model: 6N1P_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sun Jan 12 18:59:00 2014
*               Plate
*               | Grid
*               | | Cathode
*               | | |
.SUBCKT 6N1P_AN A G K
BGG   GG   0 V=V(G,K)+-0.42063507
BM1   M1   0 V=(0.007566675*(URAMP(V(A,K))+1e-10))**-0.43818786
BM2   M2   0 V=(0.77391879*(URAMP(V(GG)+URAMP(V(A,K))/29.878541)+1e-10))**1.9381879
BP    P    0 V=0.0022884667*(URAMP(V(GG)+URAMP(V(A,K))/38.606817)+1e-10)**1.5
BIK   IK   0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0013346379*V(M1)*V(M2)
BIG   IG   0 V=0.0011442333*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK  A    K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.001233721*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK  G    K I=V(IG)
* CAPS
CGA   G    A 1.6p
CGK   G    K 3.2p
CAK   A    K 1.5p
.ENDS
 
jazbo8

jazbo8

Ex-Moderator
Joined 2011
Ah, the stupid SPICE syntax again... that one was for LTSpice, try the following one for TINA:

Code: 
*
* Generic triode model: 6N1P_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sun Jan 12 18:59:00 2014
*               Plate
*               | Grid
*               | | Cathode
*               | | |
.SUBCKT 6N1P_AN A G K
.PARAM X1=-0.42063507 X2=0.007566675 X3=-0.43818786
.PARAM X4=0.77391879 X5=29.878541 X6=1.9381879
.PARAM X7=0.0022884667 X8=38.606817 X9=0.0013346379
.PARAM Y1=0.0011442333 Y2=0.001233721
BK IK 0 V=U(V(G,K)+X1)*X7*URAMP(V(G,K)+X1+URAMP(V(A,K))/X8)^1.5+(1-U(V(G,K)+X1))*X9*(X2*URAMP(V(A,K)))^X3*(X4*URAMP(V(G,K)+X1+URAMP(V(A,K))/X5))^X6
BA A K I=URAMP((Y2*URAMP(V(A,K))^1.5)-URAMP((Y2*URAMP(V(A,K))^1.5)-V(IK)+Y1*URAMP(V(G,K))^1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+.4)))+1E-10*V(A,K)
BG G K I=Y1*URAMP(V(G,K))^1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+.4)
* CAPS
CGA G A 1.6p
CGK G K 3.2p
CAK A K 1.5p
.ENDS
 
B

buildafriend

Member
Joined 2010
Hi,

I am new to tube circuit simulation and I am looking for tube models with syntax that works well in Tina. Are the models generally cross compatible since they are all spice based? I am under the impression that some work better than others in LT spice, and that some work better than others in Tina. Do you tube circuit sim lovers suggest I try to advance in Tina or in LTspice? I'm starting small with a fender champ 5F1 and then I would like to work my way up into bigger simulations. I have a 12AX7 model, so now I need 6V6GT and the power tube model 5Y3GT. I know that in the future I will need 6FQ7, 6L6GC, and probably KT88.

Thanks regardless - Jon
 
Last edited:
jazbo8

jazbo8

Ex-Moderator
Joined 2011
buildafriend said:
Are the models generally cross compatible since they are all spice based?
Click to expand...
No, they are usually NOT compatible.

I am under the impression that some work better than others in LT spice, and that some work better than others in Tina.
Click to expand...
Sometimes that is the case.

Do you tube circuit sim lovers suggest I try to advance in Tina or in LTspice?
Click to expand...

Given the popularity of LTSpice and its Yahoo user group support, it is probably the one I would recommend. Many amplifiers are available for download at the user group, which should make it easy for you to simulate and/or modify for your own circuits.
 
dirkwright

dirkwright

Member
Joined 2011
jazbo8 said:
Dr. Reefman's models using the uTracer & ExtractModel is available here, now it even includes heptodes!
Click to expand...

I'm a little confused by these macro models. They look more like the transistor models I've seen rather than the tube ones, where the model is just a list of specifications instead of equations and other things. I see now at the bottom there are the usual macro models for generic pentodes, triodes, etc. Am I supposed to copy the generic model for the particular tube I'm interested in, and then add on the specific parameter model in one file and then compile it? Sorry for the newbie questions.
 
Last edited:
dirkwright

dirkwright

Member
Joined 2011
Tube noise in spice

How does spice handle tube noise? In Tina, I know that the resistors and semiconductors incorporate noise sources, but I don't know about tube models.

Here is a thread about a new article from the JAES about finally getting a mathematical expression for total noise in vacuum tubes:
http://www.diyaudio.com/forums/tube...r-noise-dominates-triode-noise-audio-aes.html

Is it possible to incorporate his equation into a spice macro model for tubes? Is it needed? His equation includes a prediction for flicker noise in tubes, which up to now has been extremely difficult to determine mathematically.
 
You must log in or register to reply here.
Top Bottom