LND150 Depletion MOSFET model

[jackinnj]

Someone had posted a DMOS model for the LND150 on another forum. I've taken the Supertex info and re-worked it a tiny bit to come up with the following changes to their NMOS Model:

.SUBCKT BVS841_DepletionMosfets__1__5 10 20 30
M1 10 20 30 30 NMOS
.MODEL NMOS NMOS (
+ LEVEL=3
+ NSUB=5.0e13
+ TPG=1
+ CGDO=2.1716e-12
+ RD=400
+ VTO=-1.50
+ VMAX=1.0e8
+ ETA=0.1
+ NFS=6.6e10
+ TOX=1.0e-7
+ LD=1.698e-9
+ UO=862.425
+ XJ=6.467e-7
+ DELTA=0.1
+ THETA=1E-5
+ L=10e-6
+CGSO=5.09e-10
+ W=600e-6
+ KAPPA=1.0
+ )
.ENDS

 

[iko]

I don't get it, supertex makes a whole library available, and LND150 has a model in it too (see below). Was there a problem with their model?

*LND150 MODEL
*
.MODEL LND150 NMOS (LEVEL=3 RS=150.00 NSUB=5.0E13
+DELTA=0.1 KAPPA=1.O TPG=1 CGDO=2.1716E-12
+RD=40.0 VTO=-2.0 VMAX=1.0E8 ETA=0.1
+NFS=6.6E10 TOX=1.0E-7 LD=1.698E-9 UO=862.425
+XJ=6.4666E-7 THETA=1.0E-5 CGSO=5.09E-10 L=10.0E-6
+W=600E-6)
*.ENDS

 

[jackinnj]

It's just the VTO and RD which are modified -- but it looks somewhat more than the chart on page 3 of the datasheet:

 

[b_force]

To make this model work in mutlsim, are the following connections correct?

10 = Drain
20 = Gate
30 = Source

if so, I don't see that much difference if you add a capacitor parallel to the source resistor.

 

[luixssj3]

I throw up this old topic to ask a question, how can I add a txt model like that of the LND150 in Orcad PSPICE?

I'm searching for a tutorial but I haven't find any information.

Thank you!
Regards
Luix

 

[Oak Blood Three]

It turns out there was (and still is) a problem in the model from the Supertex website. There's an "O" where there should be a "0".

I don't get it, supertex makes a whole library available, and LND150 has a model in it too (see below). Was there a problem with their model?

*LND150 MODEL
*
.MODEL LND150 NMOS (LEVEL=3 RS=150.00 NSUB=5.0E13
+DELTA=0.1 KAPPA=1.0 TPG=1 CGDO=2.1716E-12
+RD=40.0 VTO=-2.0 VMAX=1.0E8 ETA=0.1
+NFS=6.6E10 TOX=1.0E-7 LD=1.698E-9 UO=862.425
+XJ=6.4666E-7 THETA=1.0E-5 CGSO=5.09E-10 L=10.0E-6
+W=600E-6)
*.ENDS

 

[IanHegglun]

BTW There is a LND150 VDMOS model in LTspice by adding Alexander Bordodynov's (standard.mos) library here For LTspice users. Libraries of models, examples, etc

Or add the following to your circuit in LT-XVII

*VDMOS (c) Copyright Ian Hegglun Jul 2019 
.model LND150h VDMOS (Rg=100 Vto=-1.4 Lambda=0m Rs=70 Kp=3m Ksubthres=95m Mtriode=0.6 Rd=300 Bex=-2 Vtotc=-5m Tksubthres1=3m Trs1=2.6m Trd1=3m Cgdmax=5p Cgdmin=3p a=0.3 Cgs=3p Cjo=15p m=0.7 VJ=0.75 IS=15p N=1.5 EG=1.1 Rb=100 Vds=400 Ron=600 mfg=IHKT1911) ;LT-XVII

For LT-IV and LT-XVII

*VDMOS (c) Copyright Ian Hegglun Jul 2019 
.model LND150_ VDMOS (Rg=100 Vto={-1.4-(5m-1m)*(Temp-25)} Lambda=0m
+ Rs={70*(1+2.6m*(Temp-25))} Kp={3m*((Temp+273)/(273+25))**-(2-1.5)}
+ Ksubthres={0.095*(1+3m*(Temp-25))} Mtriode=0.6 Rd={300*(1+3m*(Temp-25))}
+ Cgdmax=5p Cgdmin=3p a=0.3 Cgs=3p Cjo=15p m=0.7 VJ=0.75
+ IS=15p  N=1.5  EG=1.1 Rb=100 Vds=400 Ron=600 mfg=IH1911)

The VDMOS model has some extra features that the Supertex model doesn't have like good subthreshold conduction and Mtriode and variable junction capacitance, but the Supertex LND150 has ETA=0.1 (similar effect to Mu of a tube) which the VDMOS doesn't have (but it can be approximated by say Lambda=2m).