• WARNING: Tube/Valve amplifiers use potentially LETHAL HIGH VOLTAGES.
    Building, troubleshooting and testing of these amplifiers should only be
    performed by someone who is thoroughly familiar with
    the safety precautions around high voltages.

Vacuum Tube SPICE Models

Jump to Latest
cogsncogs

cogsncogs

Member
Joined 2003
Here's one I made with Curve Captor back in 2007:

Code: 
* 6N7_GE Twin triode power amplifier LTSpice model
 * Modified Koren model (8 parameters): mean fit error 0.0594438mA
* Traced by Wayne Clay on 9/6/2007 using Curve Captor v0.9.1
* from General Electric data sheet
* Note: Positive grid region not modeled
.subckt 6N7  P G K
    Bp  P K  I=
+ (0.01144070334m)*uramp(V(P,K)*ln(1.0+(-0.5378627915)+exp((7.018436419)+
+ (7.018436419)*((40.28309326)+(474.9635984m)*V(G,K))*V(G,K)/sqrt((-2.346284445e-05)**2+
+ (V(P,K)-(-24.10402862))**2)))/(7.018436419))**(1.29012841)
  Cgk G K 3.0p
  Cpk P K 2.5p
  Cgp G P 4.5p
  Rpk P K 1G   ; to avoid floating nodes
  d3  G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
 .ends 6N7_GE
Might we talk Adrian into modelling one for us...? ;)
 

Attachments

  • 6N7_GE_CC.png
    6N7_GE_CC.png
    64.8 KB · Views: 324
cogsncogs

cogsncogs

Member
Joined 2003
DIYspaceW said:
Looking for 6C5 LTspice working model?? Anyone???
Click to expand...
Code: 
* ============================================================== 
* 6C5 LTSpice model 
* Modified Koren model (8 parameters): mean fit error 0.154002mA 
* Traced by Wayne Clay on 1/13/2014 using Curve Captor v0.9.1 
* from Tung-Sol data sheet 
* ============================================================== 
.subckt 6C5  P G K 
    Bp  P K  I= 
+ (0.02259428077m)*uramp(V(P,K)*ln(1.0+(-0.197682911)+exp((6.808001501)+ 
+ (6.808001501)*((22.3975015)+(57.1203515m)*V(G,K))*V(G,K)/sqrt((15.65144672)**2+ 
+ (V(P,K)-(-19.06525818))**2)))/(6.808001501))**(1.306693288) 
  Cgp G P 2.2p ; 0.2p added 
  Cgk G K 3.2p ; 0.2p added 
  Cpk P K 11.2p ; 0.2p added 
  Rpk P K 1G ; to avoid floating nodes 
  d3  G K dx1 
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n) 
.ends 6C5
 
rongon

rongon

Member
Joined 2009
is there a model around for 6C45pi?
Click to expand...

This is everything I've collected for 6C45P (6S45P). I don't have any of those tubes, so I can't tell you which (if any) of these are particularly accurate. I understand the tubes themselves have quite variable characteristics, which would make it difficult to create a one-size-fits-most model. Hopefully one of these models will work well enough for you.

