Need ECF80 / 6BL8 tube spice 3f4 model - Page 2 - diyAudio
Go Back   Home > Forums > Amplifiers > Tubes / Valves

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 2nd November 2006, 05:23 PM   #11
bembel is offline bembel  Europe
diyAudio Member
 
bembel's Avatar
 
Join Date: Aug 2006
Send a message via Yahoo to bembel
Default Robert, thanks again & again

Quote:
Originally posted by Robert McLean
I thought I would give this one more try.

So I downloaded the demo version of ProteusVSM to see what is going on.

I got a circuit to work using their models of EL34, EF86 and EL84 but the other pentode models will not work. There may be something wrong with pin assignments.

So I think you will have to use the EL34 schematic symbol, but change the specified spice model from 6CA7 to Ecf80_p or 6BL8_p.

I looked at the spice code they are using and I noticed that they use PWR and PWRS, so I put those commands back into my code. Everything else looks OK.

I was not able to test the models, since I have not been able to figure out how to link in my models. How do you tell Proteus to do that ?

Anyway here are the models that I think should work, if you can get Proteus to use them using the EL34 type
Robert, as I said, thanks again and again.
I think that you're right about a pin assignment bug in proteus, actually, I was using their generic pentode symbol. they are a few other problematic bugs also (with grid current notably).

I'm not enough skilled into code to tell you about models parameters (I just know PARAM is proprietary to Pspice, don't know about PWR)

To link the models, simply select the symbol (Rclick), then go into its parameters (Lclick), then check "edit properties as text", then edit something like:
{PRIMITIVE=ANALOGUE,SUBCKT}
{SPICEMODEL=ecf80t,ecf80t.inc}
{SPICEPINS=A,G,K}

where SPICEMODEL=X,Y is:
X being the model name inside the model file (ie: XECF80_P)
Y being the file model name (ie: ECF80.inc)

NB: don't forget to add to "models PATH" your folder where your ECF80.inc or ECF80.txt is. (you can find paths preferences in the system menu)
__________________
Plus je pédale moins vite, moins j'avance plus vite !
  Reply With Quote
Old 2nd November 2006, 06:03 PM   #12
bembel is offline bembel  Europe
diyAudio Member
 
bembel's Avatar
 
Join Date: Aug 2006
Send a message via Yahoo to bembel
PS : Although I not cleary understand pin assignement in ProteusVSM, I suspect that you assign pins the SPICEPINS property, in the order as they come in the symbol. ?!? can anyone confirm ?
__________________
Plus je pédale moins vite, moins j'avance plus vite !
  Reply With Quote
Old 2nd November 2006, 07:57 PM   #13
diyAudio Member
 
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Default success !!

OK, here are two models that work in proteusVSM



.SUBCKT 6BL8_p2 A S G K
*
* CALCULATE CONTRIBUTION TO CATHODE CURRENT
*
BAT AT 0 V=0.636*ATAN(V(A,K)/9.973379205)
BGS GS 0 V=URAMP(V(S,K)/2.32E+01 + V(G,K)*1.903769916)
BGS2 GS2 0 V=V(GS)^1.5
BCATH CC 0 V=V(GS2)*V(AT)
*
* CALCULATE ANODE CURRENT
*
BA A K I=1.25E-03*V(CC)
*
* CALCULATE SCREEN CURRENT
*
BSCRN SC 0 V=V(GS2)*(1.1-V(AT))
BS S K I=1.22E-03*V(SC)
*
* GRID CURRENT (APPROXIMATION - DOES NOT MODEL LOW VA/VS)
*
BG G K I=(URAMP(V(G,K)+1)^1.5)*1.49E-04
*
* CAPACITANCES
*
CG1 G K 2.5P
CAK A K 1.8P
CG1A G A 1.5P
.ENDS



