LTSPICE problems with 10Y model

[synchro27]

Hi, having a hard time getting this subcircuit for the 10Y to work in LTSPICE:

getting run errors such as "RGI unknown"

does anyone have a 10Y subcircuit that runs in LTSPICE without problems, or can tell me how to correct this subcircuit so it will run?

.SUBCKT 10Y 1 2 3; A G C
E1 7 0 VALUE=
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

 

[tikiroo]

You are missing the parameters, try this:

.SUBCKT 10Y 1 2 3; A G C
+params: MU=8.07 EX=1.571 KG1=5297.4 KP=141 KVB=111 RGI=2000
+ CCG=3.0P CGP=7.0P CCP=4.0P
E1 7 0 VALUE=
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

 

[synchro27]

Thanks!! Much appreciated!!!

I just saw the zip files for the tube models also - the sticky - I'm going to download that, unzip it, fix them, and post them somewhere ready to copy out.