Go Back   Home > Forums > >

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Vacuum Tube SPICE Models
Vacuum Tube SPICE Models
Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools
Old 21st November 2020, 11:53 PM   #2671
zintolo is online now zintolo  Italy
diyAudio Member
 
Join Date: Sep 2012
Dear all,

may I ask you a model fr this tube?
https://frank.pocnet.net/sheets/095/6/6P13P.pdf

Thank you in advance,
Kind Regards
  Reply With Quote
Old 22nd November 2020, 07:04 AM   #2672
Adrian Immler is offline Adrian Immler  Switzerland
diyAudio Member
 
Adrian Immler's Avatar
 
Join Date: Oct 2018
Location: East Border of Switzerland
Hi zintolo

Freshly backed:

Code:
*6P13P LTspice model based on the generic tetrode/pentode model from Adrian Immler, version i4, Nov 2020
*Be aware that the iG1 model is just guessed due to lack of iG1 data!!
*A version log is at the end of this file
*Params fitted to chinese datasheet by Adrian Immler, Nov 2020
*This model is an enhancement of Adrians generic triode model to achieve tetrode/pentode behaviour.
*Hence, it is also suitable when the tetrode/pentode is "triode connected".
*Convenient for tetrodes, power beam tetrodes and g3-grounded pentodes.
*Copes secondary emission effect!
*
*             version i4
*             | p=preliminary due to lack of iG1 data
*             | | plate (in this model, "anode" means the internal virtual triode anode)
*             | | | grid2
*             | | | |  grid1
*             | | | |  |  cathode
*             | | | |  |  |
.subckt 6P13P.i4p P G2 G1 K
.params
*Parameters for the space charge current @ Vg <= 0
+ mu1 = 9       ;Main factor for voltage gain @ constant Ia in triode mode
+ ks = 325      ;Permeance factor. Has to be readjusted if xs is changed
+ Vg0 = 0.35    ;Offsets the Ia-traces on the Va axis. Electrode material's contact potential
+ kp = 37       ;Mimics the island effect
+ xs = 1.5      ;Determines the curve of the Ia traces. Typically between 1.2 and 1.8
*
*Parameters for an optional space charge current reduction @ Vg > 0
+ kIsr = 0.0    ;Va independable Is reduction, a function of Vg1
+ Rg1i = 10     ;Internal grid1 resistor which causes an extra Is drop when Va approaches zero.
*
*Parameters for assigning the space charge current to Ia and Ig @ Vg > 0 and small Va
+ kB1 = 0.3     ;Describes how fast Ia_virtual drops to zero when Va_virtual approaches zero.
+ radl = 275    ;Differential resistance for the Ia emission limit @ very small Va and Vg > 0
+ tsh = 12      ;Ia transmission sharpness from 1th to 2nd Ia area. Keep between 3 and 20. Start with 20.
+ xl = 1.3      ;Exponent for the emission limit
+ Vctl = 0 f=0  ;Offsets the Ia emission limit trace on the Va axis. f=related Vg1 koeff.
*
*Parameters of the grid-cathode vacuum diode
+ kg1 = 3k      ;estimated value!!
+ Vctg1 = 0.55  ;estimated value!!
+ xg1 = 1.5     ;Determines the curve of the Ig slope versus (positive) Vg and Va >> 0
+ VT = 0.1      ;Log(Ig) slope @ Vg<0. VT=k/q*Tk (cathodes absolute temp, typically 1150K)
*
*Parameters for the caps
+ cg1p  = 0p5   ;according datasheet
+ cg1All= 6p5   ;according datasheet
+ CpAll = 18p5  ;according datasheet
+ Cpk   = 1p    ;guessed value, not mentioned in datasheet
*
*Parameters to enhance the triode model to a pentode model
+ mu2 = 44      ;1/mu2 is the fraction of Vp which together with Vg2i builds the virtual Triode-Anode Voltage
+ kB2 = 0.2     ;Describes how fast Ip drops to zero when Vp approaches zero.
+ Rg2i = 10     ;Internal grid2 resistor. Causes an Is reduction when Ig2 increases while Vp drops
+ fr2 = 0.07    ;determines the residual ig2 fraction @ high Va values
+ ftfr2 = 0     ;if fr2 showes a Vg2 dependancy, this can be considered with this parameter
*
*Parameters to mimic the secondary emission (inspired from Derk Reefmans approach)
+ co = 1.5      ;decribes the crossover region (Ise drop when Va increase). between 0 and 9
+ Vse=55   a=0  ;Va where the sec. emission is strongest. a=related Vg1 coefficient
+ Ise0=0m3 b=0m4;sec. emission peak current @ Vg=0. b=related Vg1 coefficient
+ Vg2ref = 150  ;Vg2 where the following coeffficients has no influence to the emission effect:
+ c = 0         ;Vg2 coefficient of a
+ d = 0         ;exp Vg2 coefficient of Ise0
+ e = 0         ;Vg2 coeff. of b
*
*Calculated parameters
+ kl = pow(1/(radl*xl*Ild**(1-1/xl)),-xl) ;Reduces the xl influence to the Ia slope @ small Va
+ Ild = sqrt(radl)*1m ;Current where the limited anode a.c. resistance is set according to radl.
*
*Space charge current model
Bggi GG1i 0 V=v(G1i,K)+Vg0 - v(G1,K)*(1-1/(1+kIsr*max(0,v(G1,K)))) ;Effective internal grid voltage.
Bahc Ahc 0 V=uramp(v(P,K)/mu2+v(G2i,K)) ;voltage of the virtual triode anode, hard cut to zero
Bst St 0 V=max(v(GG1i)+v(Ahc)/(mu1), v(Ahc)/kp*ln(1+exp(kp*(1/mu1+v(GG1i)/(1+v(Ahc))))));Steering volt.
Bs Ai K I=1/ks*pow(v(St),xs) ;Langmuir-Childs law for the space charge current Is
*
*Anode current limit @ small Va
.func smin(x,y,n) {pow(pow(x + 1f, -n)+pow(y+1f, -n), -1/n)} ;Min-function with smooth trans.
Ra A Ai 1
Bpl G2i P I=i(Rp) - smin(1/kl*pow(v(P,K)+min(0,Vctl+f*v(G1,K)),xl),i(Rp),tsh);Ip emission limit
*
*Grid model
Rg1i G1 G1i {Rg1i} ;Internal grid resistor for "Ia-reduction" @ Vg > 0
.func Ivd(Vvd, kvd, xvd, VTvd) {1/kvd*pow(VTvd*xvd*ln(1+exp(Vvd/VTvd/xvd)),xvd)} ;Vacuum diode function
Bg1vd G1 K I=Ivd(v(G1,K)+Vctg1-1m*sqrt(v(Ahc)), kg1, xg1, VT) ;Grid-cathode vacuum diode
Bg1r G1i Ai I=ivd(v(GG1i),ks, xs, 0.8*VT)/(1+kB1*v(Ahc));Is reflection to grid when Va appr. zero
Bs0 Ai K I=ivd(v(GG1i),ks, xs, 0.8*VT) - 1/ks*pow(v(GG1i),xs) ;Compensates neg Ia
*@ small Va and Vg near zero
*
*additional model parts necessary for a pentode
Rg2i G2 G2i {Rg2i}
Rp P A 1
Bg2r G2i A I=i(Ra)*((1-frg2())/(1+kB2*max(0,v(P,K))) ) ; Va dependable ig2 part, reflected from the plate
Bg2f G2  A I=i(Ra)*frg2() ; Va independable ig2 part. Not to lead this current over Rg2i improves convergence
.func frg2() {fr2*exp(ftfr2*(v(G2,K)-250))}
*
*model for secondary emission effect
*nomalizing function nf(sh) ensures that the peak of y=x*(1-tanh(sh(x-1)) is always at x=1 while sh=0..9
.func nf(z) {609m/z + 293m + 107m*z - 5.71m*z*z}
.func sh() {pow(co,2)} ;results in a more linear control of the cross over region with the param co
Bsee G2 P I=min(Ise()*nf(sh())*xf()*(1-tanh(sh()*(nf(sh())*xf()-1))) / (nf(sh())*(1-tanh(sh()*(nf(sh())-1)))),i(Rp)-i(Bpl))
.func Ise() {smin(uramp(Isef() - bf()*v(G1,K)),0.98*i(Rp),2)} ;avoides neg. Iplate caused by strong sec. em.
.func xf() {v(P,K)/(1m+uramp(Vse-af()*v(G1,K)))}; moves the sec emission peak to the wanted voltage Vsep
.func af() {a + c*(v(G2,K)-Vg2ref)}
.func Isef()   {Ise0 * exp(d*(v(G2,K)-Vg2ref))}
.func bf()  {b + e*((v(G2,K)-Vg2ref))}
*
*Caps
C1 G1 P {cg1p}
C2 G1 K {(cg1All-cg1p)/2} ;As this model does not consider the ambient as further electrodes for parasitic caps,
;best way is to assume this " g1 to all" cap as it would be half to cathode and half to g2 (after substraction of cg1p).
C3 G1 G2 {(cg1All-cg1p)/2}
C4 P K {cpk}
C5 P G2 {cpAll-cpk-cg1p}
.end
*
*Version log
*i1 :Initial version
*i2 :Pin order changed to the more common order "P G2 G1 K" (Thanks to Markus Gyger for his tip)
*i3 :residual ig2 @ large Va introduced; 2nd emission effect introduced;
;Va indep. grid current parts no longer lead over internal grid resistors for better convergence
*i4 :to improve convegence, the Ia reduction @ pos Vg is no longer done by Rg1i. Instead, kIsr introduced
;Furthermore, ks and Vg0 are set directly, as rad and Vct turned out to be usefull for triodes only
*i4f :Major bug fixed. Tube works now also when Cathode not grounded (for cathode follower and the like)
Enjoy!

cheers, Adrian
Attached Images
File Type: jpg 6P13P_fit.jpg (256.6 KB, 189 views)
  Reply With Quote
Old 22nd November 2020, 01:34 PM   #2673
zintolo is online now zintolo  Italy
diyAudio Member
 
Join Date: Sep 2012
Thank you very much Adrian!
  Reply With Quote
Old 23rd November 2020, 02:49 PM   #2674
Koonw is online now Koonw
diyAudio Member
 
Join Date: Apr 2013
Quote:
Originally Posted by Koonw View Post
Here is trial model, will update if any issue:


Code:
* www.dmitrynizh.com/tubeparams_image.htm
 * Plate Curves image file: E130L.png
* Data source link: <plate curves URL>
*----------------------------------------------------------------------------------
.SUBCKT E130L P G2 G K ; LTSpice tetrode.asy pinout
* .SUBCKT E130L P G K G2 ; Koren Pentode Pspice pinout
+ PARAMS: MU=8.385 KG1=297113.95 KP=53.7 KVB=427.08 VCT=14.24 EX=3.231 KG2=564711.87 KNEE=865.42 KVC=1.948
+ KLAM=3.281E-10 KLAMG=7.089E-4  KD=2136.62 KC=1.346E30 KR1=3.254E-5 KR2=7.823 KVBG=0.000983 KB1=8 KB2=7.04 KB3=2.02 KB4=0.195 KVBGI=0.05472 KNK=-0.03236 KNG=0.006438 KNPL=0.02578 KNSL=0.07314 KNPR=106 KNSR=44.14
+ CCG=35P CGP=2P CCP=17P VGOFF=-0.6 IGA=0.001 IGB=0.3 IGC=8 IGEX=2
* Vp_MAX=300 Ip_MAX=1000 Vg_step=2 Vg_start=0 Vg_count=16
* X_MIN=81 Y_MIN=37 X_SIZE=674 Y_SIZE=560 FSZ_X=1296 FSZ_Y=736 XYGrid=false
* Rp=1400 Vg_ac=20 P_max=27.5 Vg_qui=-15 Vp_qui=300 
* showLoadLine=n showIp=y isDHP=n isPP=n isAsymPP=n isUL=n showDissipLimit=y 
* showIg1=y isInputSnapped=y addLocalNFB=n
* XYProjections=n harmonicPlot=y dissipPlot=n 
* UL=0.43 EG2=150 gridLevel2=y addKink=y isTanhKnee=n advSigmoid=y 
*----------------------------------------------------------------------------------
RE1  7 0  1G    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(G2,K)/KP*LOG(1+EXP((1/MU+(VCT+V(G,K))/SQRT(KVB+V(G2,K)*V(G2,K)))*KP))}
RE2  6 0  1G    ; DUMMY SO NODE 6 HAS 2 CONNECTIONS
E2  6 0  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))} ; Kg1 times KIT current
E4   8 0  VALUE={V(P,K)/KNEE/(KVBGI+V(6)*KVBG)}
E5  81 0  VALUE={PWR(V(8),KB1)}
E6  82 0  VALUE={PWR(V(8),KB2)}
E7  83 0  VALUE={PWR(V(8),KB3)}
E8   9 0  VALUE={PWR(1-EXP(-V(81)*(KC+KR1*V(82))/(KD+KR2*V(83))),KB4)*1.5708}
RE4  8 0  1
RE5 81 0  1
RE6 82 0  1
RE7 83 0  1
RE8  9 0  1
RE21 21 0 1
E21  21 0 VALUE={V(6)/KG1*V(9)} ; Ip with knee but no slope and no kink
RE22 22 0 1 ; E22: kink curr deviation for plate
E22  22 0 VALUE={V(21)*LIMIT(KNK-V(G,K)*KNG,0,0.3)*(-ATAN((V(P,K)-KNPL)/KNSL)+ATAN((V(P,K)-KNPR)/KNSR))} 
G1   P K  VALUE={V(21)*(1+KLAMG*V(P,K))+KLAM*V(P,K) + V(22)}
G2   G2 K  VALUE={V(6)/KG2*(KVC-V(9))/(1+KLAMG*V(P,K)) - V(22)}
RCP  P K  1G     ; FOR CONVERGENCE
C1   K G  {CCG}  ; CATHODE-GRID 1
C2   G P  {CGP}  ; GRID 1-PLATE
C3   K P  {CCP}  ; CATHODE-PLATE
RE23 G 0 1G 
GG G K VALUE={(IGA+IGB/(IGC+V(P,K)))*(MU/KG1)*
+(PWR(V(G,K)-VGOFF,IGEX)+PWRS(V(G,K)-VGOFF,IGEX))}
.ENDS
*$

