Vacuum Tube SPICE Models

ripson · 2018-01-26 8:43 pm

Spice models for ABC1, EBC3 and UX201A

Does anybody have spice models for mentioned in the subject vacuum tubes?

jazbo8 · 2018-01-27 8:05 am

These are quite antiquated tubes... you can try making the models with CurveCaptor yourself.
Curve Captor download | SourceForge.net

ripson · 2018-01-28 11:48 am

jazbo8 said:
These are quite antiquated tubes... you can try making the models with CurveCaptor yourself.
Curve Captor download | SourceForge.net

Thanks for that!

ripson · 2018-01-30 3:29 am

In case if someone needs:

Code:

.subckt ABC1  P G K
   Bp  P K  I=(0.03461462647m)*uramp(V(P,K)*ln(1.0+(-0.09451114315)+exp((4.492501276)+(4.492501276)*((27.91471754)+(-293.1782318m)*V(G,K))*V(G,K)/sqrt((31.13718048)**2+(V(P,K)-(6.760356504))**2)))/(4.492501276))**(1.200237187)
   CGK G K 4.3p
   CGP G P 1.7p
   CPK P K 3.1p
.ends ABC1

Indiana.61 · 2018-02-05 9:45 am

search ltspice model

hi, I need the ltspice model of the subminiature jan 6418 valve connected to a triode.

euro21 · 2018-02-05 6:58 pm

Is anybody has soviet 6S28B/6S29B tubes model?

artosalo · 2018-02-12 5:26 pm

I have not found EL82 model. Does anybody have ?

Koonw · 2018-02-12 5:48 pm

euro21 said:
Is anybody has soviet 6S28B/6S29B tubes model?

The datasheet is found here.
Not sure you can model it, try.

rongon · 2018-02-12 5:53 pm

artosalo said:
I have not found EL82 model. Does anybody have ?

If it helps, I stumbled onto triode curves, here:
http://audioportal.hi-fi.ru/attachment.php?attachmentid=5278&d=1176045289

artosalo · 2018-02-12 5:55 pm

Thanks.
I look for tetrode model to simulate UL-circuits.

rongon · 2018-02-12 6:06 pm

My limited understanding is that triode curves are required to create pentode or tetrode model. That's why I posted triode curves. I do not know how to create a spice model, though.

Koonw · 2018-02-12 10:33 pm

I have created 6s28BV model. Hope I got the capacitance right -see attached

* 6s28bv LTSpice model
.subckt 6s28bv P G K
Bp P K I=(0.002601162511m)*uramp(V(P,K)*ln(1.0+(1.527218592)+exp((9.597585957)+(9.597585957)*((44.10205487)+(1219.438634m)*V(G,K))*V(G,K)/sqrt((45.94661787)**2+(V(P,K)-(-7.057968898))**2)))/(9.597585957))**(2.135670747)
CGK G K 6p
CGP G P 3.1p
CPK P K 7p
.ends 6s28bv

rongon · 2018-02-13 2:10 am

Thanks Koonw.

Hey artosalo, would 6P18P be close enough to EL82 for you to use? Maybe you'll want to give it a try.

Code:

.SUBCKT 6P18P_P  1 2 3 4 ; P G1 C G2 (Pentode) 24-Dec-2006
+ PARAMS: MU= 14.95  EX= 1.350  KG1= 568.0  KP=37.41   KC= 150
+ KVB=  34.4  VCT=  0.00  RGI=1000
+ CCG=11.5P  CPG1=0.2P CCP=6P
RE1  7 0  1MEG    
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LN(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1   1 3  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*1.57*TANH(2*V(1,3)/(KVB*3.14159))}
G2   4 3  VALUE={STP(((EXP(EX*(LN((V(4,3)/MU)+V(2,3)))))/KC)-((PWR(V(7),EX)+PWRS(V(7),EX))/KG1*1.57*TANH(2*V(1,3)/(KVB*3.14159))))
+*(((EXP(EX*(LN((V(4,3)/MU)+V(2,3)))))/KC)-((PWR(V(7),EX)+PWRS(V(7),EX))/KG1*1.57*TANH(2*V(1,3)/(KVB*3.14159))))}
RCP  1 3  1G      ; FOR CONVERGENCE
C1   2 3  {CCG}   ; CATHODE-GRID 1
C2   1 2  {CPG1}  ; GRID 1-PLATE
C3   1 3  {CCP}   ; CATHODE-PLATE
R1   2 5  {RGI}   ; FOR GRID CURRENT
D3   5 3  DX      ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