Code: 
* model by Eugene V. Karpov
*
.SUBCKT 6S45P-E  1 2 3 ; P G C (Triode) 23-Oct-2006
+ PARAMS: MU= 53.57  EX= 1.957  KG1= 126.6  KP= 368.51 
+ KVB= 300.0  VCT= 0.00 RGI=1000
+ CCG=11P  CGP=5P CCP=1.9P
E1 7 0 VALUE=
+{V(1,3)/KP*LN(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G    ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG}  ; CATHODE-GRID; 
C2 2 1 {CGP}  ; GRID-PLATE; 
C3 1 3 {CCP}  ; CATHODE-PLATE; 
D3 5 3 DX     ; FOR GRID CURRENT
R1 2 5 {RGI}  ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

From Stephie Bench:

Code: 
.subckt 6C45-PE 1 2 3 ; plate grid cathode
+ params: mu=47.4501 ex=2.374193 kg1=268.615545 kp=485.735371 kvb=501.503636 rgi=300
+ ccg=2.4p cgp=4p ccp=.7p
e1 7 0 value= {v(1,3)/kp*log(1+exp(kp*(1/mu+v(2,3)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1g
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1g
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends

Another one, but I don't remember where I found it:

Code: 
* ==============================================================
* 6C45Pi PSpice model
* Joel Tunnah
* ==============================================================
.subckt 6C45Pi-j P G K
  Gp P K VALUE=
+ {(0.005984658048m)*limit(V(P,K)*ln(1.0+(0.02028899001)+exp((7.114994862)+
+ (7.114994862)*((56.68678595)+(336.3011671m)*V(G,K))*V(G,K)/sqrt((7.450118654e-006)**2+
+ (V(P,K)-(-10.58802286))**2)))/(7.114994862),0.0,1.0e16)**(1.976888442)}
  Cgp G P 4p
  Cgk G K 11p
  Cpk P K 1.9p
  Rpk P K 1G ; to avoid floating nodes
  d3  G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 6C45Pi-j


This is what I have for WE 437A (You'll need to change "^" to "**" for LTspice):

Code: 
* Copyright (C) 2001 Andrei Frolov <andrei@phys.ualberta.ca>
* Distributed under the terms of GNU Public License.
* 437A  -  IDH miniature high-transconductance Bp  P K  I=(m)*uramp(()*V(G,K)+V(P,K))^1.5
* From WE 437A datasheet - traced on 24-03-02 by AF
.subckt 437A  P G K
    Cgp G P  3.8p
    Ci  G K  11.1p
    Co  P K  1.0p
* Child-Langmuir law: mean fit error 3.16544 mA
*   Bp  P K  I=(0.08803578596m)*uramp((46.53586861)*V(G,K)+V(P,K))^1.5
* Child-Langmuir law with contact potential: mean fit error 3.13346 mA
*   Bp  P K  I=(0.08984194232m)*uramp((46.41042043)*V(G,K)+V(P,K)+(-1.625595632))^1.5
* Rydel model (4 parameters): mean fit error 2.85294 mA
*   Bp  P K  I=((0.09961070341m)+(0.004497964639m)*V(G,K))*uramp((43.21809681)*V(G,K)+V(P,K)+(-8.460821328))^1.5
* Rydel model (5 parameters): mean fit error 2.5059 mA
*   Bp  P K  I=((0.1072981442m)+(0.003810318087m)*V(G,K))*uramp((46.45918184)*V(G,K)+V(P,K)+(3.803361558))^1.5 * V(P,K)/(V(P,K)+(35.10094748))
* Koren model (4 parameters): mean fit error 2.82829 mA
*   Bp  P K  I=(0.06450876758m)*uramp(V(P,K)*ln(1.0+exp((11.92107695)+(11.92107695)*(46.58588321)*V(G,K)/V(P,K)))/(11.92107695))^(1.566457341)
* Koren model (5 parameters): mean fit error 2.46529 mA
*   Bp  P K  I=(0.0391526539m)*uramp(V(P,K)*ln(1.0+exp((11.13445084)+(11.13445084)*(47.10181935)*V(G,K)/sqrt((2.879020671k)+V(P,K)^2)))/(11.13445084))^(1.667607418)
* Modified Koren model (6 parameters): mean fit error 2.05999 mA
*   Bp  P K  I=(0.04248601694m)*uramp(V(P,K)*ln(1.0+(-0.2031315389)+exp((6.39958427)+(6.39958427)*((43.26744987)+(-942.0790694m)*V(G,K))*V(G,K)/V(P,K)))/(6.39958427))^(1.648729764)
* Modified Koren model (8 parameters): mean fit error 2.03357 mA
    Bp  P K  I=(0.04441361464m)*uramp(V(P,K)*ln(1.0+(-0.08216925584)+exp((6.905076822)+(6.905076822)*((41.36290447)+(-1039.217009m)*V(G,K))*V(G,K)/sqrt((-36.83706712)^2+(V(P,K)-(10.98747878))^2)))/(6.905076822))^(1.639335869)
.ends 437A

--
 
disco

disco

Member
Joined 2006
rongon said:
This is everything I've collected for 6C45P (6S45P). I understand the tubes themselves have quite variable characteristics, which would make it difficult to create a one-size-fits-most model. Hopefully one of these models will work well enough for you.
Click to expand...
Thanks Ron, appreciated. They take some time to settle when used for the first time, a couple of hours should do it. I'll pick the model with the nearest gm.
 
D

dazzamps

Member
Joined 2017
Hi guys. I'm trying to simulate a 6L6 single ended output stage. I've been told I should be able to get 12W out of it, but using the models here I can't get past 6W.

I'm using the 6L6.inc model from Ayumi, but also tried other 6Lx6's to no avail.

Here's a screenshot of the test circuit. I simply increased the input voltage amplitude till I reached 6% THD at the output, and then measured the output power. Am I missing something obvious here, please?

ETA: Sorry, B2 should have been 240V instead, but it doesn't make a difference in the simulation

E5wuykD.png
 
Last edited:
artosalo

artosalo

Member
Joined 2010
I've been told I should be able to get 12W out of it, but using the models here I can't get past 6W.
Click to expand...

You have been told something that even the tube manufacturer does not promise.
Look at the tube data here: http://www.mif.pg.gda.pl/homepages/frank/sheets/127/6/6L6G.pdf

Your main problem is far too low plate voltage (293 V).
In the datasheet 10.8 W is got with 350 V at plate (and 15 % THD), with 4k2 load impedance and fixed bias.
 
D

dazzamps

Member
Joined 2017
You must log in or register to reply here.
Top Bottom