PSpice model of output transformer - diyAudio
Go Back   Home > Forums > Amplifiers > Tubes / Valves

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 7th August 2008, 04:13 PM   #1
oshifis is offline oshifis  Hungary
diyAudio Member
 
Join Date: Mar 2004
Location: Budapest, Hungary
Default PSpice model of output transformer

Hi all,

I am new in this field, and I want to use PSpice for modelling audio circuits (mostly tube circuits). I downloaded the tube.lib from Norman L. Koren's site:

http://www.normankoren.com/Audio/Tub...e_article.html

I am really stuck in creating a model of output transformer. It should be quite simple, a primary with a center tap, a secondary with a center tap. It can be characterized by the turns ratio in the first run. (Its model can be modified later by including primary and secondary inductance, coupling coefficient or stray inductance, and primary and secondary resistance, and later perhaps self and mutual capacitances). Do you know of any good SPICE model of such transformer?

I attached my schematics (a working amplifier of my design, that I want to optimize with SPICE). The problem is when I run simulation, it gives an error which is most probably related to the output transformer. I tried to edit the OUTPUT_XFRMR symbol, but no avail. Could someone please have a look at my schematics, and help me find what is the problem? Please forgive me if it is a very stupid problem, but as I said, I am an absolute beginner.

Thanks in advance,

Laszlo
  Reply With Quote
Old 8th August 2008, 05:10 AM   #2
exeric is offline exeric  United States
diyAudio Member
 
Join Date: Mar 2008
I couldn't find your schematic.
  Reply With Quote
Old 8th August 2008, 10:41 AM   #3
oshifis is offline oshifis  Hungary
diyAudio Member
 
Join Date: Mar 2004
Location: Budapest, Hungary
Here is my schematics. I replaced OUTPUT_XFRMR with DYNA_OUTPUT_XFRMR. Now it does work, I just have to figure out how to do AC and Fourier analysis.
  Reply With Quote
Old 8th August 2008, 02:17 PM   #4
diyAudio Member
 
jackinnj's Avatar
 
Join Date: Apr 2002
Location: Llanddewi Brefi, NJ
Here's the Multisim audio transformer model

.SUBCKT ts_audio_ideal 1 2 3 4 5
* EWB Version 4 - Transformer Model
* n= 2 Le= 1e-006 Lm= 0.001 Rp= 1e-006 Rs= 1e-006
Rp 1 6 1e-006ohm
Rs1 10 3 1e-006ohm
Rs2 11 5 5e-007ohm
Le 6 7 1e-006H
Lm 7 2 0.001H
E1 9 8 7 2 0.25
E2 8 4 7 2 0.25
V1 9 10 DC 0V
V2 8 11 DC 0V
F1 7 2 V1 0.5
F2 7 2 V2 0.5
.ENDS

Here's a model for a power transformer using K coupling factors:

.SUBCKT ts_pwr_10_to_1 1 2 3 4 5
* *1, 2-- primary winding, *3,4-- secondary terminal, 5-- neutural
Rs1 1 11 1.000e-3
Rl2 31 3 1.000e-3
Rl3 41 4 1.000e-3
L1 11 2 5.000e+000
L2 31 5 5.000e-002
L3 5 41 5.000e-002
K12 L1 L2 9.999e-001
K13 L1 L3 9.999e-001
K23 L2 L3 9.999e-001
.ENDS

For a center tap use the transformer backwards and adjust the inductance to reflect the primary and secondary impedances.

You might find the 2nd set easier to use -- if you are modeling a real world transformer you would probably put in interwinding coupling capacitance between nodes 11 and 31 of a few hundred pF's, and some additional inductance on the primary and secondary.
  Reply With Quote
Old 8th August 2008, 03:02 PM   #5
oshifis is offline oshifis  Hungary
diyAudio Member
 
Join Date: Mar 2004
Location: Budapest, Hungary
Thanks, I can at least start with this. Also the DYNA_OUTPUT_XFRMR does work, I just need to adjust the parameters of the transformer.

----------------------------------------
.SUBCKT DYNA_OUTPUT_XFRMR 1 2 3 4 5 6 7 8 9 ; PARAMETERS FOR MARK 3:
+PARAMS: LPRIM=60 LLKG=.040 RPRIM=125 CPRIM=1.04NF LRATIO={4/4300}

* ERIC BARBOUR ARTICLE: ~233H TOTAL PRIMARY L FOR MARK 3.
* MARK 3: LPRIM=60 LLKG=.040 RPRIM=125 CPRIM=1.04NF LRATIO={4/4300}

* LPRIM IS THE TOTAL PRIMARY L (VARIES WITH MEASUREMENT).
* LLKG IS THE LEAKAGE L (MEASURABLE: CONSISTENT).
* RPRIM IS THE TOTAL PRIMARY R.
* CPRIM IS THE MEASURED PRIMARY CAPACITANCE.
* LRATIO IS THE INDUCTANCE RATIO: (4 OHMS)/(PRIMARY Z).

.PARAM QFCTR={LPRIM/LLKG} ; Q-FACTOR.
CS1 1 5 {CPRIM} ; PRIMARY CAPACITANCE
RS1 1 5 300K ; SHUNT R FOR HIGH FREQUENCY EFFECTS.
LP1 1 12 {LPRIM*.09} ; .7164H ; PRIMARY
RP1 12 2 {RPRIM*.5}
LP2 2 3 {LPRIM*.04} ; .3184H
LP3 3 4 {LPRIM*.04}
LP4 4 45 {LPRIM*.09}
RP4 45 5 {RPRIM*.5}
LP5 7 6 {.34315*LPRIM*LRATIO} ; 8-16 OHM WINDING: (2-SQRT(2))^2
LP6 8 7 {.17157*LPRIM*LRATIO} ; 4-8 OHM WINDING: (SQRT(2)-1)^2
LP7 9 8 {LPRIM*LRATIO} ; COM-4 OHM WINDING
KALL LP1 LP2 LP3 LP4 LP5 LP6 LP7 {1-1/(2*QFCTR)} ; COUPLING
.ENDS

----------------------------------------

My other problem is that I can not find the diode.slb library. I found diode.lib and diode.olb, but I can not convert them to diode.slb whatever I do. Any advice would be appreciated
  Reply With Quote

Reply


Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Similar Threads
Thread Thread Starter Forum Replies Last Post
spice model for UL output transformer? docali Tubes / Valves 30 5th May 2013 01:52 AM
New 12AX7A Pspice model eppidei Tubes / Valves 17 20th January 2008 07:01 AM
I need 2SC2570 PSPICE Model xitronics Parts 1 10th July 2006 09:29 AM
HIP4080A pspice model Anthony C Smith Class D 1 3rd January 2006 08:52 PM
output transformer spice model Paracelsus Tubes / Valves 6 9th September 2005 03:52 PM


New To Site? Need Help?

All times are GMT. The time now is 04:13 AM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2014 DragonByte Technologies Ltd.
Copyright 1999-2014 diyAudio

Content Relevant URLs by vBSEO 3.3.2