.SUBCKT ECF80_p2 A S G K
*
* CALCULATE CONTRIBUTION TO CATHODE CURRENT
*
BAT AT 0 V=0.636*ATAN(V(A,K)/10.3933476)
BGS GS 0 V=URAMP(V(S,K)/2.17E+01 + V(G,K)*1.720663004)
BGS2 GS2 0 V=V(GS)^1.5
BCATH CC 0 V=V(GS2)*V(AT)
*
* CALCULATE ANODE CURRENT
*
BA A K I=1.23E-03*V(CC)
*
* CALCULATE SCREEN CURRENT
*
BSCRN SC 0 V=V(GS2)*(1.1-V(AT))
BS S K I=2.28E-03*V(SC)
*
* GRID CURRENT (APPROXIMATION - DOES NOT MODEL LOW VA/VS)
*
BG G K I=(URAMP(V(G,K)+1)^1.5)*1.49E-04
*
* CAPACITANCES
*
CG1 G K 2.5P
CAK A K 1.8P
CG1A G A 1.5P
.ENDS


I used the same style of model as the 6CA7 supplied with Proteus, so that way I knew it must work. I recalculated the parameters to fit my ECF80 and 6BL8 data.

To use them I used the EL34 symbol, and then edited the SPICEMODEL to say {SPICEMODEL=ECF80_p,MyPentodes.inc}

I only tested them in a dc circuit, ie dc voltages on grid, screen and plate, and then read the currents, which were correct per my LTSpice simulations, but they should be OK.

The 6BL8_p model wont work at all, and the ECF80_p model works, but gives incorrect values. I do not know why, but I am not going to worry about it, the latest _p2 models should be close enough.

I tried using the good models with the 6L6GC symbol, and I get the same error about the cathode connection.

So my suggestion is just use the EL34 symbol
__________________
Robert McLean
  Reply With Quote
Old 2nd November 2006, 08:35 PM   #14
bembel is offline bembel  Europe
diyAudio Member
 
bembel's Avatar
 
Join Date: Aug 2006
Send a message via Yahoo to bembel
Robert, can you send me one of your error messages (relative to symbol & pin assignement) please ? Maybe I can help
__________________
Plus je pédale moins vite, moins j'avance plus vite !
  Reply With Quote
Old 8th November 2006, 10:51 AM   #15
bembel is offline bembel  Europe
diyAudio Member
 
bembel's Avatar
 
Join Date: Aug 2006
Send a message via Yahoo to bembel
Default Your last model works well Robert