This is update E130L model with improved convergence and alignment on zero bias line:


Code:
**** E130L ******************************************
* Created on 11/23/2020 21:11 using paint_kip.jar
* Model Paint Tools: Trace Tube Parameters over Plate Curves, Interactively
* Plate Curves image file: E130L.png
* Data source link: <plate curves URL>
*----------------------------------------------------------------------------------
.SUBCKT E130L P G2 G K ; LTSpice tetrode.asy pinout
* .SUBCKT E130L P G K G2 ; Koren Pentode Pspice pinout
+ PARAMS: MU=8.383 KG1=92.03 KP=63.63 KVB=1658.88 VCT=-2.17 EX=1.126 KG2=153.72 KNEE=5440.17 KVC=1.74
+ KLAM=6.25E-9 KLAMG=4.5E-4  KD=1.102 KC=0.1408 KR1=5.289E-7 KR2=0.001063 KVBG=1.216E-4 KB1=5.592 KB2=0 KB3=2 KB4=0.2697 KVBGI=1.152E-4 KNK=-0.008432 KNG=0.02399 KNPL=0.4572 KNSL=46.15 KNPR=69.89 KNSR=77.47
+ CCG=3P CGP=1.4P CCP=1.9P VGOFF=-0.6 IGA=0.001 IGB=0.3 IGC=8 IGEX=2
* Vp_MAX=300 Ip_MAX=1000 Vg_step=4 Vg_start=0 Vg_count=11
* X_MIN=56 Y_MIN=21 X_SIZE=749 Y_SIZE=624 FSZ_X=1296 FSZ_Y=736 XYGrid=false
* Rp=1400 Vg_ac=20 P_max=27.5 Vg_qui=-20 Vp_qui=300
* showLoadLine=n showIp=y isDHP=n isPP=n isAsymPP=n isUL=n showDissipLimit=y
* showIg1=y isInputSnapped=y addLocalNFB=n
* XYProjections=n harmonicPlot=y dissipPlot=n
* UL=0.43 EG2=150 gridLevel2=y addKink=y isTanhKnee=n advSigmoid=y
*----------------------------------------------------------------------------------
RE1  7 0  1G    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(G2,K)/KP*LOG(1+EXP((1/MU+(VCT+V(G,K))/SQRT(KVB+V(G2,K)*V(G2,K)))*KP))}
RE2  6 0  1G    ; DUMMY SO NODE 6 HAS 2 CONNECTIONS
E2  6 0  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))} ; Kg1 times KIT current
E4   8 0  VALUE={V(P,K)/KNEE/(KVBGI+V(6)*KVBG)}
E5  81 0  VALUE={PWR(V(8),KB1)}
E6  82 0  VALUE={PWR(V(8),KB2)}
E7  83 0  VALUE={PWR(V(8),KB3)}
E8   9 0  VALUE={PWR(1-EXP(-V(81)*(KC+KR1*V(82))/(KD+KR2*V(83))),KB4)*1.5708}
RE4  8 0  1
RE5 81 0  1
RE6 82 0  1
RE7 83 0  1
RE8  9 0  1
RE21 21 0 1
E21  21 0 VALUE={V(6)/KG1*V(9)} ; Ip with knee but no slope and no kink
RE22 22 0 1 ; E22: kink curr deviation for plate
E22  22 0 VALUE={V(21)*LIMIT(KNK-V(G,K)*KNG,0,0.3)*(-ATAN((V(P,K)-KNPL)/KNSL)+ATAN((V(P,K)-KNPR)/KNSR))}
G1   P K  VALUE={V(21)*(1+KLAMG*V(P,K))+KLAM*V(P,K) + V(22)}
G2   G2 K  VALUE={V(6)/KG2*(KVC-V(9))/(1+KLAMG*V(P,K)) - V(22)}
RCP  P K  1G     ; FOR CONVERGENCE
C1   K G  {CCG}  ; CATHODE-GRID 1
C2   G P  {CGP}  ; GRID 1-PLATE
C3   K P  {CCP}  ; CATHODE-PLATE
RE23 G 0 1G
GG G K VALUE={(IGA+IGB/(IGC+V(P,K)))*(MU/KG1)*
+(PWR(V(G,K)-VGOFF,IGEX)+PWRS(V(G,K)-VGOFF,IGEX))}
.ENDS
*$
Attached Images
File Type: jpg E130L paint-4.jpg (377.7 KB, 164 views)
  Reply With Quote