I've attached a 6P18P datasheet. Interelectrode capacitances are in there.

rongon · 2018-02-13 2:17 am

The Philips EL82 pdf datasheet I have is too large to upload here, but the interelectrode capacitances are:

Ca = 5.9 pF
Cg1 = 11 pF
Cag1 < 1 pF
Cg;f < 0.15 pF

I hope that helps.

Koonw · 2018-02-13 3:33 am

Also try this EL82 pentode model use pentode and triode curve as input:

* Created on 02/13/2018 11:26 using paint_kip.jar
* Model Paint Tools: Trace Tube Parameters over Plate Curves, Interactively
* Plate Curves image file: el82.png
* Data source link: <plate curves URL>
*----------------------------------------------------------------------------------
.SUBCKT EL82 1 2 3 4 ; P G K G2
+ PARAMS: CCG=11P CGP=1P CCP=5.9P RGI=2000
+ MU=9.2 KG1=11601.3 KP=52.3 KVB=23.6 KVC=2.43 VCT=5.02 EX=2.1 KG2=34328.4
* Vp_MAX=400 Ip_MAX=250 Vg_step=2 Vg_start=0 Vg_count=21
* Rp=1600 Vg_ac=23.5 P_max=11 Vg_qui=-23.4 Vp_qui=240 UL=0.43 EG2=170
* X_MIN=69 Y_MIN=251 X_SIZE=869 Y_SIZE=548 FSZ_X=1942 FSZ_Y=1102 XYGrid=false
* showLoadLine=n showIp=y isDHP=n isPP=n isAsymPP=n isUL=n showDissipLimit=y
* showIg1=n gridLevel2=n isInputSnapped=n
* XYProjections=n harmonicPlot=y harmonics=y
*----------------------------------------------------------------------------------
RE1 7 0 1G ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+(VCT+V(2,3))/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
* Alexander Gurskii screen current, see audioXpress 2/2011
RE2 8 3 1G ; Dummy
G2 8 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG2*(KVC-ATAN(V(1,3)/KVB))}
E2 8 4 VALUE={0} ; Dummy
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CGP} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

Koonw · 2018-02-13 5:04 am

Indiana.61 said:
hi, I need the ltspice model of the subminiature jan 6418 valve connected to a triode.

Triode curve is included in the datasheet. Noted the capacitance values are not listed.

Code:

* 6418T LTSpice model
.subckt 6148  P G K
    Bp  P K  I=(2.232751379m)*uramp(V(P,K)*ln(1.0+(-0.1251078596)+exp((9.293821508)+(9.293821508)*((7.752252766)+(-9.512594942m)*V(G,K))*V(G,K)/sqrt((2.911290527e-008)**2+(V(P,K)-(0.3137181941))**2)))/(9.293821508))**(1.896157386)
.ends 6418T

euro21 · 2018-02-13 8:47 am

Koonw said:
I have created 6s28BV model.

Thank you so much.

artosalo · 2018-02-13 2:26 pm

Thanks a lot for 6P18P and EL82 models.

matejsirk · 2018-02-13 2:34 pm

Hi I am looking for LTspice model for 6S46G-V.

Tube data on: 6С46Г-В, Tube 6С46Г-В; Rohre 6С46Г-В ID43226, Double Triode

Triode curves in attach file

Koonw · 2018-02-13 3:40 pm

matejsirk said:
Hi I am looking for LTspice model for 6S46G-V.

Tube data on: 6С46Г-В, Tube 6С46Г-В; Rohre 6С46Г-В ID43226, Double Triode

Triode curves in attach file

Code:

* 6S46G-V LTSpice model
.subckt 6S46G-V  P G K
    Bp  P K  I=(0.2734720428m)*uramp(V(P,K)*ln(1.0+(-0.03670114995)+exp((1.195695849)+(1.195695849)*((13.41579021)+(-192.3170616m)*V(G,K))*V(G,K)/sqrt((22.0885471)**2+(V(P,K)-(4.392866787))**2)))/(1.195695849))**(1.454315615)
    CGK G K 6.5p
    CGP G P 2.2p
    CPK P K 7.5p
.ends 6S46G-V

Vacuum Tube SPICE Models

Member

Ex-Moderator

Member

Member

Member

Member

Member

Disabled Account

Attachments

Member

Member

Member

Disabled Account

Attachments

Member

Attachments

Member

Disabled Account

Attachments

Disabled Account

Attachments

Member

Member

Member

Attachments

Disabled Account

Attachments