Better power MOSFET models in LTSpice

What's the closest model to the old Siliconix VMP series VMOS parts?

You can try an VN88AFD...it's the same m-fet in different housing as Siliconix 2N6658 aka VMP-4 or VMP-12 iirc...

.SUBCKT VN88AFD 1 2 3
* Model Generated by MODPEX *
*Copyright(c) Symmetry Design Systems*
* All Rights Reserved *
* UNPUBLISHED LICENSED SOFTWARE *
* Contains Proprietary Information *
* Which is The Property of *
* SYMMETRY OR ITS LICENSORS *
*Commercial Use or Resale Restricted *
* by Symmetry License Agreement *
* Model generated on Sep 8, 97
* MODEL FORMAT: SPICE3
* Symmetry POWER MOS Model (Version 1.0)
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source
M1 9 7 8 8 MM L=100u W=100u
* Default values used in MM:
* The voltage-dependent capacitances are
* not included. Other default values are:
* RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=1.24222 LAMBDA=0 KP=0.410756
+CGSO=3.69374e-07 CGDO=1e-11
RS 8 3 3.00363
D1 3 1 MD
.MODEL MD D IS=5e-09 RS=0.01 N=1 BV=80
+IBV=10 EG=1.11 XTI=3 TT=0
+CJO=5.33925e-11 VJ=5 M=0.834582 FC=0.5
RDS 3 1 1.15e+07
RD 9 1 0.0001
RG 2 7 1.26706
D2 4 5 MD1
* Default values used in MD1:
* RS=0 EG=1.11 XTI=3.0 TT=0
* BV=infinite IBV=1mA
.MODEL MD1 D IS=1e-32 N=50
+CJO=7.44807e-11 VJ=0.732014 M=0.9 FC=1e-08
D3 0 5 MD2
* Default values used in MD2:
* EG=1.11 XTI=3.0 TT=0 CJO=0
* BV=infinite IBV=1mA
.MODEL MD2 D IS=1e-10 N=0.4 RS=3e-06
RL 5 10 1
FI2 7 9 VFI2 -1
VFI2 4 0 0
EV16 10 0 9 7 1
CAP 11 10 1.5e-10
FI1 7 9 VFI1 -1
VFI1 11 6 0
RCAP 6 10 1
D4 0 6 MD3
* Default values used in MD3:
* EG=1.11 XTI=3.0 TT=0 CJO=0
* RS=0 BV=infinite IBV=1mA
.MODEL MD3 D IS=1e-10 N=0.4
.ENDS vn88afd
 
IRFP340, IRFP9140 VDMOS models

...It would be very nice indeed if you could the same for IRFP9140 (for less then +/-40VDC supply) and IRFP340 (for less then +/-80VDC supply)...
Here they are:

*VDMOS with subthreshold (c) Ian Hegglun Apr 2019
.model IRFP340 VDMOS (Rg=5 Vto={3.9-6m*(0+temp-25)} Lambda=3m
+ Rs={35m*(1+3.5m*(0+temp-25))} Kp={7.3/(1+8.8m*(0+temp-25))}
+ Ksubthres={0.15*(1+4m*(0+temp-25))} Mtriode={0.2} Rd={0.3*(1+5m*(0+temp-25))}
+ Cgdmax={1.7n} Cgdmin={20p} a={0.35} Cgs={1.4n} Cjo={1n} Tnom=temp
+ m=0.75 VJ=5 IS=1n N=1.3 Rb=0.1 Vds=400 Ron=0.5 Qg=62nC mfg=VishIH1904)
*
*VDMOS with subthreshold (c) Ian Hegglun Apr 2019
.model IRFP9140 VDMOS (pchan Rg=6 Vto={(-3.76+6m*(0+temp-25))} Lambda=4m
+ Rs={35m*(1+3.5m*(0+temp-25))} Kp={12/(1+8.8m*(0+temp-25))}
+ Ksubthres={0.15*(1+4m*(0+temp-25))} Mtriode=0.25 Rd={0.1*(1+5m*(0+temp-25))}
+ Cgdmax={2.3n} Cgdmin={20p} a={0.35} Cgs={1.4n} Cjo={590p} Tnom=Temp
+ m=0.5 Vj=0.75 N=3 Is=10p Rb=0.08 Vds=-100 Ron=0.2 Qg=61nC mfg=VishIH1904)