Old 29th November 2020, 01:04 PM   #2675
DIYspaceW is offline DIYspaceW  Slovenia
diyAudio Member
 
Join Date: May 2009
Location: Slovenia
Has someone the model for 2C22 triode? Thanks!
  Reply With Quote
Old 29th November 2020, 03:20 PM   #2676
Adrian Immler is offline Adrian Immler  Switzerland
diyAudio Member
 
Adrian Immler's Avatar
 
Join Date: Oct 2018
Location: East Border of Switzerland
Hi DIYspaceW

Here you go:
Code:
*2C22 LTspice model based on the generic triode model from Adrian Immler, version i4
*A version log is at the end of this file
*Params fitted to RCA datasheet by Adrian Immler, Nov. 2020
*The high fit quality is presented at adrianimmler.simplesite.com
*History's best of tube decribing art (plus some new ideas) is merged to this new approach.
*@ neg. Vg, Ia accuracy is similar to Koren or Ayumi models.
*@ small neg. Vg, the "Anlauf" current is considered.
*@ pos. Vg, Ig and Ia accuracy is on a unrivaled level.
*This offers new simulation possibilities like bias point setting with MOhm grid resistor,
*Audion radio circuits, low voltage amps, guitar distortion stages or pulsed stages.
*                 anode (plate)
*                 | grid
*                 | | cathode
*                 | | |
.subckt 2C22.RCi4 A G K
.params
*Parameters for the space charge current @ Vg <= 0
+ mu   = 21.4 ;Determines the voltage gain @ constant Ia
+ rad  = 5k4  ;Differential anode resistance, set @ Iad and Vg=0V
+ Vct  = 1.2  ;Offsets the Ia-traces on the Va axis. Electrode material's contact potential
+ kp   = 160  ;Mimics the island effect
+ xs   = 1.4  ;Determines the curve of the Ia traces. Typically between 1.2 and 1.8
*
*Parameters for assigning the space charge current to Ia and Ig @ Vg > 0
+ kB   = 0.055;Describes how fast Ia drops to zero when Va approaches zero.
+ radl = 280  ;Differential resistance for the Ia emission limit @ very small Va and Vg > 0
+ tsh  = 10   ;Ia transmission sharpness from 1th to 2nd Ia area. Keep between 3 and 20. Start with 20.
+ xl   = 1.3  ;Exponent for the emission limit
*
*Parameters of the grid-cathode vacuum diode
+ kvdg  = 35  ;virtual vacuumdiode. Causes an Ia reduction @ Ig > 0.
+ kg = 7k5    ;Inverse scaling factor for the Va independent part of Ig (caution - interacts with xg!)
+ Vctg = 0.55 ;Offsets the log Ig-traces on the Vg axis. Electrode material's contact potential
+ xg   = 1.5  ;Determines the curve of the Ig slope versus (positive) Vg and Va >> 0
+ VT   = 0.1  ;Log(Ig) slope @ Vg<0. VT=k/q*Tk (cathodes absolute temp, typically 1150K)
+ kVT=0       ;Va dependant koeff. of VT
+ Vft2 = 0 gft2 = 0 ;finetunes the gridcurrent @ low Va and Vg near zero
*
*Parameters for the caps
+ cag  = 3p6  ;From datasheet
+ cak  = 0p7  ;From datasheet
+ cgk  = 2p2  ;From datasheet
*
*special purpose parameters
+ os = 1      ;Overall scaling factor, if a user wishes to simulate manufacturing tolerances
*
*Calculated parameters
+ Iad = 100/rad  ;Ia where the anode a.c. resistance is set according to rad.
+ ks = pow(mu/(rad*xs*Iad**(1-1/xs)),-xs) ;Reduces the unwished xs influence to the Ia slope
+ ksnom = pow(mu/(rad*1.5*Iad**(1-1/1.5)),-1.5) ;Sub-equation for calculating Vg0
+ Vg0 = Vct + (Iad*ks)**(1/xs) - (Iad*ksnom)**(2/3) ;Reduces the xs influence to Vct.
+ kl = pow(1/(radl*xl*Ild**(1-1/xl)),-xl) ;Reduces the xl influence to the Ia slope @ small Va
+ Ild = sqrt(radl)*1m ;Current where the Il a.c. resistance is set according to radl.
*
*Space charge current model
Bggi GGi 0 V=v(Gi,K)+Vg0 ;Effective internal grid voltage.
Bahc Ahc 0 V=uramp(v(A,K)) ;Anode voltage, hard cut to zero @ neg. value
Bst   St 0 V=uramp(max(v(GGi)+v(A,K)/(mu), v(A,K)/kp*ln(1+exp(kp*(1/mu+v(GGi)/(1+v(Ahc)))))));Steering volt.
Bs    Ai K I=os/ks*pow(v(St),xs) ;Langmuir-Childs law for the space charge current Is
*
*Anode current limit @ small Va
.func smin(z,y,k) {pow(pow(z+1f, -k)+pow(y+1f, -k), -1/k)} ;Min-function with smooth trans.
Ra  A Ai 1
Bgl Gi A I=min(i(Ra)-smin(1/kl*pow(v(Ahc),xl),i(Ra),tsh),i(Bgvd)*exp(4*v(G,K))) ;Ia emission limit
*
*Grid model
Bvdg G Gi I=1/kvdg*pwrs(v(G,Gi),1.5) ;Reduces the internal effective grid voltage when Ig rises
Rgip G Gi 1G ;avoids some warnings
Cvdg G Gi 0p1;this small cap improves convergence
.func fVT() {VT*exp(-kVT*sqrt(v(A,K)))}
.func Ivd(Vvd, kvd, xvd, VTvd)  {if(Vvd < 3, 1/kvd*pow(VTvd*xvd*ln(1+exp(Vvd/VTvd/xvd)),xvd), 1/kvd*pow(Vvd, xvd))} ;Vacuum diode function
Bgvd Gi K I=Ivd(v(G,K) + Vctg, kg/os, xg, fVT())
.func ft2() {gft2*(1-tanh(3*(v(G,K)+Vft2)))} ;Finetuning-func. improves ig-fit @ Vg near -0.5V, low Va.
Bgr Gi Ai I=ivd(v(GGi),ks/os, xs, 1.1*VT)/(1+ft2()+kB*v(Ahc));Is reflection to grid when Va approaches zero
Bs0 Ai K  I=ivd(v(GGi),ks/os, xs, 1.1*VT)/(1+ft2()) - os/ks*pow(v(GGi),xs) ;Compensates neg Ia @ small Va and Vg near zero
*
*Caps
C1 A G {cag}
C2 A K {cak}
C3 G K {cgk}
.end
*
*Version log
*i1 :Initial version
*i2 :Pin order changed to the more common order €žA G K€œ (Thanks to Markus Gyger for his tip)
*i3 :bugfix of the Ivd-function: now also usable for larger Vvd
*i4: Rgi replaced by a virtual vacuum diode (better convergence). ft1 deleted (no longer needed)
;2 new prarams for Ig finetuning @ Va and Vg near zero. New emission skaling factor ke for aging etc.
Enjoy!
cheers, Adrian
Attached Images
File Type: jpg fit_2C22_posVg.jpg (359.6 KB, 120 views)
File Type: jpg fit_2C22_negVg.jpg (353.8 KB, 112 views)
  Reply With Quote
