JJ Tesla ECC99 spice model

[Kashmire]

This valve has been out for some years now.

Anyone have access to a SPICE model of the JJ Tesla ECC99?

For such a great-sounding tube, there should be a design tool.

[runeight]

This is a PSpice model. If you need a Berkeley model, let me know.

Be careful with the LOG function. In this model it means natural log, which is sometimes written as LN. If your simulator uses LN for natrual log, then replace LOG with LN. If not, you're ok.

If you don't know, plot the curves. If they look right then you're good. If not, change it to LN and it should look right.

*
* Triode Model for ECC99
*
* Alex Cavalli
* 2003
*
* Based on models from Norman Koren
*
* Grid current is modeled with a diode.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*

.SUBCKT ECC99 1 2 3 ; P G C; NEW MODEL
E1 7 0 VALUE=
+{V(1,3)/500*LOG(1+EXP(500*(1/22+V(2,3)/SQRT(300+V(1,3)*V(1,3)))))}
G1 1 3 VALUE={(PWR(V(7),1.3)+PWRS(V(7),1.3))/362}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 5.8p
C2 2 1 5.1p
C3 1 3 0.91p
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 2000 ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=0 TT=1N)
.ENDS

[Kashmire]

Here's the B2Spice model.

Please check it. I haven't figured out how to add the grid current model.


* ecc99
* numbers by Alex Cavalli
* adaptation to B2Spice by stephenwmoore.com
*
.subckt ecc99 p g k
bp p k i=(2/362)*uramp(v(p,k)/500*log(1+exp(500*(1/22+v(g,k)/sqrt(300+v(p,k)*v(p,k))))))^1.3
cgk g k 5.8p
cgp g p 5.1p
cpk p k 0.91p
.ends ecc99

[Kashmire]

Something didn't look right, so I plugged the equation into excel and plotted a family of curves.

It doesn't match up exactly with the JJ datasheet, but it looks close.

[Kashmire]

Updated. Still doesn't exactly match datasheet curves, but is close. Maybe the original model was developed from real samples instead of the datasheet?

* ecc99
* numbers by Alex Cavalli
* adaptation to B2Spice by stephenwmoore.com
*
.subckt ecc99 p g k
bp p k i=(2/362)*uramp(v(p,k)/500*ln(1+exp(500*(1/22+v(g,k)/sqrt(300+v(p,k)*v(p,k))))))^1.3
cgk g k 5.8p
cgp g p 5.1p
cpk p k 0.91p
.ends ecc99

[Kashmire]

Here's the performance for Vg = -2, -4, -6, -8.

The blue dots are points from the data sheet on JJ's web site.

It works very good!

[PRR]

> I haven't figured out how to add the grid current model.

If you can't figure the syntax for B2Spice, just add a silicon diode in series with 2K from Grid to Cathode on your schematic. That is the same as the Koren model, just external to the tube model.

Koren's approximation isn't exact (doesn't try to be). If you need the exact mA grid current at +13V on the grid, you need a much more complicated model.

But in most audio, the grid-cathode voltage is always negative so grid current is always zero. You sure can drive grids positive, but the grid impedance drops from "infinite" to around 1K or 2K. And that is usually more trouble than the added plate current is worth.

In the heat of simulation you sometimes crank-up till grid-cathode voltage is swinging positive. If your grid driver had infinite current and zero Zout, that would not matter. But in most cases the driver has high output impedance (compared to positive-grid resistance), so SPICE will show you impossible things if it does not know about positive grid current.

The diode and resistor won't give the "exact" answer, but it will usually flat-top the wave, alerting you to the fact that you are driving a grid positive and should turn-down the drive. (Or beef-up the driver, and be aware that this grid-model won't give exact answers when running grid current.)

[Kashmire]

Let's see if I got the lesson right:

The model simulates 2k grid impedance only if the grid is going positive.

If I'm assured the simulation never applies a positive on the grid, then I don't need the grid model.

That's easy enough! Thanks.

I'm worried about how I'm using these models recently. I'm tweaking an SRPP to minimize even-order harmonics, especially 5th-9th. Are the models accurate enough to determine this?

For example, I'd like to know if a JJ ECC99 is lower distortion than a 6H30pi (of course, depending on the setup and power supply of the circuit).

I'm trying to answer the question if I should wire a 12V heater for the ECC99/12BH7 family of pinouts or a 6.3V heater for the 6CG7/6FQ7/6H30pi family of pinouts. It's going on a PCB, so once the boards are made, I've locked myself into using a particular pinout family.

The SRPP is driving a 50k load with at least 1500pF capacitance - most likely a bit more. I want to minimize even-order harmonics, with special attention to 5th-9th. The power supply hasn't been built, so I can use almost any voltage, even a CCS.

Under these assuptions, which pinout family will offer me the best tube for my application?

[pedroskova]

Originally posted by Kashmire
I want to minimize even-order harmonics, with special attention to 5th-9th.

OK, I'm confused. "5th -9th" means "6th & 8th" harmonics, as far as even harmonics go. WIth just about any triode circuit, shouldn't these be buried in the noise floor?

[Kashmire]

Ooops...

ODD is the word I was thinking about. "ODD". Opposite of "even".

5th through 9th are ODD, not even, I don't know what I was thinking.

Funny how the mind works.