6sj7 spice model

[sulcorebutia]

Dear All,

Does anybody has a ltspice/pspice model of 6sj7 /6ac7 octal pentode? I have searched through the forum. If anybody is kind enough, would you share it with us?

million thx

[singh santa]

Hi,

.SUBCKT 6SJ7 A G2 G1 K
BGG GG 0 V=V(G1,K)+0.40161932
BEP EP 0 V=URAMP(V(A,K))+1e-10
BEG EG 0 V=URAMP(V(G1,K))+1e-10
BEG2 EG2 0 V=URAMP(V(G2,K))+1e-10
BM1 M1 0 V=(0.02462593*(URAMP(V(EG2)-1e-10)+1e-10))**-0.84287662
BM2 M2 0 V=(0.64023858*(URAMP(V(GG)+V(EG2)/14.609049)+1e-10))**2.3428766
BP P 0 V=0.0011655656*(URAMP(V(GG)+V(EG2)/22.818133)+1e-10)**1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.00071703729*V(M1)*V(M2)
BIG IG 0 V=0.00068041382*V(EG)**1.5*(V(EG)/(V(EP)+V(EG))*1.2+0.4)
BIK2 IK2 0 V=V(IK,IG)*(1-0.4*(EXP(-V(EP)/V(EG2)*15)-EXP(-15)))
BIG2T IG2T 0 V=V(IK2)*(0.78466568*(1-V(EP)/(V(EP)+10))**1.5+0.21533432)
BIK3 IK3 0 V=V(IK2)*(V(EP)+12950)/(V(EG2)+12950)
BIK4 IK4 0 V=V(IK3)-URAMP(V(IK3)-(0.00044226898*(V(EP)+URAMP(V(EG2,EP)))**1.5))
BIP IP 0 V=URAMP(V(IK4,IG2T)-URAMP(V(IK4,IG2T)-(0.00044226898*V(EP)**1.5)))
BIAK A K I=V(IP)+1e-10*V(A,K)
BIG2 G2 K I=URAMP(V(IK4,IP))
BIGK G1 K I=V(IG)
* CAPS
CGA G1 A 0.005p
CGK G1 K 3.6p
C12 G1 G2 2.4p
CAK A K 7p
.ENDS

SS

[revintage]

If Singh´s model doesn´t work try Steve Bench´s:

:: View topic - Updated Tube Models

Lots of useful info at Sim City!

[sulcorebutia]

Thx revintage and Singh Santa. You two are the best

[Robert McLean]

I just wanted to add a couple of things.

Singh Santa
I think the model that you posted is very good. It uses some interesting formulas. I have sent you a PM for more information if that is OK.

Revintage
Thanks for the link to SimCity, I was not previously aware of it.

Robert.

[revintage]

Hey Robert,

These are the libraries where singh santa´s model comes from. Great models but remember to change all ^ to **.

[Robert McLean]

Lars
Thanks, I will take some time to study these.

Robert

[jeapel]

hi
I just download steve bench tube data and singh santa tube data so
i would like to learn win xp tube simulation free software but steve and singh
data are for spice or pspice or ltspice or ???
thanks

[singh santa]

Hello,
I use ltspice,its free.
Cheers!
SS

[Mosquito]

Hi
IIs the 6SJ7 model close enough to the 6J7 behavior, at least for simulation purposes?
Or better, a circuit optimized around the 6SJ7 model, can reasonably work with an 6J7 in place?
Thanks
J