Old 1st December 2020, 07:14 AM   #2677
Ufudu is offline Ufudu  South Africa
diyAudio Member
 
Ufudu's Avatar
 
Join Date: Mar 2015
Location: Cape Town
Default Error in ExtractModel.exe output (V3.0)

When extracting Spice parameters using the pentode model including secondary emission, there is a term V(9)*KG2 missing in the Spice .cir output file for the screen current G2.

Depending on the model (just check the output file) you need to add V(9)*KG2 as follows:

G2 2 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG2 * (1+ als/(1+be*V(1,4)) + V(9)*KG2)}

or

G2 2 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG2 *(1+als*Exp(-be*V(1,4) * SQRT(be*V(1,4))) + V(9)*KG2)}

I have discussed this with Derk Reefman, who agrees. It appears as if the gnuplot includes the term but the .cir file does not.

Derk did indicate this would be corrected in the next ExtractModel update.

This only affects the screen current and not the anode current. The images attached show Is with and without the term added.
Attached Images
File Type: png Screenshot from 2020-06-11 08-52-13.png (253.9 KB, 97 views)
File Type: png Screenshot from 2020-06-11 08-53-43.png (169.8 KB, 23 views)
  Reply With Quote
Old 1st December 2020, 02:26 PM   #2678
jackinnj is offline jackinnj  United States
diyAudio Member
 
