Triode spice models for Circuit maker

[bogdan_borko]

Is there any triode spice models that can be used in Circuit Maker 2000?
What spice engine CM is using and what models?

[bogdan_borko]

the spice models I need:

ECC88(6DJ8)
ECC81(12AT7)
6N3P(2C51)

I got all of these models, but I can`t use them in CM 2000.

[wa2ise]

I have circuitmaker 2000, and this works for me

* 6DJ8 Spice 3F4 model
.SUBCKT X6DJ8 P G K
Bp P K I=(0.06867321543e-3)*uramp(V(P,K)*ln(1.0+(-0.03262478644)+exp((7.453794563)+(7.453794563)*((3 1.84399594)+(-13.80505589e-3)*V(G,K))*V(G,K)/V(P,K)))/(7.453794563))^(1.37713474)

C1 G K 3.1E-12
C2 G P 1.4E-12
C3 P K 0.18E-12

.ends X6DJ8

another version

*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)
.SUBCKT X6DJ8a 1 3 4
B1 2 4 I=((URAMP((V(2,4)/31)+V(3,4)))^1.5)/120
C1 3 4 3.1E-12
C2 3 1 1.4E-12
C3 1 4 0.18E-12
R1 3 5 10E+3
D1 1 2 DX
D2 4 2 DX2
D3 5 4 DX
.MODEL DX D(IS=1.0E-12 RS=1.0)
.MODEL DX2 D(IS=1.0E-9 RS=1.0)
.ENDS X6DJ8a


12AT7:

*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)
.SUBCKT X12AT7A A G K

* ANODE MODEL

BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037

BGG GG 0 V=V(G)-V(K)--0.5

BRP1 RP1 0 V=URAMP(-V(GG)* 0.09869 )

BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)

BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.1

BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.012937 )))

BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 45.093 )

BEP EP 0 V=(V(EM)^ 1.4 )*V(RP)* 0.00000863

BEL1 EL1 0 V=URAMP(V(EP))

BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))

BLD LD 0 V=URAMP(V(EP)-V(LI))

BAK A K I=V(EL)

* GRID MODEL

BGF GF 0 V=(URAMP(V(G)-V(K)--0.5 )^1.5)* 0.00012

BG G K I=V(GF)+V(LD)

* CAPS

CAK A K 0.0000000000004

CGK G K 0.0000000000023

CGA G A 0.0000000000016

.ENDS X12AT7A


don't have anything for the 6N3P

Other models I do have are at:
http://home.netcom.com/~wb2jia/tubes/spice.txt
http://home.netcom.com/~wb2jia/tubes/spice2.txt
http://home.netcom.com/~wb2jia/tubes/spice3.txt
http://home.netcom.com/~wb2jia/tubes/spice4.txt

[jackinnj]

in any of these programs you should take the Model and back into the curves in the RCA tube handbook (or other). The Koren models work well but they are in need of adjustment of some of the variables to acurately portray what's cookin down there in ECC83 land.