A took sometime to reinstall proteus, doing some cleaning to my folders, models, libraries, etc.
Your last models, works well, I am using the EL34 Symbol with it, and everything is fine.
I have a big tube symbol library (more than 100 diifferent one, made for proteus, Have to try them, It was made by someone, to get around pin assignement problem.

Thx again
__________________
Plus je pédale moins vite, moins j'avance plus vite !
  Reply With Quote
Old 7th January 2010, 09:57 PM   #16
diyAudio Member
 
Join Date: Jan 2010
Location: Germany
Default Need ECF80 triode spice 3f4 model

Hello,

I´m very sorry for digging out this quite historical thread....
But you are my last hope; I spend hours on searching the Net for a running ECF80 spice model.
The Pentode model you discussed is running very well for b2spice after change the line:
** s k i=2.28e-03*v(sc) --> ** s k i=2.28e-03*v(sc)

But I need also the triode model ! I try the 12au7 but this is too different....

Please be so kind and provide me the missing triode model for the ECF80.

By the way:
Any good tool-chain to create a spice model from datasheed for a non mathematical genie???

Thanks a lot
Karsten

Last edited by karsten21; 7th January 2010 at 10:12 PM. Reason: Edit changed line of pentode model
  Reply With Quote
Old 8th January 2010, 11:39 AM   #17
diyAudio Member
 
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Default ECF80 Triode model

Karsten
try this one. It is for LT Spice, it may be compatible. If not, let me know.


****
* R McLean 19 Oct 2008
* ECF80t
* Koren6 model generated using Koren&RydelTriodeModels.xls
* LTSpice compatible
* RMS mA err 0.277551005104373
*
*
*
*
****
.Subckt ECF80t_k6 P G K
Bp P K I=(0.0765426120591168m)*uramp(V(P,K)*ln(1.0+(-0.0345984809165187)+
+ exp((3.0207469570032)+(3.0207469570032)*
+ ((20.6508712664427)+(-146.65206568867m)*V(G,K))*V(G,K)/V(P,K)))/(3.0207469570032))
+ **(1.26916507120526)
*** Grid current not modeled

C1 G K 2.5p
C2 P K 1.8p
C3 G P 1.5p
.ENDS ECF80t_k6



A model building tool for non-mathematical people is Curve Captor. It does diodes and triodes, but not pentodes. You can find it by searching this forum. It does models for several types of Spice ie 3F4, Pspice, LTSpice etc.
It will extract data graphically from the curves on data sheets, or you can enter a table of measured data points. It is a very good tool

For pentodes, I dont know of any easy to use software tool. I use various spreadsheets of my own design, but they are not really user friendly. I have been working on Access, C++ and VB versions that could result in a useable program, but it is a long way off, it is not my day job etc.

Others may know of pentode modelling tools.
__________________
Robert McLean

Last edited by Robert McLean; 8th January 2010 at 11:44 AM. Reason: to correct wrap-around problem due to text width
  Reply With Quote
Old 8th January 2010, 07:16 PM   #18
diyAudio Member
 
Join Date: Jan 2010
Location: Germany
Default error in devision ...

Robert,

Thanks a lot for your answer! I worked yesterday night several hours on this model

I try your model using b2spice V5, but unfortunately the simulation exited with an error:
>ERROR: external error: Error in division: -10651.6, 0 out of range for /
....multible times ....
>WARNING: SINGULAR MATRIX: CHECK NODES B:XX1:GS2#BRANCH AND 3
>WARNING: SOURCE STEPPING FAILED
>ERROR: doAnalyses: Matrix is singular
>ERROR: RUN SIMULATION(S) ABORTED

Any idea??


Well, this is realy frustrating At least I would like to USE the simulator....
I found a very nice tool named "motega_1.0" which using Matlab for calculating a Pspice model. For my delight a ECF80 is shipped as an example. But I´m not able to convert it to spice 3f4. So I searched for an "converter" and found a small perl script ps2sp.pl which does this job. I shrinked the output file to a single subcircuit. But.. a similar error:
>ERROR: external error: Error in division: -6.75751e+307, 0 out of range for /
>WARNING: SINGULAR MATRIX: CHECK NODES B:XX1:GS2#BRANCH AND 3

It´s O.K. to work hard on an challange; but I´m a newcomer on simulations and it´s hard to just jump in a black hole...

I attached all what I found and worked on. May be you have an idea??

Thanks a lot!
Karsten
Attached Files
File Type: txt ecc80_C.txt (967 Bytes, 53 views)
File Type: txt ECF80_T.txt (2.6 KB, 17 views)
File Type: txt ecf80_ps2sp.txt (886 Bytes, 20 views)
  Reply With Quote
Old 9th January 2010, 02:03 PM   #19
diyAudio Member
 
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Default model problems

Karsten
try this model. It is produced using CurveCaptor, and is in the 3F4 dialect.

* ECF80Triode Spice 3F4 model
.subckt ECF80_T P G K
Bp P K I=(0.07734143302m)*uramp(V(P,K)*ln(1.0+(-0.0324027279)+
+ exp((2.294384439)+(2.294384439)*((20.44231973)+(-346.3036329m)
+ *V(G,K))*V(G,K)/sqrt((31.45090171)^2+(V(P,K)-(15.9248421))^2)))
+ /(2.294384439))^(1.259575933)
.ends ECF80_T

Be careful with the continuation lines, the lines starting with + .
The model is actually one line starting at Bp, but it is too long so has to be broken up. Make sure whn you import this text that is doesnt get broken up, sometimes that causes strange problems.

The error messages seem to indicate a problem with the overall circuit, or how the tube subcircuit is connected into it. Singular matrices sometimes come up when there are components not connected etc. Is component XX1 the ECF80 ? I dont see a node GS2 in any of the models.

The model terminals are P G K. ( plate, grid, kathode ) Make sure this corresponds to the terminal names in your final spice net list. I notice in your files you are using a gr1 k ( anode, grid, and kathode ). You may have to change these to be consistent, depending on how your schematic capture program translates circuit symbols into the final spice net list.


Try the following ultra simple models to check this theory.

* ECF80Triode Spice 3F4 model
.subckt ECF80test1 P G K
Bp P K I=10m
.ends ECF80test1

* ECF80Triode Spice 3F4 model
.subckt ECF80test2 a gr1 k
Bp a k I=10m
.ends ECF80test2

these just pull 10 millamps no matter what voltages are present, obviously not a real tube model, but there is nothing in it to cause errors.

If neither of them work, then your overall circuit is wrong, ie missing a connection or something like that.

Have you tried any other triode spice models in this same circuit ?
Is this the only tube in the circuit you are testing ?

Can you post the spice netlist for your circuit ? This may give some clue as to what the error message is refering to as B:XX1:GS2
__________________
Robert McLean
  Reply With Quote
Old 10th January 2010, 05:56 PM   #20
diyAudio Member
 
Join Date: Jan 2010
Location: Germany
Default Works! But unexpected results...

Dear Robert,

Thanks a lot! The last model run now without any error. I checked also the dummy models ( very good idea! ) to ensure I created the part correctly.
I downloaded the "Curve Capture" and create an own ECF_80 triode model. For that I used the PCF80 datasheed; It´s a amazing programm but without any dokumentation. So It took me a while to understand how to load a image ( In fact I read the source to find it.. :-) )

