6BX7 PSpice Model? - diyAudio
Go Back   Home > Forums > Amplifiers > Tubes / Valves

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 6th October 2007, 02:56 AM   #1
pftrvlr is offline pftrvlr  United States
diyAudio Member
 
Join Date: Feb 2007
Location: SoCal
Default 6BX7 PSpice Model?

Hi, I am looking for PSPice model for 6BX7. Or I can modify one from 6SN7 if I can get those numbers. It is a headphone amp project. I am planning to use it as CF output.

Thanks.
  Reply With Quote
Old 6th October 2007, 01:30 PM   #2
diyAudio Member
 
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Hello :
try this one

* 6BX7 - IDH medium-mu high-transconductance twin Bp A K I=(m)*uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters): mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*uramp(V(A,K)*ln(1.0+(-0.1116255831)+exp((3.282351583)+(3.282351583)*((12 .22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/(3.282351583))**(1.44441018)
.ends mk_6BX7


I do not remember where I got this model, I think it was from a thread here about how Koren's 5 parameter model could be improved with 6, 7 or 8 parameters.
__________________
Robert McLean
  Reply With Quote
Old 7th October 2007, 05:55 PM   #3
pftrvlr is offline pftrvlr  United States
diyAudio Member
 
Join Date: Feb 2007
Location: SoCal
Thanks Robet.

I copied the code into my Orcad Spice model and got this error

ERROR -- Line too long. Limit is 132 characters.

Any ideas?
  Reply With Quote
Old 8th October 2007, 02:17 PM   #4
diyAudio Member
 
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Default splitting up SPICE lines

Quote:
ERROR -- Line too long. Limit is 132 characters.
Sorry about that, I should have noticed when I posted the message that the lines had wrapped around, and were not continued correctly.

The method for splitting up SPICE lines is to use a "+" at the start of the next line. This marks it as the start of a continuation line. It can be a bit confusing ( to a human reader, not to spice) knowing if the + is a continuation sign, or a normal addition sign, so I put lots of spaces in to show it is a continuation

So here is the same code with shorter lines :

* 6BX7 - IDH medium-mu high-transconductance twin
* Bp A K I=(m)* uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters):
* mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*uramp(V(A,K)*ln(1.0+(-
+ 0.1116255831)+exp((3.282351583)+(3.282351583)*
+ ((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt
+ ((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/
+ (3.282351583))**(1.44441018)
.ends mk_6BX7


that should work now.

Interesting note : when I preview this message, the extra spaces I put in have disappeared. This wont affect how the model works.
__________________
Robert McLean
  Reply With Quote
Old 8th October 2007, 08:40 PM   #5
wa2ise is offline wa2ise  United States
diyAudio Member
 
wa2ise's Avatar
 
Join Date: Apr 2005
Location: NJ
Here's another:

* Generic triode model: 6BX7
* Copyright 2003--2006 by Ayumi Nakabayashi, All rights reserved.
* Version 3.01, Generated on Wed Mar 22 17:19:49 2006
.SUBCKT 6BX7 A G K
BGG GG 0 V=V(G,K)+0.99999999
BEP EP 0 V=URAMP(V(A,K))+1e-10
BEG EG 0 V=URAMP(V(G,K))+1e-10
BM1 M1 0 V=(0.044756942*(URAMP(V(EP)-1e-10)+1e-10))^-0.87869992
BM2 M2 0 V=(0.63059657*(URAMP(V(GG)+V(EP)/8.253545)+1e-10))^2.3786999
BP P 0 V=0.0032697035*(URAMP(V(GG)+V(EP)/13.088471)+1e-10)^1.5
BIK IK 0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0020437592*V(M1)*V(M2)
BIG IG 0 V=0.0016348517*V(EG)^1.5*(V(EG)/(V(EP)+V(EG))*1.2+0.4)
BIAK A K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0020166439*V(EP)^1.5)))+1e-10*V(A,K)
BIGK G K I=V(IG)
* CAPS
CGA G A 4.2p
CGK G K 4.8p
CAK A K 1.2p
.ENDS
  Reply With Quote
Old 11th October 2007, 04:10 AM   #6
pftrvlr is offline pftrvlr  United States
diyAudio Member
 
Join Date: Feb 2007
Location: SoCal
This time I got a different error:

**** EXPANSION OF SUBCIRCUIT X_VL1 ****
X_VL1.Cgp N731296 X_VL1.P 4.2p
X_VL1.Ci N731296 N604658 4.4p
X_VL1.Co N604270 N604658 1.1p
X_VL1.Bp N604270 N604658 X_VL1.I X_VL1.0.1001852541m *uramp
-----------------------------------------------------$
ERROR -- Invalid parameter

Is Orcad Spice different from what your guys use?
  Reply With Quote
Old 11th October 2007, 05:53 AM   #7
diyAudio Member
 
boB_K7IQ's Avatar
 
Join Date: Sep 2007
Location: Everett, WA
Send a message via Yahoo to boB_K7IQ
Quote:
Originally posted by pftrvlr
This time I got a different error:

**** EXPANSION OF SUBCIRCUIT X_VL1 ****
X_VL1.Cgp N731296 X_VL1.P 4.2p
X_VL1.Ci N731296 N604658 4.4p
X_VL1.Co N604270 N604658 1.1p
X_VL1.Bp N604270 N604658 X_VL1.I X_VL1.0.1001852541m *uramp
-----------------------------------------------------$
ERROR -- Invalid parameter
Is Orcad Spice different from what your guys use?

These errors look like they're from spice or orcad itself. Them's some big node numbers ! (Ex. N731296)

Are you starting from an example circuit ? If not, that might be easier.

boB
  Reply With Quote
Old 11th October 2007, 10:45 PM   #8
diyAudio Member
 
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Default Orcad PSpice

Orcad PSpice does not like the uramp function. So you need to rewrite the models slightly by replacing

uramp( blablabla )
with
limit( blablabla, 0, 1e16 )


Here is my model rewritten in PSpice

* 6BX7 - IDH medium-mu high-transconductance twin
* Bp A K I=(m)* uramp(()*V(G,K)+V(A,K))**1.5
* From GE 6BX7GT datasheet - traced on 19-01-04 by AF
.subckt mk_6BX7 A G K
Cgp G P 4.2p
Ci G K 4.4p
Co A K 1.1p
* Modified Koren model (8 parameters):
* mean fit error 0.573819 mA
Bp A K I=(0.1001852541m)*limit(V(A,K)*ln(1.0+(-
+ 0.1116255831)+exp((3.282351583)+(3.282351583)*
+ ((12.22538987)+(-24.13446294m)*V(G,K))*V(G,K)/sqrt
+ ((0.04128697397)**2+(V(A,K)-(-6.806029609))**2)))/
+ (3.282351583), 0, 1e16)**(1.44441018)
.ends mk_6BX7
__________________
Robert McLean
  Reply With Quote
Old 14th October 2007, 09:50 PM   #9
pftrvlr is offline pftrvlr  United States
diyAudio Member
 
Join Date: Feb 2007
Location: SoCal
Still could not get the model to work. So I modified the a simple 6SN7 to fit the 6BX7 curve. Here is what I have:

* Connections: Plate
* | Grid
* | | Cathode
* | | |
.SUBCKT 6BX7 A G K
E1 2 0 VALUE={V(A,K)+10.43*V(G,K)}
R1 2 0 1.0K
Gp A K VALUE={200.89E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G K 4.4P
Cgp G A 4.2P
Cpk A K 1.1P
Rak A K 1G
Rgi G X 2K
D3 X K dx
.model dx d(is=1n rs=1 cjo=0 tt=1n)
.ENDS 6BX7

I powered up the headphone amp and took some measurements. The quiescent point is close enough (actual Ip <5% lower) in a CF application.

I guess the more ciomplicated model will be closer?
  Reply With Quote

Reply


Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Similar Threads
Thread Thread Starter Forum Replies Last Post
pspice model of 811A billr Tubes / Valves 0 15th July 2007 06:47 AM
HIP4080A pspice model Anthony C Smith Class D 1 3rd January 2006 07:52 PM
PSpice Model for 2SJ201 ChocoHolic Solid State 7 25th October 2005 12:24 AM
PSpice model library - please help Evan Shultz Solid State 0 30th November 2004 07:28 PM
PSpice model for Outputtranformers Posthorn Tubes / Valves 1 31st July 2003 12:27 PM


New To Site? Need Help?

All times are GMT. The time now is 03:05 PM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2014 DragonByte Technologies Ltd.
Copyright 1999-2014 diyAudio

Content Relevant URLs by vBSEO 3.3.2