Thanks for the quick responce! Also, why are Ayumi tube models much longer thank koren's? Koren's look like the models from ltspice's cmp folder and Ayumi's look like opamp or ic models.
I found this in my archives:
Code:
*
* Generic pentode model: EL83
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Fri Sep 18 10:19:14 2015
* Plate
* | Screen Grid
* | | Control Grid
* | | | Cathode
* | | | |
.SUBCKT EL83 A G2 G1 K
BGG GG 0 V=V(G1,K)+-0.58288162
BM1 M1 0 V=(0.027878725*(URAMP(V(G2,K))+1e-10))**-1.1736118
BM2 M2 0 V=(0.56103882*(URAMP(V(GG)+URAMP(V(G2,K))/15.745382)))**2.6736118
BP P 0 V=0.0078884298*(URAMP(V(GG)+URAMP(V(G2,K))/28.064693))**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.005914561*V(M1)*V(M2)
BIG IG 0 V=0.0039442149*URAMP(V(G1,K))**1.5*(URAMP(V(G1,K))/(URAMP(V(A,K))+URAMP(V(G1,K)))*1.2+0.4)
BIK2 IK2 0 V=V(IK,IG)*(1-0.4*(EXP(-URAMP(V(A,K))/URAMP(V(G2,K))*15)-EXP(-15)))
BIG2T IG2T 0 V=V(IK2)*(0.87412329*(1-URAMP(V(A,K))/(URAMP(V(A,K))+10))**1.5+0.12587671)
BIK3 IK3 0 V=V(IK2)*(URAMP(V(A,K))+4012.5)/(URAMP(V(G2,K))+4012.5)
BIK4 IK4 0 V=V(IK3)-URAMP(V(IK3)-(0.004369569*(URAMP(V(A,K))+URAMP(URAMP(V(G2,K))-URAMP(V(A,K))))**1.5))
BIP IP 0 V=URAMP(V(IK4,IG2T)-URAMP(V(IK4,IG2T)-(0.004369569*URAMP(V(A,K))**1.5)))
BIAK A K I=V(IP)+1e-10*V(A,K)
BIG2 G2 K I=URAMP(V(IK4,IP))
BIGK G1 K I=V(IG)
* CAPS
CGA G1 A 0.07p
CGK G1 K 8.4p
C12 G1 G2 5.6p
CAK A K 8p
.ENDS
So far I did compare your ECC81 model against Philips ECC81 and GE 12AT7, it does not fit.
Could you please tell me which ECC81 fits with your model?
Thanks in advance.
Just realized that your model is based on a real valve through a curve tracer.
Entschuldigung.
Hi popilin
Yes I prefer to fit my models to measured data, because datasheets very often containes no or just rudimentary grid current data. Especially the grid "Anlauf" current is never described in datasheets.
It was a Philips Miniwatt ECC81, NOS, so its Transconductance is a bit higher than the datasheet says (and will reduce over lifetime).
all the best, Adrian
Hi rankot
Yes, I plan to add more models.
Up to now, I have to do the measurements my hand (Multimeters), that means about 2 -3 hours of work. But I'm developing an iTracer (capable to measure grid current including "Anlauf current") to faster get the measured data. It will be finished in spring, I guess. And of course there is a certain risk that this project fails, especially the totally new logarithmic Ig amplifier intended to measure from 1nA to 100mA without any range switch. We will see...
all the best, Adrian
Yes I prefer to fit my models to measured data, because datasheets very often containes no or just rudimentary grid current data. Especially the grid "Anlauf" current is never described in datasheets.
It was a Philips Miniwatt ECC81, NOS, so its Transconductance is a bit higher than the datasheet says (and will reduce over lifetime).
all the best, Adrian
Hi rankot
Yes, I plan to add more models.
Up to now, I have to do the measurements my hand (Multimeters), that means about 2 -3 hours of work. But I'm developing an iTracer (capable to measure grid current including "Anlauf current") to faster get the measured data. It will be finished in spring, I guess. And of course there is a certain risk that this project fails, especially the totally new logarithmic Ig amplifier intended to measure from 1nA to 100mA without any range switch. We will see...
all the best, Adrian
jazbo8?
Koonw?
Wouldn't that be a case for you?
(My approach would be a nonsense as I would have to guess 8 of 14 parameters due to lack of Ig data in the found datasheets)
101D LTspice models
Code:
* ==============================================================
* 101D LTSpice model
* Rydel model (5 parameters): mean fit error 0.100848mA
* Traced by Wayne Clay on 02/15/2019 using Engauge Digigtizer and
* Curve Captor v0.9.1 from Western Electric data sheet
* ==============================================================
.subckt 101D P G K
Bp P K I=
+ ((0.01394315566m)+(2.959899593e-05m)*V(G,K))*uramp((6.164604113)*
+ V(G,K)+V(P,K)+(-5.467657615))**1.5 * V(P,K)/(V(P,K)+(1.541179666))
Cgp G P 7.1p ; 0.5p added (6.4p)
Cgk G K 4.9p ; 0.5p added (4.4p)
Cpk P K 3.4p ; 0.5p added (2.9p)
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 101D
Code:
*
* Generic triode model: 101D_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Fri Feb 15 13:47:22 2019
* Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 101D_AN A G K
BGG GG 0 V=V(G,K)+1
BM1 M1 0 V=(0.0038602025*(URAMP(V(A,K))+1e-10))**-0.038461538
BM2 M2 0 V=(0.975*(URAMP(V(GG)+URAMP(V(A,K))/6.4763442)+1e-10))**1.5384615
BP P 0 V=0.00019674697*(URAMP(V(GG)+URAMP(V(A,K))/6.6424043)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.00017088867*V(M1)*V(M2)
BIG IG 0 V=9.8373487e-05*URAMP(V(G,K))**1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0001444357*URAMP(V(A,K))**1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 6.4p
CGK G K 4.4p
CAK A K 2.9p
.ENDSAttachments
What happened? 6.4+0.5=6.9 not 7.1 
Corrected below.
Corrected below.
Code:
* ==============================================================
* 101D LTSpice model
* Rydel model (5 parameters): mean fit error 0.100848mA
* Traced by Wayne Clay on 02/15/2019 using Engauge Digigtizer and
* Curve Captor v0.9.1 from Western Electric data sheet
* ==============================================================
.subckt 101D P G K
Bp P K I=
+ ((0.01394315566m)+(2.959899593e-05m)*V(G,K))*uramp((6.164604113)*
+ V(G,K)+V(P,K)+(-5.467657615))**1.5 * V(P,K)/(V(P,K)+(1.541179666))
Cgp G P 6.9p ; 0.5p added (6.4p)
Cgk G K 4.9p ; 0.5p added (4.4p)
Cpk P K 3.4p ; 0.5p added (2.9p)
Rpk P K 1G ; to avoid floating nodes
d3 G K dx1
.model dx1 d(is=1n rs=2k cjo=1pf N=1.5 tt=1n)
.ends 101DExtracted from pctube Ver 1.21 Linux:
View attachment pctube.r.pdf
(you need to remove the pdf suffix first)
(you need to remove the pdf suffix first)
Maybe DIYaudio should maintain a spice model repository indexed by tube type.
Vacuum tube WIKI for LTSpice perhaps?
Same exists for semi's, optos etc.
I look for the possibility to simulate with dual control pentode 6HZ6 and I found this model:
Can anyone modify it to work with standard Pentode symbol of LT Spice ?
Code:
*Vacuum Tube dual control
.SUBCKT X6HZ6 A 3 S G K
*model written to use op-amp symbol +in=g1,-in=g3, +supply=g2g4, -supply=kg5, out=plate
*work in progress, not final
* Calculate contribution to cathode current
*
*the number at the right end determines sharpness of knee
Bat at 0 V=0.636*ATAN(V(A,K)/24)
*the URAMP(V(S,K)/# mostly determines peak plate current, grid line spacing nearly constant
*the number at the right end determines slope of grid lines (plate resistance)
Bgs gs 0 V=URAMP((V(S,K)*1.1964+V(G,K)*43.75+V(A,K)*0))
Bgss gss 0 V=URAMP((V(S,K)*0.0005)+(-(URAMP((SQRT(URAMP(V(K,3))^2.7)))/((((SQRT(V(A,K))^1.5)/5)^1)))*0.0405+V(A,K)/9400))*1+((URAMP(V(3,K))/((SQRT(V(A,K))*11)))*1)*0.5
*the exponent sets the linearity of grid line spacing, and big impact on peak plate currrent
Bgs2 gs2 0 V=V(gs)^1.5
Bgs3 gs3 0 V=V(gss)^1.5
Bcath cc 0 V=V(gs2)*(V(at))
Ban an 0 V=V(gs2)*(V(gs3))*(V(at))
*
* Calculate anode current, grid line spacing adjust and peak plate current
*
Ba A K I=0.395E-3*V(an)
*
* Calculate screen current
*
Bscrn sc 0 V=V(gs2)*(1.0-V(at)*0.9)
Bs S K I=(URAMP(0.34E-3*V(sc)-(1.95E-3*(V(an)))))*0.29*(V(at))*0.37
*
* Grid current (approximation - does not model low va/vs)
*
Bg G K I=(URAMP(V(G,K)+1)^1.5)*50E-6
*
* Capacitances
*
Cg1 G K 5.5p
Cak A K 7.5p
Cg3 3 S 5.6p
Cg1g3 G 3 0.09p
Cg1a G A 0.02p
Cg3a 3 A 1.6p
.ENDS X6HZ6Can anyone modify it to work with standard Pentode symbol of LT Spice ?