jackinnj's Avatar
 
Join Date: Apr 2002
Location: Llanddewi Brefi, NJ
Vacuum Tube SPICE Models
Quote:
Originally Posted by DIYspaceW View Post
Has someone the model for 2C22 triode? Thanks!
Less precise than Adrian's (kudos), but works well if you just want to use Koren:
Attached Images
File Type: png 2C22.png (49.2 KB, 21 views)
  Reply With Quote
Old 1st December 2020, 04:23 PM   #2679
Ray Waters is offline Ray Waters  United States
diyAudio Member
 
Join Date: Nov 2010
Location: Kansas
Quote:
Originally Posted by Ufudu View Post
When extracting Spice parameters using the pentode model including secondary emission, there is a term V(9)*KG2 missing in the Spice .cir output file for the screen current G2.

Depending on the model (just check the output file) you need to add V(9)*KG2 as follows:
Quote:
Originally Posted by Ufudu View Post
Derk did indicate this would be corrected in the next ExtractModel update.
Thanks for this information. Does Derk plan to also update the library file on his website (link below) or do we need to do this on our own?

The uTracer, a miniature Tube Curve Tracer / Tester.

I noticed some other G2 definitions that did not match either of the ones you cited.
  Reply With Quote
Old 2nd December 2020, 12:00 AM   #2680
cogsncogs is offline cogsncogs  United States
diyAudio Member
 
