ua739 SPICE model

[jackinnj]

I know it's an obsolete part, came up in another discussion. ua739 is also used in the Crown DC-300 amplifier. I cobbled this together from the Fairchild datasheet:

* CONNECTIONS: NON-INVERTING INPUT
* | INVERTING INPUT
* | | NEG POWER SUPPLY
* | | | POZ POWER SUPPLY
* | | | | OUTPUT
* | | | | | LAG3
* | | | | | |
* | | | | | | LAG4
* | | | | | | |
* | | | | | | | LAG2
* | | | | | | | |
.SUBCKT UA739 1 2 3 4 5 6 7 8
*
D1 4 17 DX
D2 17 16 DX
D3 16 15 DX
D4 15 14 DX
R6 4 13 200
R5 4 9 9k
Q7 5 9 13 QP
Q5 9 6 10 QN
Q6 10 11 12 QN
R4 12 3 1.7k
Q4 4 7 10 QN
Q1 7 1 21 QN
R1 14 7 10k
R2 14 6 10k
Q2 6 2 21 QN
Q3 21 11 22 QN
R3 22 3 3k
R9 14 11 15k
D5 11 20 DX
D6 20 3 DX
R739 5 3 5000
.MODEL DX D(Is=0.1p Rs=1.6 CJO=2p Tt=12n Bv=100 Ibv=0.1p)
.MODEL QN NPN(Is=26.03f Xti=3 Eg=1.11 Vaf=90.7 Bf=7.756K Ne=1.204
+ Ise=26.7f Ikf=.2397 Xtb=1.5 Br=1.06 Nc=2 Isc=0 Ikr=0 Rc=.5
+ Cjc=11.01p Mjc=.3763 Vjc=.75 Fc=.5 Cje=24.07p Mje=.3641 Vje=.75
+ Tr=244n Tf=573.2p Itf=0 Vtf=0 Xtf=0 Rb=10)
.MODEL QP PNP(Is=650.6E-18 Xti=3 Eg=1.11 Vaf=115.7 Bf=216.2 Ne=1.829
+ Ise=58.72f Ikf=1.079 Xtb=1.5 Br=3.578 Nc=2 Isc=0 Ikr=0 Rc=.715
+ Cjc=14.76p Mjc=.5383 Vjc=.75 Fc=.5 Cje=19.82p Mje=.3357 Vje=.75
+ Tr=111.6n Tf=603.7p Itf=.65 Vtf=5 Xtf=1.7 Rb=10)
.ENDS

 

[T117]

I built the full schematics of this opamp. Turned out to be quite close to reality. However, the simulator calculates the distortion is very slow due to the complexity of the overall schematics. But the results regarding THD be more reliable.