SPICE model for 6AK5 wanted!

[d2134]

Hi,

I need a Berkeley SPICE 3f4 compatible model for 6AK5 pentode or equivalents (EF95 - European, 6J1P - Russian, 6F32 - "TESLA").

Thank you!

[Robert McLean]

Here is a model for 6AK5 that I have developed. The data I have does not include control grid current, so the model is not accurate in that respect. Also, I dont know if this is 3F4 compatible or not, I have forgotten all the conversions. It works with LTSpice. If it is not 3F4 compatible, then some day I will do a translation, but not today.


*******************
*
* Pentode model based on my investigations
* see Excel spreadsheets BeamDLPentode.xls
*
*
* this model therefore uses Korens method for total current, and diode lines.
*
* similart to Pentode1, but with revised Capture Ratio formula
*
* R McLean 1 Apr 2008
*
*
************************
.Subckt 6AK5 A S G K
+ Params: Ex=1.919796584 Mug=28.62765031 Mus=5.93E+02 Kg1=1241.263033 Kp=87.71075724
+ Kvb=0.001045715 Go=-0.174882604 Kd=5.00E-02 Exd=1.018581504 Exsd=1.106610165
+ C1= -20.45944113 A1=-0.001923837 B1=20.33820425 X1=0.011665792 Y1= 0.000268033 Sr=0.032709138
+ Cgk=4P Cgs=.5P Cga=0.03P Cak=2.8P

* calculate the total space current based on Koren's triode equations,
* but with an equivalent triode plate volatage equal to the pentode Vs + Vp/Mus
En1 n1 0 VALUE={(V(A,K)/Mus+V(S,K))/Kp*LN(1+EXP(Kp*(1/Mug+(V(G,K)-Go)/SQRT(Kvb+(V(A,K)/Mus+V(S,K))**2))))}
Esc sc 0 VALUE={ (PWR(V(n1),Ex)+PWRS(V(n1), Ex))/(Kg1) }

* calculate the plate current capture ratio
Ecr cr 0 Value={If(V(A,K)<=0,0,C1+A1*V(A,K)+B1*((limit(V(A, G),1,1e6)**X1)/(limit(V(S,G),1,1e6)**Y1)))}

* the tentative plate current is total space current multiplied by capture ratio
Ept pt 0 Value={V(sc)*V(cr)}

* calculate the diode line current
Ed d 0 value={Kd*V(A,K)**Exd*V(S,K)**Exsd}

* the actual Plate current is the lesser of pt and d
Ep p 0 value={Min(V(d),V(pt))}
Ga A K value={V(p)}

* calculate the screen current capture ratio
* if Vg <= 0 then the screen gets all the remaining current, otherwise the grid gets some
Escr scr 0 value={Limit(if(V(G,K)>0,1-Sr*V(G,K),1),0,1)}

* screen current is anything not captured by the plate, multiplied by screen capture ratio
Esg sg 0 value={(V(sc)-V(p))*V(scr)}
Gs S K value={V(sg)}

* grid current is anything not captured by the plate or the screen
Gg G K value={V(sc)-v(p)-V(sg)}

* interelectrode capacitances
C1 G K {Cgk}
C2 G S {Cgs}
C3 G A {Cga}
C4 A K {Cak}
.ENDS 6AK5