Vacuum Tube SPICE Models

Adams_Leo · 2017-08-08 1:35 am

Koonw said:
Try reverse the direction of R66. I found that long ago, not sure why the current phase is reversed.

Edit: in other sim, it shows the direction when you bring the cursor over the components, so please note.

You are right.just reverse the direction of R66.the current phase change to correct.thank you.

Adams_Leo · 2017-08-08 1:43 am

jazbo8 said:
You may want to check the LTSpice manual wrt the current flow convention.

has fixed this issue.you are right.my fault.

Adams_Leo · 2017-08-08 4:29 am

jazbo8 said:
You may want to check the LTSpice manual wrt the current flow convention.

would you please help to double check the EC86 SPICEL model and help to build EC88 SPICE model?

My current EC86 model seems does not work.
*
* Generic triode model: EC86
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sat Mar 8 22:42:35 2008
* Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT EC86 A G K
BGG GG 0 V=V(G,K)+0.22760069
BM1 M1 0 V=(0.0026112468*(URAMP(V(A,K))+1e-10))**-0.29355976
BM2 M2 0 V=(0.83632563*(URAMP(V(GG)+URAMP(V(A,K))/62.680543)+1e-10))**1.7935598
BP P 0 V=0.0095464624*(URAMP(V(GG)+URAMP(V(A,K))/74.947533)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0059140675*V(M1)*V(M2)
BIG IG 0 V=0.0047732312*URAMP(V(G,K))^1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.00496493*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 2.2p
CGK G K 3.5p
CAK A K 0.2p
.ENDS

here is the datasheet file.
http://www.tubebbs.com/tubedata/sheets/030/e/EC88.pdf
http://www.tubebbs.com/tubedata/sheets/030/e/EC86.pdf

Best Regards
Leo

Koonw · 2017-08-08 4:58 am

BIG IG 0 V=0.0047732312*URAMP(V(G,K))^1.5*

It doesn't work because there is still one more "^" in the above line, replaced with "**", should work.

Adams_Leo · 2017-08-08 5:11 am

Koonw said:
BIG IG 0 V=0.0047732312*URAMP(V(G,K))^1.5*

It doesn't work because there is still one more "^" in the above line, replaced with "**", should work.

Yeah,replace it and fixed it.thanks.

Koonw · 2017-08-08 6:21 am

This model is traced by me using CurveCaptor, Koren8 model, pretty close, maybe you like to use it, there is more than one way to get the model, included also the marker and data file for reference.

* ec88 LTSpice model
.subckt ec88 P G K
Bp P K I=(0.1271584816m)*uramp(V(P,K)*ln(1.0+(-0.08785188791)+exp((2.922603012)+(2.922603012)*((70.68877455)+(-2844.697934m)*V(G,K))*V(G,K)/sqrt((66.12972009)**2+(V(P,K)-(34.81182848))**2)))/(2.922603012))**(1.087629465)
Cgk G K 3.8p ; added
Cpk P K 0.055p ; added
Cgp G P 1.7p ; added
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends ec88

Adams_Leo · 2017-08-08 6:28 am

thanks you so much. Koonw

EL8 · 2017-08-10 8:56 am

Here is the EF14. it worked well in PSpice

**** EF14 ******************************************
* Created on 07/19/2017 Sam
*----------------------------------------------------------------------------------
.SUBCKT EF14 1 2 3 4 ; P G K G2
+ PARAMS: CCG=9.5P CGP=0.15P CCP=10P RGI=1000
+ MU=31.2 KG1=387 KP=82.4 KVB=11.4 KVC=1.57 VCT=-1.24 EX=1.2 KG2=7.33
*----------------------------------------------------------------------------------
RE1 7 0 1G ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+(VCT+V(2,3))/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
* Alexander Gurskii screen current, see audioXpress 2/2011
RE2 8 3 1G ; Dummy
G2 8 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG2*(KVC-ATAN(V(1,3)/KVB))}
E2 8 4 VALUE={0} ; Dummy
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CGP} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

Adams_Leo · 2017-08-10 8:59 am

