Go Back   Home > Forums > >
Home Forums Rules Articles diyAudio Store Blogs Gallery Wiki Register Donations FAQ Calendar Search Today's Posts Mark Forums Read

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Vacuum Tube SPICE Models
Vacuum Tube SPICE Models
Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 4th April 2014, 02:49 PM   #421
jackinnj is offline jackinnj  United States
diyAudio Member
 
jackinnj's Avatar
 
Join Date: Apr 2002
Location: Llanddewi Brefi, NJ
Vacuum Tube SPICE Models
Here's the result for the 6P36S using Multisim:

An externally hosted image should be here but it no longer works. Please upload images instead of linking to them to prevent this.


An externally hosted image should be here but it no longer works. Please upload images instead of linking to them to prevent this.
  Reply With Quote
Old 4th April 2014, 04:03 PM   #422
artosalo is offline artosalo  Finland
diyAudio Member
 
artosalo's Avatar
 
Join Date: Feb 2010
What is the Ug2 at upper plot ?
  Reply With Quote
Old 4th April 2014, 04:39 PM   #423
jackinnj is offline jackinnj  United States
diyAudio Member
 
jackinnj's Avatar
 
Join Date: Apr 2002
Location: Llanddewi Brefi, NJ
Vacuum Tube SPICE Models
190 -- which the EL500 shows in their datasheet. Couldn't find the datasheet for the 6P36S owing to lack of cyrillic knowledge.
  Reply With Quote
Old 4th April 2014, 04:57 PM   #424
jazbo8 is offline jazbo8
diyAudio Moderator
 
jazbo8's Avatar
 
Join Date: Jan 2011
Location: In Transient
Vacuum Tube SPICE Models
Many russian tube datasheets are available at klausmobile, including the 6P36S.

Vacuum Tube SPICE Models
  Reply With Quote
Old 4th April 2014, 05:43 PM   #425
artosalo is offline artosalo  Finland
diyAudio Member
 
artosalo's Avatar
 
Join Date: Feb 2010
English version: http://www.mif.pg.gda.pl/homepages/f...13/6/6P36S.pdf
  Reply With Quote
Old 4th April 2014, 06:42 PM   #426
dirkwright is offline dirkwright  United States
diyAudio Member
 
dirkwright's Avatar
 
Join Date: May 2011
Location: Virginia
Please help. I have Tina and I get an error "line 61: missing left parenthesis" in this 6N1P model:

Code:
*-----------------------------------------------------------------------
* Filename:		6N1P.inc  V1  25/10/97
* Simulator:		PSpice
* Device type:		Triode
* Device model:		Svetlana 6N1P
*
* Author:		Duncan Munro
* Date:			25/10/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT 6N1P A G K

************************************************************************
*
* Anode model
*
* Models reduction in mu at large negative grid voltages
* Models change in Ra with negative grid voltages
* Models limit in Ia with high +Vg and low Va
*
* PARAMETERS
*
*	LIP Conduction limit exponent
*	LIF Conduction limit factor
*	RAF Anode resistance factor for neg grid voltages
*	RAP Anode resistance factor for positive grid voltages
*	MU0 Mu between grid and anode at Vg=0
*	MUR Mu reduction factor for large negative grid voltages
*	EMC Emission coefficient
*	GCF Grid current scale factor
*
************************************************************************

.PARAM LIP 1
.PARAM LIF 1E-3
.PARAM RAF 9E-3
.PARAM RAP 4E-3
.PARAM MU0 38
.PARAM MUR 19E-3
.PARAM EMC 9.6E-6
.PARAM GCF 213E-6
Elim  LI 0  VALUE {PWR(LIMIT{V(A,K),0,1E6},{LIP})*{LIF}}
Erpf  RP 0  VALUE {1+LIMIT{V(G,K),0,-1E6}*{RAF}+LIMIT{V(G,K),0,1E6}*{RAP}}
Egr   GR 0  VALUE {LIMIT{V(G,K),0,1E6}+LIMIT{V(G,K)*(1+V(G,K)*{MUR}),0,-1E6}}
Eem   EM 0  VALUE {LIMIT{V(A,K)*V(RP)+V(GR)*{MU0},0,1E6}}
Eep   EP 0  VALUE {PWR(V(EM),1.5)*{EMC}}
Eel   EL 0  VALUE {LIMIT{V(EP),0,V(LI)}}
Eld   LD 0  VALUE {LIMIT{V(EP)-V(LI),0,1E6}}
Ga    A  K  VALUE {V(EL)}

************************************************************************
*
* Grid current model
*
* Models grid current, along with rise in grid current at low Va
*
************************************************************************
Egf   GF 0  VALUE {PWR(LIMIT{V(G,K),0,1E6},1.5)*{GCF}}
Gg    G  K  VALUE {(V(GF)+V(LD))}

