Hello :
try this one
* 6BX7 - IDH medium-mu high-transconductance twin Bp A K I=(m)*uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters): mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*uramp(V(A,K)*ln(1.0+(-0.1116255831)+exp((3.282351583)+(3.282351583)*((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/(3.282351583))**(1.44441018)
.ends mk_6BX7
I do not remember where I got this model, I think it was from a thread here about how Koren's 5 parameter model could be improved with 6, 7 or 8 parameters.
try this one
* 6BX7 - IDH medium-mu high-transconductance twin Bp A K I=(m)*uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters): mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*uramp(V(A,K)*ln(1.0+(-0.1116255831)+exp((3.282351583)+(3.282351583)*((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/(3.282351583))**(1.44441018)
.ends mk_6BX7
I do not remember where I got this model, I think it was from a thread here about how Koren's 5 parameter model could be improved with 6, 7 or 8 parameters.
splitting up SPICE lines
The method for splitting up SPICE lines is to use a "+" at the start of the next line. This marks it as the start of a continuation line. It can be a bit confusing ( to a human reader, not to spice) knowing if the + is a continuation sign, or a normal addition sign, so I put lots of spaces in to show it is a continuation
So here is the same code with shorter lines :
* 6BX7 - IDH medium-mu high-transconductance twin
* Bp A K I=(m)* uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters):
* mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*uramp(V(A,K)*ln(1.0+(-
+ 0.1116255831)+exp((3.282351583)+(3.282351583)*
+ ((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt
+ ((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/
+ (3.282351583))**(1.44441018)
.ends mk_6BX7
that should work now.
Interesting note : when I preview this message, the extra spaces I put in have disappeared. This wont affect how the model works.
Sorry about that, I should have noticed when I posted the message that the lines had wrapped around, and were not continued correctly.ERROR -- Line too long. Limit is 132 characters.
The method for splitting up SPICE lines is to use a "+" at the start of the next line. This marks it as the start of a continuation line. It can be a bit confusing ( to a human reader, not to spice) knowing if the + is a continuation sign, or a normal addition sign, so I put lots of spaces in to show it is a continuation
So here is the same code with shorter lines :
* 6BX7 - IDH medium-mu high-transconductance twin
* Bp A K I=(m)* uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters):
* mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*uramp(V(A,K)*ln(1.0+(-
+ 0.1116255831)+exp((3.282351583)+(3.282351583)*
+ ((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt
+ ((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/
+ (3.282351583))**(1.44441018)
.ends mk_6BX7
that should work now.
Interesting note : when I preview this message, the extra spaces I put in have disappeared. This wont affect how the model works.
Here's another:
* Generic triode model: 6BX7
* Copyright 2003--2006 by Ayumi Nakabayashi, All rights reserved.
* Version 3.01, Generated on Wed Mar 22 17:19:49 2006
.SUBCKT 6BX7 A G K
BGG GG 0 V=V(G,K)+0.99999999
BEP EP 0 V=URAMP(V(A,K))+1e-10
BEG EG 0 V=URAMP(V(G,K))+1e-10
BM1 M1 0 V=(0.044756942*(URAMP(V(EP)-1e-10)+1e-10))^-0.87869992
BM2 M2 0 V=(0.63059657*(URAMP(V(GG)+V(EP)/8.253545)+1e-10))^2.3786999
BP P 0 V=0.0032697035*(URAMP(V(GG)+V(EP)/13.088471)+1e-10)^1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0020437592*V(M1)*V(M2)
BIG IG 0 V=0.0016348517*V(EG)^1.5*(V(EG)/(V(EP)+V(EG))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0020166439*V(EP)^1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 4.2p
CGK G K 4.8p
CAK A K 1.2p
.ENDS
* Generic triode model: 6BX7
* Copyright 2003--2006 by Ayumi Nakabayashi, All rights reserved.
* Version 3.01, Generated on Wed Mar 22 17:19:49 2006
.SUBCKT 6BX7 A G K
BGG GG 0 V=V(G,K)+0.99999999
BEP EP 0 V=URAMP(V(A,K))+1e-10
BEG EG 0 V=URAMP(V(G,K))+1e-10
BM1 M1 0 V=(0.044756942*(URAMP(V(EP)-1e-10)+1e-10))^-0.87869992
BM2 M2 0 V=(0.63059657*(URAMP(V(GG)+V(EP)/8.253545)+1e-10))^2.3786999
BP P 0 V=0.0032697035*(URAMP(V(GG)+V(EP)/13.088471)+1e-10)^1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0020437592*V(M1)*V(M2)
BIG IG 0 V=0.0016348517*V(EG)^1.5*(V(EG)/(V(EP)+V(EG))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0020166439*V(EP)^1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 4.2p
CGK G K 4.8p
CAK A K 1.2p
.ENDS
This time I got a different error:
**** EXPANSION OF SUBCIRCUIT X_VL1 ****
X_VL1.Cgp N731296 X_VL1.P 4.2p
X_VL1.Ci N731296 N604658 4.4p
X_VL1.Co N604270 N604658 1.1p
X_VL1.Bp N604270 N604658 X_VL1.I X_VL1.0.1001852541m *uramp
-----------------------------------------------------$
ERROR -- Invalid parameter
Is Orcad Spice different from what your guys use?
**** EXPANSION OF SUBCIRCUIT X_VL1 ****
X_VL1.Cgp N731296 X_VL1.P 4.2p
X_VL1.Ci N731296 N604658 4.4p
X_VL1.Co N604270 N604658 1.1p
X_VL1.Bp N604270 N604658 X_VL1.I X_VL1.0.1001852541m *uramp
-----------------------------------------------------$
ERROR -- Invalid parameter
Is Orcad Spice different from what your guys use?
pftrvlr said:This time I got a different error:
**** EXPANSION OF SUBCIRCUIT X_VL1 ****
X_VL1.Cgp N731296 X_VL1.P 4.2p
X_VL1.Ci N731296 N604658 4.4p
X_VL1.Co N604270 N604658 1.1p
X_VL1.Bp N604270 N604658 X_VL1.I X_VL1.0.1001852541m *uramp
-----------------------------------------------------$
ERROR -- Invalid parameter
Is Orcad Spice different from what your guys use?
These errors look like they're from spice or orcad itself. Them's some big node numbers ! (Ex. N731296)
Are you starting from an example circuit ? If not, that might be easier.
boB
Orcad PSpice
Orcad PSpice does not like the uramp function. So you need to rewrite the models slightly by replacing
uramp( blablabla )
with
limit( blablabla, 0, 1e16 )
Here is my model rewritten in PSpice
* 6BX7 - IDH medium-mu high-transconductance twin
* Bp A K I=(m)* uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters):
* mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*limit(V(A,K)*ln(1.0+(-
+ 0.1116255831)+exp((3.282351583)+(3.282351583)*
+ ((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt
+ ((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/
+ (3.282351583), 0, 1e16)**(1.44441018)
.ends mk_6BX7
Orcad PSpice does not like the uramp function. So you need to rewrite the models slightly by replacing
uramp( blablabla )
with
limit( blablabla, 0, 1e16 )
Here is my model rewritten in PSpice
* 6BX7 - IDH medium-mu high-transconductance twin
* Bp A K I=(m)* uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters):
* mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*limit(V(A,K)*ln(1.0+(-
+ 0.1116255831)+exp((3.282351583)+(3.282351583)*
+ ((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt
+ ((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/
+ (3.282351583), 0, 1e16)**(1.44441018)
.ends mk_6BX7
Still could not get the model to work. So I modified the a simple 6SN7 to fit the 6BX7 curve. Here is what I have:
* Connections: Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 6BX7 A G K
E1 2 0 VALUE={V(A,K)+10.43*V(G,K)}
R1 2 0 1.0K
Gp A K VALUE={200.89E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G K 4.4P
Cgp G A 4.2P
Cpk A K 1.1P
Rak A K 1G
Rgi G X 2K
D3 X K dx
.model dx d(is=1n rs=1 cjo=0 tt=1n)
.ENDS 6BX7
I powered up the headphone amp and took some measurements. The quiescent point is close enough (actual Ip <5% lower) in a CF application.
I guess the more ciomplicated model will be closer?
* Connections: Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 6BX7 A G K
E1 2 0 VALUE={V(A,K)+10.43*V(G,K)}
R1 2 0 1.0K
Gp A K VALUE={200.89E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G K 4.4P
Cgp G A 4.2P
Cpk A K 1.1P
Rak A K 1G
Rgi G X 2K
D3 X K dx
.model dx d(is=1n rs=1 cjo=0 tt=1n)
.ENDS 6BX7
I powered up the headphone amp and took some measurements. The quiescent point is close enough (actual Ip <5% lower) in a CF application.
I guess the more ciomplicated model will be closer?
- Status
- This old topic is closed. If you want to reopen this topic, contact a moderator using the "Report Post" button.
- Home
- Amplifiers
- Tubes / Valves
- 6BX7 PSpice Model?