any body can share the D3A Triode-Connected SPICE Model.This one is really good tube for the driver stage.

Thanks.

jazbo8 · 2017-08-10 9:13 am

See D3a triode – Bartola Valves

Adams_Leo · 2017-08-14 2:22 pm

Koonw said:
This model is traced by me using CurveCaptor, Koren8 model, pretty close, maybe you like to use it, there is more than one way to get the model, included also the marker and data file for reference.

* ec88 LTSpice model
.subckt ec88 P G K
Bp P K I=(0.1271584816m)*uramp(V(P,K)*ln(1.0+(-0.08785188791)+exp((2.922603012)+(2.922603012)*((70.68877455)+(-2844.697934m)*V(G,K))*V(G,K)/sqrt((66.12972009)**2+(V(P,K)-(34.81182848))**2)))/(2.922603012))**(1.087629465)
Cgk G K 3.8p ; added
Cpk P K 0.055p ; added
Cgp G P 1.7p ; added
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends ec88

I tried to use this model,but got an error.please refer to attached screen short.

jazbo8 · 2017-08-14 2:42 pm

May be some formatting issue, try this one: LTSpice tube models

Adams_Leo · 2017-08-14 2:58 pm

jazbo8 said:
May be some formatting issue, try this one: LTSpice tube models

Yes,thanks jazbo8,this model no error fond.it work fine.

Koonw · 2017-08-14 4:28 pm

Adams_Leo said:
I tried to use this model,but got an error.please refer to attached screen short.

I paste the wrong one, this one is working on pc, saved to a file.

vcoustics · 2017-08-23 5:45 pm

I have used the AN_26 from this Thread with great Success but does anyone have the Composite 26? I've seen Ale Bartola (image attached) has a schematic but anyone have the model?

jazbo8 · 2017-08-23 6:11 pm

Found it here.

vcoustics · 2017-08-23 8:40 pm

Amazing! Thank you jazbo8

d888sp4 · 2017-08-26 9:37 am

Hello everyone,
I'm designing a phono stage in LTSpice.
For the input stage I would like to use the EC8010, but I could not find the spice model.
Can anyone share the spice model of this triode?
Thank you very much.

Alberto.

matejsirk · 2017-08-26 1:29 pm

d888sp4 said:
Hello everyone,
I'm designing a phono stage in LTSpice.
For the input stage I would like to use the EC8010, but I could not find the spice model.
Can anyone share the spice model of this triode?
Thank you very much.

Alberto.

LTSpice tube models

post 25

cogsncogs · 2017-08-27 2:55 am

d888sp4 said:
Hello everyone,
I'm designing a phono stage in LTSpice.
For the input stage I would like to use the EC8010, but I could not find the spice model.
Can anyone share the spice model of this triode?
Thank you very much.

Alberto.

Code:

* EC8010_TF LTSpice model
* Modified Koren model (8 parameters): mean fit error 0.462343mA
* Traced on 3/23/2015 by Wayne Clay using Curve Captor v0.9.1 and
* Engauge Digitizer from Telefunken data sheet
.subckt EC8010  P G K
    Bp  P K  I=
+ (0.2131738609m)*uramp(V(P,K)*ln(1.0+(-0.09421188573)+exp((3.696690166)+
+ (3.696690166)*((62.74970209)+(-2822.087803m)*V(G,K))*V(G,K)/sqrt
+ ((52.12000848)**2+(V(P,K)-(3.725990169))**2)))/(3.696690166))**(1.146897295)
    Cgk G K 7.5p ; 1.0p added
    Cgp G P 2.5p ; 1.0p added
    Cpk P K 0.2p ; 0.1p added
    Rpk P K 1G ; to avoid floating nodes
    d3  G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends EC8010

Edit: I see matejsirk linked to my post with the same model(s).

Vacuum Tube SPICE Models

Member

Member

Member

Disabled Account

Member

Disabled Account

Attachments

Member

Member

Attachments

Member

Ex-Moderator

Member

Attachments

Ex-Moderator

Member

Disabled Account

Attachments

Member

Attachments

Ex-Moderator

Member

Member

Member

Member