I used Vishay datasheets. Jigs are attached in case you want to see.

I use gm values for Kp and some only give a "min" gm but I use "typ" gm for my Kp's. Some give "min" and "typ" gm so I use this ratio to estimate the "typ" gm when not given. This suggests you can expect up to +/-30% variations in gm values from the same supplier for dMOSFET's. BTW Exicon lateral's seem to be about +/-10% over decades and Hitachi/Renesas equivalents are within +/-20% of the Exicon's over decades.

It means random use of of p- and n- MOSFET's like the IRFP240 and IRFP9240 is a hit and miss affair in practice. Models can only indicate typical marching. You can't generalize abot how well MOSFET's like the IRFP240 and IRFP9240 are good complements just from their models either.

If you look at the SGS IRF640 and the Vishay IRF640, the SGS typ gm is 30% higher.

That's why there are a quite large range of Kp's (and gm's) between VDMOS model's of the same part number for dMOSFET's.

Another variation between VDMOS model's of the same part number is the Vto value. This does not affect gain symmetry in a push-pull amplifier so I thought it might help to use Bob Cordell's VDMOS model Vto's for the same part numbers (if Bob has one available). For the IRFP240 he uses 4.0V and for the IRFP9240 he uses -3.76V. But be aware that real amplifiers, paralleled MOSFET's of the same polarity will not have perfectly matched Vto's like your simulations, and it would help to select parts to match MOSFET Vto's of the same polarity (you can use lower value source R's that run cooler which improves reliability).

If you are using my jigs then when comparing a p-channel to the n-channel to see how close a complement it is then it is helpful to temporarily set the Vto of the p-channel equal to the n-channel. Then you can see how close the gm's are which is what you need for wingspread gain symmetry.

Cheers,
 

Attachments

  • IRFP340-IRFP9140-VDMOS.zip
    6.3 KB · Views: 167
Hi aparatusonitus,

If you are interested in symmetry, did you see my recent Echo amp circuit?
Spice model for Russian KP903A JFET?
I thought of it for LU1014D's. But now propose 5th generation trench MOSFET's. Most are aware generations after the IRF640 generation can't be used in linear mode direct off the +/-40-80V rails due to thermal hot spots (Spirito effect). But using them as Rush pairs with RET power transistors you get true symmetry and a wider better crossover region. Still just simulations.

Cheers,

Hi Ian,

I have never used trenchfets for a linear application and did indeed hear years ago that they are quite susceptible to second breakdown-like effects. Not surprising, as they are optimized for switching power supplies where they ideally should not be dissipating much in the linear region anyway.

Regarding your suggestion of using them in Rush pairs with BJT power transistors, are there actually any trenchfets available in P channel? Most SMPS use only N channel devices.

Cheers,
Bob
 
...Regarding your suggestion of using them in Rush pairs with BJT power transistors, are there actually any trenchfets available in P channel? Most SMPS use only N channel devices.
Hi Bob,

Nice to have you pop in. I see from your book thread you are now proof reading. I am looking forward to your 2nd Ed.

There are a few P trenchfets that match to N trenchfets in terms of gm for Rush pairs. I did a search 18 months ago for my Alpha and Charlie Rush amps and bought samples to try. But I left those designs for other things and have yet to return and complete them. Some pairs I have to try are (mostly D-PAK):
MTD5867 (n,60V,20A,26mR)+FDD5614 (p,60V,15A,0.1R)
NTD4909 (n,30V,40A,7mR) + IFD50P04 (p,40V,50A,9mR)
IRFU024 (n,60V,10A,0.1R) + IFQU17P06 (p,60V,12A,0.13R) or IPLU014 (n,60V,8A,0.18R)
MTD3055, MTD2955 (60V,12A) Not sure about if still available or if trenchfet.

The 'Alpha' amp IansAlphaAmp - Google Drive was bench tested with IRF640/9640 as a 50W common source "Pass" amp for current drive of a speaker. It uses p+n pairs with BJT cascode. Differences between the upper Rush FET pair and the lower Rush FET pair cancel out giving low DC offset drift and no need to match p & n MOSFET's.

The 'Charlie' amp IansCharlieAmp - Google Drive was simulated and a PCB was started. It is a 50W Diamond follower with an upper Rush trench FET pair and a lower Rush trench FET and a dMOSFET cascode. There are 14 MOSFET's and 10 are trenchfets, of these 4 need a heatsink and another 6 need to track their temperature. With 10 small SMD DPAK power transistors in contact with a heatsink it was a challenge to design a PCB for this amp that was not a pain to assemble. You can see photos of how it.can be done with only two main bolts two plates. And the dMOSFET's have spreader plates. For a 200W version I duplicate the PCB and then parallel it.

The 'Echo' amp does not need p+n channel FET's since it uses two n-channel FET's and relies on the BJT's to make complements. Less trenchfets, easier to make..

Cheers,
 
IRF730 in VDMOS

....Does anyone have an LTspice model for an IRF730 n-Channel Power MOSFET?...

Hi Cartman,

aparatusonitus posted a MODPEX model here Better power MOSFET models in LTSpice

I converted it to VDMOS (my jigs attached to compare them). Almost identical except the VDMOS has subthreshold conduction.

*VDMOS with subthreshold (c) Ian Hegglun Apr 2019
.model IRF730 VDMOS (Rg=5 Vto={4.0-6m*(0+temp-25)} Lambda=2m
+ Rs={65m*(1+3.5m*(0+temp-25))} Kp={3.1/(1+8.8m*(0+temp-25))}
+ Ksubthres={0.2*(1+4m*(0+temp-25))} Mtriode={0.9} Rd={0.7*(1+5m*(0+temp-25))}
+ Cgdmax=1.2n Cgdmin=5p a=0.25 Cgs=500p Cjo=300p Tnom=temp
+ m=0.75 VJ=5 IS=1n N=1.3 Rb=0.01 Vds=400 Ron=1 Qg=38nC mfg=VishIH1904)
 

Attachments

  • IRFP730-VDMOS-extract-jigs.zip
    5.3 KB · Views: 122
VN88AFD in VDMOS

What's the closest model to the old Siliconix ....
Hi haiqu,

Here's the MODPEX converted to VDMOS for LTspice. Better charge plot.to the Vishay datasheet (jigs attached). Better subthreshold region.

*VDMOS with subthreshold (c) Ian Hegglun Apr 2019
.model VN88AFD VDMOS (Rg=1 Vto={1.25-3.5m*(0+temp-25)} Lambda=0m
+ Rs={3*(1+1m*(0+temp-25))} Kp={0.41/(1+9m*(0+temp-25))}
+ Ksubthres={0.4*(1+1m*(0+temp-25))} Mtriode={1} Rd={0.1*(1+1m*(0+temp-25))}
+ Cgdmax=10p Cgdmin=0.7p a=1 Cgs=35p Cjo=40p Tnom=temp
+ m=0.75 VJ=5 IS=1p N=1.3 Rb=0.1 Vds=80 Ron=4 Qg=0.5nC mfg=VishIH1904)
 

Attachments

  • VN88AFD-VDMOS_07-Apr-2019.zip
    4.7 KB · Views: 94
About that Kp

... I use gm values for Kp and some only give a "min" gm but I use "typ" gm for my Kp's. ...
I had incorrect second harmonic phase on simulation of IRFP240 - IRFP9240 follower which may be caused by Kp parameter of the IRF9240 model being larger than the IRFP240 which does not reflect the typically higher Gm of the IRFP240 compared to IRFP9240 at a certain Id.

Found a youtube video How to model a MOSFET using a datasheet which shows a relation of :
Gm = sqrt(2 * Kp * Id)
hence
Kp = Gm**2 / (2 * Id)

From Harris and Intersil datasheets Gm vs Id curve, calculated Kp was plugged into Bob Cordell's model and I have better result with respect to phase of second harmonic.

Here is the modified model I now use. I am no expert in spice, so please correct me if you see any error.
Code:
* IRFP240C VDMOS copyright Cordell Audio December 20, 2014
* Modified by Indra1 April 10, 2019
.model irfp240C VDMOS(nchan Vto=4.0 Kp=5.042 Lambda=0.0032 Rs=0.01 Rd=0.1 
+Rds=1e7 Cgdmax=1100p Cgdmin=80p a=0.35 Cgs=1275p Cjo=3000p m=0.75 VJ=2.5 
+IS=4.0E-06 N=2.4 ksubthres=190m)
*
*
* IRFP9140C VDMOS   copyright Cordell Audio December 6, 2010
* Modified by Indra1 April 10, 2019
.model irfp9140C VDMOS(pchan Vto=-3.75746 Kp=2.667 Lambda=0.004 Rs=50m Rd=200m
+Rds=1e7 Cgdmax=750p Cgdmin=130p a=0.26 Cgs=1200p Cjo=2300p m=0.68 VJ=2.5 
+IS=76p N=2.4 ksubthres=0.107)
*
*
* IRFP9240C VDMOS copyright Cordell Audio December 20, 2014
* Modified by Indra1 April 10, 2019
.model irfp9240C VDMOS(pchan Vto=-3.76 Kp=3.226 Lambda=0.004 Rs=0.064 Rd=0.1 
+Rds=1e7 Cgdmax=700p Cgdmin=110p a=0.26 Cgs=1400p Cjo=2070p m=0.68 VJ=2.5 
+IS=4.0E-06 N=2.4 ksubthres=107m)
 

Attachments

  • Gm IRFP240 Harris.gif
    Gm IRFP240 Harris.gif
    10.9 KB · Views: 462
  • Gm IRFP9240 Intersil.gif
    Gm IRFP9240 Intersil.gif
    24.7 KB · Views: 484
Hi indra1,

Your approach is correct. The equation for Kp using gm or gfs neglects Rs degeneration, which is OK for starting values. The video you mention does not cover adding Rs. When you add Rs the value of Kp needs to be higher. I have a white paper (Pt.1) here VDMOS - PAK2 devo

Using gm@Id is a useful short cut to get Kp because you don't need to solve simultaneous equations like in the video.

I usually use Vishay datasheets. They don't have Gfs vs Id plots for the IRFP240/9240 but they do give gfs at one Id which is enough to calculate the starting Kp. EG

Vishay IRFP240 the gfs=6.9 A/V at 12A so Kp=2 (min) and using typ=1.3min gives Kp=2.6.typ and no Rs.yet.

Vishay IRFP9240 the gfs=4.2 A/V at 7.2A so Kp=3.6 (min) and using typ=1.3min gives Kp=4.7.typ and no Rs yet.

The Vishay datasheets give higher Kp's for the p-channel by a factor of 1.8 times. That's why Bob Cordell and my models end up with a Kp of 5 or 6 for the IRFP240 and 9 for the IRFP9240.once Rs is accounted for.

If your amplifier has a lower Kp for p-channel FET's than the n-channel FET's and you want your simulations to match your amp then by all means tailor the models to match your FET's.

BTW What brand of FET's are you using?
 
... I usually use Vishay datasheets. They don't have Gfs vs Id plots for the IRFP240/9240 but they do give gfs at one Id which is enough to calculate the starting Kp. ...
Thank you for the link Ian.
No wonder, the problem seems to stem from min Gfs value of the Vishay data. :)
Folks at the Pass forum are using a lot of IRFP240/9x40 and in most cases, the actual Gfs of the N is higher than the P. Attached are the measured Id/Vgs curves of typical Vishay parts made by another member, published in Pass forum a few years ago.
 

Attachments

  • IRFP240_9140 vishay.png
    IRFP240_9140 vishay.png
    16.3 KB · Views: 489
  • IRFP 240_9240a.jpg
    IRFP 240_9240a.jpg
    272.3 KB · Views: 489
Last edited:
LTspice IRFP240 + IRFP9240 plots with measured gm's

... Attached are the measured Id/Vgs curves of typical Vishay parts made by another member, published in Pass forum a few years ago.
Hi indra1,

Thanks for posting the measured curves of the IRFP240, IRFP9240 and IRFP9140. Very useful to check the Vishay Datasheets and my models from those datasheets.

I used GraphGrabber to capture the data to get Tables in LTspice to compare with my models. The jigs are attached. BTW in my white paper I explain how to capture data to get it into LTspice. Plotting measured gm's is very useful!:)

The data from these plots fits myIRFP240 model well -- after trimming out Vto variations for the sake of comparisons.

My IRFP9240 had a gm and Kp about 1.3x too high, Reducing the Kp of my p- model brings it to about the same as the n- model (6A/V^2).

The attached gm screen plot shows the measured p- and n- gm's. The 4 measured plots are the highest and lowest from the p- and n-measured data. Model gm's (smooth) after the p- has been scaled by dividing by 1.3. No scaling used for the n-channel.

attachment.php

Thanks again. This has been a big help for me to compare my IRFP240/9240 models with real data. I haven't updated my model yet. I'll check first with Bob Cordell if he is doing an update and sync models if we can. In the meantime you can change my IRFP9240 model Kp to 6 and it will be close to the measured curves (and maybe use Bob's Vto of -3.76).

BTW the attached jig also contains captured data for the IRFP9140 curves.

All the best
 

Attachments

  • Compare-extractions-IRFP240-IRFP9240-gm.png
    Compare-extractions-IRFP240-IRFP9240-gm.png
    16.7 KB · Views: 873
  • Compare-extractions-IRFP240-IRFP9240.png
    Compare-extractions-IRFP240-IRFP9240.png
    21.4 KB · Views: 414
  • Compare-extractions-IRFP240-IRFP9x40.zip
    12 KB · Views: 106
Last edited:
Converted to VDMOS:


*VDMOS with subthreshold (c) Ian Hegglun Apr 2019
.model ZVP2110G VDMOS (pchan Rg=65 Vto={-(2.8-6m*(temp-25))} Lambda=6m
+ Rs={2*(1+3.5m*(temp-25))} Kp={0.17/(1+8.8m*(temp-25))}
+ Ksubthres={0.15*(1+4m*(temp-25))} Mtriode=0.5 Rd={2.5*(1+5m*(temp-25))}
+ Cgdmax=20p Cgdmin=3p a=0.5 Cgs=140p Cjo=60p Tnom=Temp
+ m=0.5 Vj=0.75 N=3 Is=5p Rb=1 Vds=-100 Ron=8 Qg=2nC mfg=DioInc1904)
 
... Vto={-(2.8-6m*(temp-25))}

Hi Ian

Most of the time you have VTO with a -6 mV/K slope.
Is that a default or do you actually measure this?
I know the Silicon BJT value of -2.2 mV/K is tied to the semiconductor physics and doesn't vary much.
I know much less about VDDMOS physics, not sure about how much variation there is.
Some of the datasheets imply a different value but it's usually at the limit of the plot so it's hard to be sure.

Best wishes
David
 
Hi David,

For the ZVP2110G the -6mV/K was a carry over from the previous fit. For the ZVP2110G there was no data for higher temps in the DiodesInc datasheet so I couldn't set the temp co's. I figured rough temp co's would be better than none. In hindsight at temp co of 2mV or 3mV might be more likely. The DiodeInc model from their website didn't have a temp co for Vto, but did have temp co's for Rs and Rd (but were quadratics and so I didn't try to match their temp cos).

If someone can find temperature data I can then check and amend the model unless someone else would like to do it.

As for how I choose the temp co for VTO I first get the Kp and Rs temp co's about right using gm vs Id plots at 2 temps (if available) otherwise it ha to be Id/Vgs plots. The I vary the VTO temp co to try and get the ZTC crossover to match the plots.

My lateral MOSFET' were measured to have a VTO temp co of -2mV/C. Some of my models have been -1mV/C. The -6mV has been a carry over from the IRF640 I did around 2016 from Vishay datasheets, and for the IRF9640 I used 2.5mV/C (neg temp co).

Several years back I checked the default temp co for the VDMOS and it has a fixed -1mV/C and Kp has a fixed BEX of 1.5 (about -5m/K at 300K). Mike Engelhardt reassured keantoken (host of this thread) by PM that there are no other fixed temp co's in the VDMOS.

I usually disable the internal temp co's to avoid confusion (using Tnom=Temp) and add my own temp co's using equations and note this also disables the body diode XTI temp co for the 'Is' parameter.

If you roll your own models and are happy with the internal temp co's then don't apply the Tnom=Temp statement in the model.

Cheers,
 
[A] temp co of 2mV or 3mV...more likely

Thanks for the, as usual, informative reply.
What's the reason to think 2 or 3 mV/K more likely in this case?
Any rule of thumb to correlate the Vto or the resistance of the FET, or whatever?
Apart from Lateral FETs that is (better understood just in time for their obsolescence!)

I meet Mike E. next week, should I ask for the temperature coefficient to be available as a parameter?
Should be an easy code enhancement, save some complications.
Any other requests?

Best wishes
David.
 
Hi David,

For the ZVP2110G the -6mV/K was a carry over from the previous fit. For the ZVP2110G there was no data for higher temps in the DiodesInc datasheet so I couldn't set the temp co's. I figured rough temp co's would be better than none. In hindsight at temp co of 2mV or 3mV might be more likely. The DiodeInc model from their website didn't have a temp co for Vto, but did have temp co's for Rs and Rd (but were quadratics and so I didn't try to match their temp cos).

