• WARNING: Tube/Valve amplifiers use potentially LETHAL HIGH VOLTAGES.
    Building, troubleshooting and testing of these amplifiers should only be
    performed by someone who is thoroughly familiar with
    the safety precautions around high voltages.

Vacuum Tube SPICE Models

Thanks, but this model does not work, or at least I can't get it to work.



This Ayumi model works.
BTW, E182CC (Mullard or Philips) sounds much better in practice than the simulation shows, IMO


* Generic triode model: E182CC
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sat Mar 8 22:42:34 2008
* Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT E182CC A G K
BGG GG 0 V=V(G,K)+0.56912497
BM1 M1 0 V=(0.020096637*(URAMP(V(A,K))+1e-10))**-0.83371956
BM2 M2 0 V=(0.64275075*(URAMP(V(GG)+URAMP(V(A,K))/17.776569)+1e-10))**2.3337196
BP P 0 V=0.0068220515*(URAMP(V(GG)+URAMP(V(A,K))/27.657018)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0041807778*V(M1)*V(M2)
BIG IG 0 V=0.0034110257*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0037843497*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 4.1p
CGK G K 6p
CAK A K 1.1p
.ENDS
 
Newbie question: Looking at an FFT plot, the fundamental (1khz in pic below) shows not as a sharp spike but sort of a wider shape with a peak at some +20dB. Is this just a LTspice inaccuracy, is it the result of less than optimal tube models, or ??? I get this behavior with a variety of tubes.

And does this indicate that all other peaks (f2, f3, etc) are similarly off?
 

Attachments

  • Capture.JPG
    Capture.JPG
    88 KB · Views: 383
Now the LTSpice model of E182CC would be needed.
Does anybody have ?
Yes... Included in a zip file I posted a few months ago in this thread.
Code:
* E182CC_LC LTSpice model 
* Modified Koren model (8 parameters): mean fit error 0.170981mA 
* Traced by Wayne Clay on 10/18/2013 using Curve Captor v0.9.1 
* from Philips data sheet low current (0-10mA) plate curves 
.subckt E182CC  P G K 
    Bp  P K  I=
+ (0.2203535708m)*uramp(V(P,K)*ln(1.0+(-0.1063849781)+exp((3.874792069)+
+ (3.874792069)*((27.50585286)+(-67.76184167m)*V(G,K))*V(G,K)/sqrt((10.80206098)**2+
+ (V(P,K)-(-7.968864547))**2)))/(3.874792069))**(1.172598079) 
  Cgk G K 4.7p ; 0.7p added 
  Cpk P K 1.6p ; 0.5p added 
  Cgp G P 1.8p ; 0.7p added 
  Rpk P K 1G ; to avoid floating nodes 
  d3  G K dx1 
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n) 
.ends E182CC
 
Optimising Spice model parameters

I was asked by Bondini to measure a few 5CZ5 pentodes on the uTracer which I duly did. I then extracted the Spice model using Derk Reedman's extractmodel for the beam pentode using DERKE. One set of triode connected curves and 4 sets of pentode curves for different values of Vs were used. The visual correlation between simulated and measured data looked pretty good.

I then built a simple Spice circuit that simulates what the uTracer does in UL mode, and measured the same on the uTracer. The comparison is shown in the attached file, with the solid blue lines being the Spice curves and the other coloured curves being the measured ones.

You can see some deviation in the area of interest, which is probably due to the inclusion of too many low current data points in the optimisation.

Any views on this?
 

Attachments

  • RCA_5CZ5 B+ 250V UL 50%.jpg
    RCA_5CZ5 B+ 250V UL 50%.jpg
    131.3 KB · Views: 413
  • Test jig.JPG
    Test jig.JPG
    43.9 KB · Views: 409