PSpice simulation - diyAudio
Go Back   Home > Forums > Amplifiers > Tubes / Valves

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 3rd December 2014, 05:47 PM   #1
diyAudio Member
 
Join Date: Dec 2014
Default PSpice simulation

Hi everyone,
I'm trying to do a simulation of Bassman 5F6-A (1959) in PSpice. How can I simulate the output transformer? Use magnetic.lib from spice or create a new model? I don't know the core material to use magnetic.lib.

Anyone help me?


Click the image to open in full size.
  Reply With Quote
Old 5th December 2014, 02:06 PM   #2
udok is online now udok  Austria
diyAudio Member
 
Join Date: Jul 2011
Location: Austria
Use two coils L1 and L2 and couple them with the statement "K12 L1 L2 0.99".
  Reply With Quote
Old 8th December 2014, 01:59 AM   #3
diyAudio Member
 
Join Date: Oct 2004
Location: Adelaide South Oz
Universal Transformer Model.
This has Ultralinear Taps but just connect them to 0V via say 10Meg resistors for simulating the Bassman otherwise the simulator will have a "dummy spit". (Dummy is Oz vernacular for a babies pacifier).

**************************************
*
* Center Tap Audio Transformer,
* for push-pull tube operation,
* with screen grid taps
*
* TransPPSGT
*
* Primary Terminals
* P1, P2 plate connections
* Sg1, Sg2 screen grid connections
* B primary center tap (+Vpp)
* Secondary terminals
* Sp1, Sp2 speaker connections
*
*
* Parameters :
* RP one half primary winding resistance
* LA one half primary winding inductance
* LP one half primary inductance, plate to screen tap
* LS one half primary inductance, screen tap to center tap
* RA impedance ratio, primary plate-plate to secondary
* RS secondary winding resistance
*
* the parameters are related to frequency response as follows :
* let Rs = source resistance ( ie the load at the seen by the plate )
* let RL = load resistance ( ie the speaker )
* then RA = Rs/RL =n^2, where n is turns ratio, Ts/Tp
* let r1 = total primary winding resistance
* let r2 = total secondary winding resistance
* let F1 = upper 3dB frequency
* let F2 = lower 3dB frequency
* if 3dB points are not known, but 1 dB points are, then
* let F1' = upper 1dB frequency,
* let F2' = lower 1dB frequency
* then F1 = F1' x 2
* F2 = F2' / 2
*
* then calculate total series inductance La
* La = (Rs + r1 + (n^2)( RL + r2))/( 2 x pi x F1 )
*
* then calculate total parallel inductance Lb
* Lb = (Rs +r1)(RL + r2) (n^2)/((Rs + r1 +(n^2)(RL +r2))x 2 x pi x F2)
*
* then divide up La and Lb into the multiple windings required
* let t be the screen grid tap percentage,
* ie for a 40% screen grid tap, t = 0.40
* then the parameters are
* RP = r1 / 2
* RS = r2 (NOTE : RS is NOT Rs !!)
* LP = (1-t)Lb/2
* LS = t x Lb/2
* LA = La/2
*
* the default parameter values given are for an 8K to 8ohm transformer,
* with 40% screen grid taps,
* and 30 to 30KHz frequency response (15 to 60KHz 3dB response)
*
.SUBCKT TransPPSGT P1 Sg1 B Sg2 P2 Sp1 Sp2
* PARAMS: RP=25 LA=0.02234801 LP=13.3822388 LS=8.921493 RA=1000 RS=0.8
*
* primary
*
RP1 P1 1 {RP}
La1 1 2 {LA}
LP1 2 3 {LP}
LS1 4 5 {LS}
LS2 6 7 {LS}
LP2 8 9 {LP}
La2 9 10 {LA}
RP2 10 P2 {RP}
RP3 3 Sg1 1
RP4 Sg1 4 1
RP5 5 B 1
RP6 B 6 1
RP7 7 Sg2 1
RP8 Sg2 8 1

*
* secondary
*
Rs Sp1 11 {RS}
LSA 11 Sp2 {8*(LP +LS)/RA}

*
* coupling
*
Kcore1 LP1 LS1 .999999
Kcore2 LP1 LS2 .999999
Kcore3 LP1 LP2 .999999
Kcore4 LP1 LSA .999999
Kcore5 LS1 LS2 .999999
Kcore6 LS1 LP2 .999999
Kcore7 LS1 LSA .999999
Kcore8 LS2 LP2 .999999
Kcore9 LS2 LSA .999999
Kcore10 LP2 LSA .99999
.ENDS TransPPSGT


You should be able to modify this easily to suit the Bassman (or anything else).
Also have a look in the Vaccuum Tube Spice models sticky at the top to see if anyone has put output tranny models in there.

Cheers,
Ian

Last edited by gingertube; 8th December 2014 at 02:03 AM.
  Reply With Quote
Old 8th December 2014, 07:03 AM   #4
AllenB is offline AllenB  Australia
diyAudio Member
 
Join Date: Oct 2008
For a quick fix you could use an L//R.

Gingertube.. Do you know if this would fit into circuitmaker? Oh, and is Huey active on your side of the stump? There's no let up here, may try to hit up my car insurance for a spray job.
  Reply With Quote
Old 8th December 2014, 09:16 AM   #5
nl3prc is offline nl3prc  Netherlands
diyAudio Member
 
nl3prc's Avatar
 
Join Date: Mar 2012
Location: Den Helder The Netherlands
You can try this one if you have EXCEL running on your pc you can configure it yourself
Attached Files
File Type: zip transformer-test.zip (74.7 KB, 5 views)
  Reply With Quote
Old 8th December 2014, 09:00 PM   #6
diyAudio Member
 
Join Date: Oct 2004
Location: Adelaide South Oz
Quote:
Originally Posted by AllenB View Post
For a quick fix you could use an L//R.

Gingertube.. Do you know if this would fit into circuitmaker? Oh, and is Huey active on your side of the stump? There's no let up here, may try to hit up my car insurance for a spray job.
Not at all familiar with Circuitmaker. Have used the simulator which is part of the Altium Designer package but for day to day stuff I use this:
http://www.beigebag.com/
It has quite a few tube models "built in" and is the source of the above transformer model.

Cheers,
Ian
  Reply With Quote

Reply


Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Similar Threads
Thread Thread Starter Forum Replies Last Post
BJT model and fT simulation with PSpice MaxMagnificent Solid State 4 23rd February 2011 07:30 AM
BJT model and fT simulation with PSpice MaxMagnificent Solid State 0 22nd February 2011 07:16 PM
PSPICE simulation sunknu Everything Else 0 21st September 2006 09:30 AM
Pspice preamp simulation Antonix Tubes / Valves 8 10th January 2006 01:51 PM
PSpice Simulation annex666 Everything Else 1 25th November 2005 03:56 PM


New To Site? Need Help?

All times are GMT. The time now is 04:15 PM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2015 DragonByte Technologies Ltd.
Copyright 1999-2015 diyAudio

Content Relevant URLs by vBSEO 3.3.2