Go Back   Home > Forums > >
Home Forums Rules Articles diyAudio Store Blogs Gallery Wiki Register Donations FAQ Calendar Search Today's Posts Mark Forums Read

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

SPICE model for 6AK5 wanted!
SPICE model for 6AK5 wanted!
Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Thread Tools Search this Thread
Old 27th March 2008, 04:34 AM   #1
d2134 is offline d2134  Romania
diyAudio Member
Join Date: Mar 2007
Send a message via Yahoo to d2134
Default SPICE model for 6AK5 wanted!


I need a Berkeley SPICE 3f4 compatible model for 6AK5 pentode or equivalents (EF95 - European, 6J1P - Russian, 6F32 - "TESLA").

Thank you!
  Reply With Quote
Old 2nd April 2008, 12:39 AM   #2
Robert McLean is offline Robert McLean  Canada
diyAudio Member
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Here is a model for 6AK5 that I have developed. The data I have does not include control grid current, so the model is not accurate in that respect. Also, I dont know if this is 3F4 compatible or not, I have forgotten all the conversions. It works with LTSpice. If it is not 3F4 compatible, then some day I will do a translation, but not today.

* Pentode model based on my investigations
* see Excel spreadsheets BeamDLPentode.xls
* this model therefore uses Korens method for total current, and diode lines.
* similart to Pentode1, but with revised Capture Ratio formula
* R McLean 1 Apr 2008
.Subckt 6AK5 A S G K
+ Params: Ex=1.919796584 Mug=28.62765031 Mus=5.93E+02 Kg1=1241.263033 Kp=87.71075724
+ Kvb=0.001045715 Go=-0.174882604 Kd=5.00E-02 Exd=1.018581504 Exsd=1.106610165
+ C1= -20.45944113 A1=-0.001923837 B1=20.33820425 X1=0.011665792 Y1= 0.000268033 Sr=0.032709138
+ Cgk=4P Cgs=.5P Cga=0.03P Cak=2.8P

* calculate the total space current based on Koren's triode equations,
* but with an equivalent triode plate volatage equal to the pentode Vs + Vp/Mus
En1 n1 0 VALUE={(V(A,K)/Mus+V(S,K))/Kp*LN(1+EXP(Kp*(1/Mug+(V(G,K)-Go)/SQRT(Kvb+(V(A,K)/Mus+V(S,K))**2))))}
Esc sc 0 VALUE={ (PWR(V(n1),Ex)+PWRS(V(n1), Ex))/(Kg1) }

* calculate the plate current capture ratio
Ecr cr 0 Value={If(V(A,K)<=0,0,C1+A1*V(A,K)+B1*((limit(V(A, G),1,1e6)**X1)/(limit(V(S,G),1,1e6)**Y1)))}

* the tentative plate current is total space current multiplied by capture ratio
Ept pt 0 Value={V(sc)*V(cr)}

* calculate the diode line current
Ed d 0 value={Kd*V(A,K)**Exd*V(S,K)**Exsd}

* the actual Plate current is the lesser of pt and d
Ep p 0 value={Min(V(d),V(pt))}
Ga A K value={V(p)}

* calculate the screen current capture ratio
* if Vg <= 0 then the screen gets all the remaining current, otherwise the grid gets some
Escr scr 0 value={Limit(if(V(G,K)>0,1-Sr*V(G,K),1),0,1)}

* screen current is anything not captured by the plate, multiplied by screen capture ratio
Esg sg 0 value={(V(sc)-V(p))*V(scr)}
Gs S K value={V(sg)}

* grid current is anything not captured by the plate or the screen
Gg G K value={V(sc)-v(p)-V(sg)}

* interelectrode capacitances
C1 G K {Cgk}
C2 G S {Cgs}
C3 G A {Cga}
C4 A K {Cak}
Robert McLean
  Reply With Quote


SPICE model for 6AK5 wanted!Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

Similar Threads
Thread Thread Starter Forum Replies Last Post
Help With 6v6 Spice Model porcatroya Tubes / Valves 0 5th May 2008 07:41 AM
SPICE model Prune Software Tools 6 16th October 2004 04:22 PM
Does anybody have an lm3886 SPICE model? Faber Chip Amps 0 14th July 2004 01:31 PM
Spice model doigtee Tubes / Valves 6 12th July 2003 12:42 PM
Spice model for LED? G Solid State 5 14th September 2002 04:33 AM

New To Site? Need Help?

All times are GMT. The time now is 01:22 PM.

Search Engine Optimisation provided by DragonByte SEO (Pro) - vBulletin Mods & Addons Copyright © 2017 DragonByte Technologies Ltd.
Resources saved on this page: MySQL 16.67%
vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2017 DragonByte Technologies Ltd.
Copyright ©1999-2017 diyAudio