The model works for DC-sweep as expected. I draw the plate cure with b2spice program using the model. The compare between datasheed, "Curve captor" and b2spice simulation is very good. So I should assume, that the AC or static DC "in circuit" simulation will work.

Well, try to evaluate a Cathode follower using the triode and datasheed to define working point the simulation return an unexpected value.
The grid is 129V ( from a plate of a pentode DC coupled ), HT 250V. I chouse a 18K value for the Rk to get an center based WP at Ug=129V.

Using your and my model URk and IRk are 0! Using a 12au7a model with same values it works; URk = 131V and IRk=7,295mA.

I assume that there is something wrong with b2spice; May be I exceed some values... Now it´s time to build the hardware, see if theory and reality match.

So again: Thank you verry much for your help, your patience with an spice newcomer and.. with my bad english

Best regards
Karsten
Attached Images
File Type: gif pcf80_b2spice.GIF (49.2 KB, 142 views)
File Type: gif pcf80_CurveCaptor.GIF (37.1 KB, 140 views)
File Type: gif PCF80_datasheed.GIF (58.9 KB, 136 views)
  Reply With Quote

Reply


Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Similar Threads
Thread Thread Starter Forum Replies Last Post
WTB: ECF80/6BL8 Tubes sun850 Swap Meet 0 15th January 2009 11:22 AM
Help with ECF80 spice model 00940 Tubes / Valves 0 1st November 2007 03:32 PM
ECF80/6BL8 Tobruk Tubes / Valves 4 1st May 2007 10:16 PM
Tube Spice Model Problem valveitude Tubes / Valves 5 5th July 2005 01:56 AM
SPICE model Prune Parts 6 16th October 2004 03:22 PM


New To Site? Need Help?

All times are GMT. The time now is 07:37 AM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2014 DragonByte Technologies Ltd.
Copyright ©1999-2014 diyAudio

Content Relevant URLs by vBSEO 3.3.2