If someone can find temperature data I can then check and amend the model unless someone else would like to do it.

As for how I choose the temp co for VTO I first get the Kp and Rs temp co's about right using gm vs Id plots at 2 temps (if available) otherwise it ha to be Id/Vgs plots. The I vary the VTO temp co to try and get the ZTC crossover to match the plots.

My lateral MOSFET' were measured to have a VTO temp co of -2mV/C. Some of my models have been -1mV/C. The -6mV has been a carry over from the IRF640 I did around 2016 from Vishay datasheets, and for the IRF9640 I used 2.5mV/C (neg temp co).

Several years back I checked the default temp co for the VDMOS and it has a fixed -1mV/C and Kp has a fixed BEX of 1.5 (about -5m/K at 300K). Mike Engelhardt reassured keantoken (host of this thread) by PM that there are no other fixed temp co's in the VDMOS.

I usually disable the internal temp co's to avoid confusion (using Tnom=Temp) and add my own temp co's using equations and note this also disables the body diode XTI temp co for the 'Is' parameter.

If you roll your own models and are happy with the internal temp co's then don't apply the Tnom=Temp statement in the model.

Cheers,

A long time ago I also measured on the order of -7 mV/C for the HEXFETs. I note that I measured (and care most about) the MOSFET tempco at the typical bias operating point, e.g., 100 - 200 mA. I have not measured the tempco for lateral MOSFETs. It is likely quite different at the typical bias current, since the tempco for laterals goes through zero in the vicinity of that current, and that is the reason for their higher degree of bias stability. Even at 150 mA, or so, I think the tempco of their Rds_on is playing a big role. HEXFETs tempco does not go through zero until quite high values of current, on the order of 5A to 10A or more.

Cheers,
Bob
 
...I also measured on the order of -7 mV/C for the HEXFETs. I note that I measured (and care most about) the MOSFET tempco at the typical bias...

Hi Bob
Your book has ~-6 mV for the IRFP240 so I was curious if Ian's default was based on that or independently checked.

I have not measured the tempco for lateral MOSFETs. It is likely quite different at the typical bias current... Even at 150 mA, or so, I think the tempco of their Rds_on...

I don't plan to use any laterals but their tempco is of interest in as far as it illuminates the mechanisms involved.
I believe you are correct, the measured tempco is a function of the Rds tempco and Vgs tempco, and they move in opposite directions.
So the vertical MOSFET tempco is worse precisely because the Rds is smaller and it's positive tempco has less affect.
So if one wants the improved efficiency of the v.FETs then the increased tempco is more or less unavoidable.
At least that's as I understand it, I hoped someone would be able to quantify it before I do the bias spreader for a vFET amp.

Best wishes
David