6146B SPICE model wanted - diyAudio
Go Back   Home > Forums > Amplifiers > Tubes / Valves

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 24th February 2012, 04:56 AM   #1
diyAudio Member
 
Join Date: Feb 2012
Default 6146B SPICE model wanted

Hi folks,

I am using NI Multisim 11 and trying to build a 6146B pentode model. Does anyone have a "pentode connected" 6146 Spice Model for me ???

Thanks in advance...
  Reply With Quote
Old 24th February 2012, 09:01 AM   #2
diyAudio Member
 
Join Date: May 2007
What about using Google? This one is one of the first that comes up. It is for the diyaudio-standard LTSpice. Intactaudio ´s Sim City is invaluable.

:: View topic - Drop Down Menus for selecting your tube
  Reply With Quote
Old 24th February 2012, 11:04 AM   #3
diyAudio Member
 
Join Date: Feb 2012
revintage, I did google it but the LTSpice Model of 6146 doesnot work with NI Multisim 11. I tried that out already..
  Reply With Quote
Old 24th February 2012, 12:35 PM   #4
diyAudio Member
 
cogsncogs's Avatar
 
Join Date: Jul 2003
Location: Wayne, West Virginia
May be the wrong flavor of spice. I don't know since I haven't tried Multisim.
Here's a couple others I have:
Code:
*Vacuum Tube Tetrode 6146
.SUBCKT X6146 A S G K
*
* Calculate contribution to cathode current
*
Bat    at  0    V=0.636*ATAN(V(A,K)/10)
Bme    me  0   V=URAMP(V(A,K)/130)
Bmup    mup 0    V=1-(URAMP(V(K,G)-30)/2000)
Bmu     mu  0    V=V(G,K)*V(mup)
Bgs    gs  0    V=URAMP(V(S,K)*4.5+V(mu)*19+URAMP(V(A,K))/10)
Bgs2    gs2 0    V=(V(gs)^1.5)*16E-6
Bsd    sd  0    V=URAMP(V(gs2)*V(at)-v(me))
Bcath    cc  0    V=V(gs2)*V(at) - V(sd)
*
* Calculate anode current
*
Ba    A   K    I=V(cc)
*
* Calculate screen current
*
Bscrn    sc  0    V=2.5E-4*(V(S,K)^1.5)*V(gs2)*(1.1-V(at))+V(sd)
Bs    S   K    I=V(sc)
*
* Grid current
*
*Bg    G   K    I=(URAMP(V(G,K)+1)^1.5)*(1.25-V(at))*870E-6
*
* Capacitances
*
Cg1    G    K    13.0p
Cak    A    K    8.5p
Cg1a    G    A    0.24p

.ENDS X6146
Code:
*
* Generic pentode model: 6146B
* Copyright 2003--2006 by Ayumi Nakabayashi, All rights reserved.
* Version 3.01, Generated on Wed Mar 22 17:22:51 2006
.SUBCKT 6146B A G2 G1 K
BGG   GG   0 V=V(G1,K)+0.99999998
BEP   EP   0 V=URAMP(V(A,K))+1e-10
BEG   EG   0 V=URAMP(V(G1,K))+1e-10
BEG2  EG2  0 V=URAMP(V(G2,K))+1e-10
BM1   M1   0 V=(0.058258554*(URAMP(V(EG2)-1e-10)+1e-10))^-0.41427032
BM2   M2   0 V=(0.78358839*(URAMP(V(GG)+V(EG2)/3.7146753)+1e-10))^1.9142703
BP    P    0 V=0.001563206*(URAMP(V(GG)+V(EG2)/4.7405951)+1e-10)^1.5
BIK   IK   0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0009173158*V(M1)*V(M2)
BIG   IG   0 V=0.000781603*V(EG)^1.5*(V(EG)/(V(EP)+V(EG))*1.2+0.4)
BIK2  IK2  0 V=V(IK,IG)*(1-0.4*(EXP(-V(EP)/V(EG2)*15)-EXP(-15)))
BIG2T IG2T 0 V=V(IK2)*(0.956750418*(1-V(EP)/(V(EP)+10))^1.5+0.043249582)
BIK3  IK3  0 V=V(IK2)*(V(EP)+3004)/(V(EG2)+3004)
BIK4  IK4  0 V=V(IK3)-URAMP(V(IK3)-(0.0013014595*(V(EP)+URAMP(V(EG2,EP)))^1.5))
BIP   IP   0 V=URAMP(V(IK4,IG2T)-URAMP(V(IK4,IG2T)-(0.0013014595*V(EP)^1.5)))
BIAK  A    K I=V(IP)+1e-10*V(A,K)
BIG2  G2   K I=URAMP(V(IK4,IP))
BIGK  G1   K I=V(IG)
* CAPS
CGA   G1  A  0.22p
CGK   G1  K  7.7p
C12   G1  G2 5.1p
CAK   A   K  8.3p
.ENDS
  Reply With Quote