*
* Capacitances
*
Cgk	G	K	2.4p
Cga	A	G	3.9p
Cak	A	K	0.7p

.ENDS
I can't find an error. Any help is appreciated. Thanks.
  Reply With Quote
Old 4th April 2014, 07:20 PM   #427
jazbo8 is offline jazbo8
diyAudio Moderator
 
jazbo8's Avatar
 
Join Date: Jan 2011
Location: In Transient
Vacuum Tube SPICE Models
Try this one instead.
  Reply With Quote
Old 4th April 2014, 07:28 PM   #428
dirkwright is offline dirkwright  United States
diyAudio Member
 
dirkwright's Avatar
 
Join Date: May 2011
Location: Virginia
Quote:
Originally Posted by jazbo8 View Post
Try this one instead.
Thanks, but Tina doesn't like the "**" in it. I tried to replace all of them with EXP but it still doesn't work.

Code:
*
* Generic triode model: 6N1P_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sun Jan 12 18:59:00 2014
*               Plate
*               | Grid
*               | | Cathode
*               | | |
.SUBCKT 6N1P_AN A G K
BGG   GG   0 V=V(G,K)+-0.42063507
BM1   M1   0 V=(0.007566675*(URAMP(V(A,K))+1e-10))**-0.43818786
BM2   M2   0 V=(0.77391879*(URAMP(V(GG)+URAMP(V(A,K))/29.878541)+1e-10))**1.9381879
BP    P    0 V=0.0022884667*(URAMP(V(GG)+URAMP(V(A,K))/38.606817)+1e-10)**1.5
BIK   IK   0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0013346379*V(M1)*V(M2)
BIG   IG   0 V=0.0011442333*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK  A    K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.001233721*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK  G    K I=V(IG)
* CAPS
CGA   G    A 1.6p
CGK   G    K 3.2p
CAK   A    K 1.5p
.ENDS
  Reply With Quote
Old 4th April 2014, 07:32 PM   #429
jazbo8 is offline jazbo8
diyAudio Moderator
 
jazbo8's Avatar
 
Join Date: Jan 2011
Location: In Transient
Vacuum Tube SPICE Models
Ah, the stupid SPICE syntax again... that one was for LTSpice, try the following one for TINA:

Code:
*
* Generic triode model: 6N1P_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sun Jan 12 18:59:00 2014
*               Plate
*               | Grid
*               | | Cathode
*               | | |
.SUBCKT 6N1P_AN A G K
.PARAM X1=-0.42063507 X2=0.007566675 X3=-0.43818786
.PARAM X4=0.77391879 X5=29.878541 X6=1.9381879
.PARAM X7=0.0022884667 X8=38.606817 X9=0.0013346379
.PARAM Y1=0.0011442333 Y2=0.001233721
BK IK 0 V=U(V(G,K)+X1)*X7*URAMP(V(G,K)+X1+URAMP(V(A,K))/X8)^1.5+(1-U(V(G,K)+X1))*X9*(X2*URAMP(V(A,K)))^X3*(X4*URAMP(V(G,K)+X1+URAMP(V(A,K))/X5))^X6
BA A K I=URAMP((Y2*URAMP(V(A,K))^1.5)-URAMP((Y2*URAMP(V(A,K))^1.5)-V(IK)+Y1*URAMP(V(G,K))^1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+.4)))+1E-10*V(A,K)
BG G K I=Y1*URAMP(V(G,K))^1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+.4)
* CAPS
CGA G A 1.6p
CGK G K 3.2p
CAK A K 1.5p
.ENDS
  Reply With Quote
Old 4th April 2014, 07:34 PM   #430
cogsncogs is offline cogsncogs  United States
diyAudio Member
 
cogsncogs's Avatar
 
Join Date: Jul 2003
Location: Wayne, West Virginia
Quote:
Originally Posted by jazbo8 View Post
Try this one instead.
Dirk, if you use this model in the link for TINA TI, you will need to change all instances of "**" to "^".
  Reply With Quote

Reply


Vacuum Tube SPICE ModelsHide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

Similar Threads
Thread Thread Starter Forum Replies Last Post
Vacuum tubes SPICE models, another way Dominique_free Software Tools 2 12th November 2013 06:26 PM
Tube spice models nhuwar Tubes / Valves 45 25th November 2011 08:47 AM
Computer program for tube curves and Spice models Jim Tonne Software Tools 9 21st November 2010 10:10 AM
Got my tube spice models, and tubed CD player page back on the air wa2ise Tubes / Valves 2 20th April 2008 11:07 PM


New To Site? Need Help?

All times are GMT. The time now is 10:42 AM.


Search Engine Optimisation provided by DragonByte SEO (Pro) - vBulletin Mods & Addons Copyright © 2018 DragonByte Technologies Ltd.
Resources saved on this page: MySQL 14.29%
vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2018 DragonByte Technologies Ltd.
Copyright ©1999-2018 diyAudio
Wiki