cogsncogs's Avatar
 
Join Date: Jul 2003
Location: Wayne, West Virginia
Here's my 2C22 model. Works in Micro Cap 11&12 as well as LTspice.
Code:
* ============================================================== 
* 2C22 LTSpice model 
* Modified Koren model (8 parameters): mean fit error 0.228577mA 
* Traced by Wayne Clay on 11/29/2017 using Engauge Digitizer and 
* Curve Captor v0.9.1 from RCA data sheet 
* ============================================================== 
.subckt 2C22  P G K 
    Bp  P K  I= 
+ (0.04379987792m)*uramp(V(P,K)*ln(1.0+(-0.03130084445)+exp((5.083473539)+ 
+ (5.083473539)*((19.65907786)+(-146.4566274m)*V(G,K))*V(G,K)/sqrt((37.01007525)**2+ 
+ (V(P,K)-(14.85637965))**2)))/(5.083473539))**(1.251309236) 
    Cgp G P  3.6p 
    Cgk G K  2.2p 
    Cpk P K  0.7p 
    Rpk P K  1.0G ; to avoid floating nodes 
    d3  G K  dx1 
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n) 
.ends 2C22
Attached Images
File Type: png 2C22.png (55.1 KB, 18 views)
__________________
Sent from my Linux desktop computer using a keyboard and a mouse.
  Reply With Quote

Reply


Vacuum Tube SPICE ModelsHide this!Advertise here!
Thread Tools

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

Similar Threads
Thread Thread Starter Forum Replies Last Post
Vacuum tubes SPICE models, another way Dominique_free Software Tools 2 12th November 2013 07:26 PM
Tube spice models nhuwar Tubes / Valves 45 25th November 2011 09:47 AM
Computer program for tube curves and Spice models Jim Tonne Software Tools 9 21st November 2010 11:10 AM
Got my tube spice models, and tubed CD player page back on the air wa2ise Tubes / Valves 2 21st April 2008 12:07 AM


New To Site? Need Help?

All times are GMT. The time now is 08:27 AM.


Search Engine Optimisation provided by DragonByte SEO (Pro) - vBulletin Mods & Addons Copyright © 2021 DragonByte Technologies Ltd.
Resources saved on this page: MySQL 14.29%
vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2021 DragonByte Technologies Ltd.
Copyright ©1999-2021 diyAudio
Wiki