Old 25th February 2012, 05:29 AM   #5
diyAudio Member
 
Join Date: Feb 2012
Thanks a lot cogsncogs. That really helped. I am still stuck though. I am trying to simulate the circuit to measure the characteristics. The circuit I rigged up is in the figure. I used the same circuit for 6V6GTA curve and I got a good match. But 6146B im no where. Can some one please give me a few pointers as to what is wrong? The model Im using is the second one given by cogsncogs. I tried the other models but no use.
Attached Images
File Type: png VAmp.png (8.1 KB, 118 views)
  Reply With Quote
Old 25th February 2012, 09:50 AM   #6
diyAudio Member
 
Join Date: May 2007
Yes, that one is totally useless. Have you converted now, looks like LTSpice to me?

Make a tetrode.asc from this. If it doesn´t work, I can mail the *.asc to you.

Version 4
SHEET 1 880 680
WIRE -416 -64 -560 -64
WIRE -544 48 -640 48
WIRE -416 48 -464 48
WIRE -640 64 -640 48
WIRE -416 96 -416 48
WIRE -560 112 -560 -64
WIRE -560 112 -592 112
WIRE -688 128 -768 128
WIRE -672 208 -672 176
WIRE -640 208 -672 208
WIRE -416 208 -416 176
WIRE -416 208 -640 208
WIRE -768 224 -768 208
WIRE -640 224 -640 208
FLAG -640 224 0
FLAG -768 224 0
FLAG -416 16 0
SYMBOL Misc\\battery -416 80 R0
SYMATTR InstName V4
SYMATTR Value {Ua2}
SYMBOL Misc\\battery -768 112 R0
WINDOW 0 -68 89 Left 0
WINDOW 3 -87 15 Left 0
WINDOW 123 0 0 Left 0
WINDOW 39 0 0 Left 0
SYMATTR InstName V5
SYMATTR Value {Ug2}
SYMBOL Misc\\tetrode -640 112 R0
WINDOW 0 6 -80 Left 0
SYMATTR InstName U2
SYMATTR Value 6AU6
SYMBOL res -448 32 R90
WINDOW 0 0 56 VBottom 0
WINDOW 3 32 56 VTop 0
SYMATTR InstName R6
SYMATTR Value 1n
SYMBOL Misc\\battery -416 -80 R0
WINDOW 123 0 0 Left 0
WINDOW 39 0 0 Left 0
SYMATTR InstName V6
SYMATTR Value 150
TEXT -728 -8 Left 0 !.op
TEXT -656 336 Left 0 !.step param Ua2 0 300 5
TEXT -656 296 Left 0 !.step param Ug2 0 -3 .5
TEXT -656 376 Left 0 !.inc tetrode.inc
  Reply With Quote
Old 25th February 2012, 12:06 PM   #7
diyAudio Member
 
Join Date: May 2007
As you surely understand, but maybe not all, just click the anoderesistor to plot the curves.

Last edited by revintage; 25th February 2012 at 12:10 PM.
  Reply With Quote
Old 27th February 2012, 04:52 AM   #8
diyAudio Member
 
Join Date: Feb 2012
Thanks for the circuit revintage.. It works like a dream yes! I switched over to LTSpice. I changed the lines
Quote:
TEXT -656 336 Left 0 !.step param Ua2 0 300 5
TEXT -656 296 Left 0 !.step param Ug2 0 -3 .5
to
.dc Ua2 0 800 1 Ug2 -50 30 10
Ive attached the circuit and the curve image. Thanks a lot..
Attached Images
File Type: png 6146B.Curves.png (7.8 KB, 98 views)
File Type: png Pentode.Graph.png (5.3 KB, 97 views)
  Reply With Quote
Old 27th February 2012, 07:36 AM   #9
diyAudio Member
 
Join Date: May 2007
You´re using nonstandard LTSpice commands. Will come back with the correct ones after work.

Off course works with whatever you use.
  Reply With Quote
Old 27th February 2012, 10:54 AM   #10
diyAudio Member
 
Join Date: May 2007
As both works equally well you can go with your. Normally I use the ".step param V1...."-commands.
  Reply With Quote

Reply


Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Similar Threads
Thread Thread Starter Forum Replies Last Post
6CB6 Spice Model wanted Alain Poitras Tubes / Valves 27 27th April 2014 08:56 AM
F.S.: 6146B Cobra2 Swap Meet 3 14th January 2011 10:49 PM
SPICE model for 6AK5 wanted! d2134 Tubes / Valves 1 1st April 2008 11:39 PM
SPICE model Prune Parts 6 16th October 2004 03:22 PM
Spice model doigtee Tubes / Valves 6 12th July 2003 11:42 AM


New To Site? Need Help?

All times are GMT. The time now is 02:58 AM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2014 DragonByte Technologies Ltd.
Copyright ©1999-2014 diyAudio

Content Relevant URLs by vBSEO 3.3.2