UJN1208k LTspice model

Status
Not open for further replies.
Jump to Latest
#2
**************************************************************************
* USCi 1200 V SiC JFET Spice Circuit Model v3.6
* Copyright 2015 United Silicon Carbide, Inc.
* This is an empirical model of USCi 1200 V JFETs based on typical characteristics of
* the device shown in the datasheet and is not warranted by USCi as fully
* representing all of the specifications and operating characteristics of the device.
* It's accuracy is best in the the linear mode of operation and for switching
* characteristics. The accuracy degrades when used in saturation.
* It includes temperature effects from 25 to 175 C Junction Temperature.
*
* The model does not include all possible conditions and effects,
* in particular it doesn't include:
* Self heating
* leakage current in blocking state
* Drain to source breakdown is notional only
*
* ujn series Drain Gate Source
**************************************************************************
.SUBCKT ujn1208k Drain Gate Source PARAMS:
+ beta=3.16 beta_tce=-30 vth=-7.892 vth_tc=4.0e-4
+ npow=1.4480 npow_tc=-0.800e-04 lambda0=0.045 lambda1=-9.500e-02
+ alpha=1.800 alpha_tc=-3.000e-03
+ cdsa0=4e-12 cds0=4.1e-12 is0g=0.7000e-14
+ cgda0=19e-12 cgd0=500e-12 cgd_FC=0.94 cgd_M=0.70 cgd_VJ=2.7
+ cgsa0=14e-12 cgs0=550e-12 cgs_FC=0.94 cgs_M=0.53 cgs_VJ=2.7
*Parasitics
LD Drain D 5n
R_RD D Dint 0.001
LS Source S 3n
R_RS S Sint 0.001
LG Gate G 3n
R_RG G Gint 0.5
R_RGAC1 Gint Gjd 1.5
R_RGAC2 Gjd Gjs 2.75
X_IDS Gjd Dint Sint IDJFET PARAMS: beta={beta} lambda0={lambda0} lambda1={lambda1}
X_IGS Gint Gjd Sint IGATETOSOURCE
*Current
DBDD Gjd Dint DDBRKDWN
DBDS Gjd Sint DSBRKDWN
DDGI Gjd Dint DGI
DDGSI Gjd Sint DGSI
*Capacitance
DGD Gjd Dint Diodecgd
CGDa Gjd Dint {0.5*cgda0}
DGD2 Gjs Dint Diodecgd
CGDb Gjs Dint {0.5*cgda0}
DGS Gjs Sint Diodecgs
CGSa Gjs Sint {0.5*cgsa0}
DGS2 Gjd Sint Diodecgs
CGSb Gjd Sint {0.5*cgsa0}
CDSint Dint Sint {cdsa0}
CGSint Gint Sint 1e-13
CDS D S 1e-13
CGD G D 1e-13
CGS G S 1e-13

.Model DGI D IS=5.6e-20 N=5.8 XTI=7 ISR=0 NR=2.9 VJ=12.7 CJO=0 Rs=.9
.Model DGSI D EG=3.26 IS=0.700e-14 N=3.71 XTI=15 ISR=0 CJO=0 Rs=.1
.MODEL DDBRKDWN D IS=1e-40 ISR=0 N=1000 IBV=1.133 NBV=4.004e2 BV=1600 TBV1=1e-6 Rs=0.2
.MODEL DSBRKDWN D EG=3.26 IS=1e-40 XTI=1 N=1000 ISR=0 IBV=1.823e-6 NBV=87.54 BV=45 Rs=0.2
.MODEL Diodecgd D IS=1e-40 XTI=1 N=1000 ISR=0 CJO={cgd0} EG=3.26 FC={cgd_FC} M={cgd_M} VJ={cgd_VJ} IKF=0 RS=0.2
.MODEL Diodecgs D IS=1e-40 XTI=1 N=1000 ISR=0 CJO={cgs0} EG=3.26 FC={cgs_FC} M={cgs_M} VJ={cgs_VJ} RS=0.2
.ENDS ujn1208k

.SUBCKT IGATETOSOURCE 1 2 3 PARAMS: is0g=1.5000e-14
.param is0_tc=0.0000e+00
.param ngs=3.7100 ngs_tc=0.0020
.param xti=1.5e+01
.param egap=3.2600
.param egapt1=1.0000e+05
.param egapt2=3.3000e-02
.func ratio_t() {(TEMP+273.15)/(300)}
.func vt() {1.38e-23*(TEMP+273.15)/1.602e-19}
.func egap_t() {egap-(egapt2*((TEMP+273.15)*(TEMP+273.15)))/((TEMP+273.15)+egapt1)}
.func is_t() {is0g*PWR(ratio_t(),(xti/ngs)) *EXP((ratio_t()-1)*(egap_t()/(ngs*vt())))}
*.func IGS(vgs) {is_t()*(EXP(vgs/(ngs*vt())) - 1)}
.func IGS(vgs) {is_t()*(1)}
G_GS 1 3 VALUE = {IGS(V(2,3))}
.ENDS IGATETOSOURCE

* JFET drain current
.SUBCKT IDJFET Gate Drain Source PARAMS: beta=5.28 beta_tce=-30 vth=-7.892 vth_tc=4.0e-4
+ npow=1.4480 npow_tc=-5.0000e-04 lambda0=0.05 lambda1=-1.1000e-01
+ alpha=1.8000 alpha_tc=-3.0000e-03
* Calculate Temperature Dependent Parameters
.func delta_t() {TEMP - 27}
.func beta_t() {beta*PWR(1.0001, beta_tce*delta_t())}
.func vth_t() {vth * (1 + vth_tc * delta_t())}
.func npow_t() {npow * (1 + npow_tc * delta_t())}
.func alpha_t() {alpha * (1 + alpha_tc * delta_t())}
* Calculate the terms of the ID equation
.func vod(vgs) {if((vgs-vth_t()>0), (vgs-vth_t()),(vgs-vth_t()-1e-15 ))}
.func npow_term(vgs) {PWR(vod(vgs),npow_t())}
**(1+lambda1*vod(vgs))}
.func lambda_factor(vds,vgs,vds_term) {if((vds_term>0), 1+lambda0*abs(vds)*(1+lambda1*vod(vgs)*0), 1+lambda0*abs(vds))}
.func tanh_term(vds,vgs) {tanh(alpha_t()*vds/vod(vgs))}
.func IDSEQ(vds,vgs,vds_term) {if(vgs>vth_t(),(beta_t()*npow_term(vgs)*tanh_term(vds,vgs)*(lambda_factor(vds, vgs,vds_term))), 0)}
.func IDS(vds,vgs,vgd) {IF((vds>0), (IDSEQ(vds,vgs,vds)+ vds/5e6), -0.8*(IDSEQ(-vds,vgd,vds)+ vds/5e6) )}
G_DS Drain Source VALUE = {IDS(V(Drain,Source),V(Gate,Source),V(Gate,Drain))}
.ENDS IDJFET
*
 
#6
Hi Moderator,

Moving this thread without comment or explanation or even notification is a bit `enthusiastic'.
This particular device is of interest to people in the Pass forum and this request is not unlike multiple other threads posted there in the past.
 
Status
Not open for further replies.
Top Bottom