6V6 line preamp - diyAudio
Go Back   Home > Forums > Amplifiers > Tubes / Valves

Tubes / Valves All about our sweet vacuum tubes :) Threads about Musical Instrument Amps of all kinds should be in the Instruments & Amps forum

Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 23rd May 2007, 05:12 AM   #1
Salas is online now Salas  Greece
diyAudio Chief Moderator
 
Salas's Avatar
 
Join Date: Oct 2002
Location: Athens-Greece
Default 6V6 line preamp

Did anybody build or listen to a 6V6 triode connected line preamp? I think it may be interesting to build one since I have some NOS. Maybe SRPP.

Later full schematic
Cathode follower version
A recommended parallel regulator
A recommended series regulator
  Reply With Quote
Old 23rd May 2007, 05:38 AM   #2
diyAudio Member
 
Geek's Avatar
 
Join Date: Sep 2004
Hi,

I have a client that uses 6V6 in line amps. He loves them.

Sorry, I don't know make or have a schematic. Just passing the info along.

Cheers!
  Reply With Quote
Old 23rd May 2007, 06:58 AM   #3
Zen Mod is offline Zen Mod  Serbia
diyAudio Member
 
Zen Mod's Avatar
 
Join Date: Jan 2003
Location: ancient Batsch , behind Iron Curtain
Default Re: 6V6 line preamp

Quote:
Originally posted by salas
Did anybody build or listen to a 6V6 triode connected line preamp? I think it may be interesting to build one since I have some NOS. Maybe SRPP.

BudP have one in his preamp.....as CF , dunno is it triode
__________________
my Papa is smarter than your Nelson !
clean thread; Cook Book;PSM LS Cook Book;Baby DiyA ;Mighty ZM's Bloggg;Papatreasure;Papa... by Mighty ZM
  Reply With Quote
Old 23rd May 2007, 08:36 PM   #4
Salas is online now Salas  Greece
diyAudio Chief Moderator
 
Salas's Avatar
 
Join Date: Oct 2002
Location: Athens-Greece
Default Feasible then...

- The info that 6V6 is already used in line circuits with good results is positive. Thanks!

- Here is a basic circuit I came to graphically. Does anybody have a 6V6 model in some sim soft package? I sadly don't have it in my sims.

- If yes, lets see if the operating point and B+ are nice or there is better.
Attached Images
File Type: jpg 6v6line.jpg (61.5 KB, 12443 views)
  Reply With Quote
Old 23rd May 2007, 08:40 PM   #5
Zen Mod is offline Zen Mod  Serbia
diyAudio Member
 
Zen Mod's Avatar
 
Join Date: Jan 2003
Location: ancient Batsch , behind Iron Curtain
Default Re: Feasible then...

Quote:
Originally posted by salas
- The info that 6V6 is already used in line circuits with good results is positive. Thanks!

- Here is a basic circuit I came to graphically. Does anybody have a 6V6 model in some sim soft package? I sadly don't have it in my sims.

- If yes, lets see if the operating point and B+ are nice or there is better.

these simple tube circuit deserves that you learn graph-ruler-calculator routine.

you don't need sim for that ; or you'll never learn how tube works
__________________
my Papa is smarter than your Nelson !
clean thread; Cook Book;PSM LS Cook Book;Baby DiyA ;Mighty ZM's Bloggg;Papatreasure;Papa... by Mighty ZM
  Reply With Quote
Old 23rd May 2007, 08:57 PM   #6
Salas is online now Salas  Greece
diyAudio Chief Moderator
 
Salas's Avatar
 
Join Date: Oct 2002
Location: Athens-Greece
Default Re: Feasible then...

Quote:
Originally posted by salas

- Here is a basic circuit I came to graphically

I did already. But it would be nice to double check.

Cheers.
  Reply With Quote
Old 23rd May 2007, 09:06 PM   #7
Zen Mod is offline Zen Mod  Serbia
diyAudio Member
 
Zen Mod's Avatar
 
Join Date: Jan 2003
Location: ancient Batsch , behind Iron Curtain
Default Re: Re: Feasible then...

Quote:
Originally posted by salas



I did already. But it would be nice to double check.

Cheers.

ok-then you did already what sims can do just worse ;

double check with dvm and cro and whatever you have
__________________
my Papa is smarter than your Nelson !
clean thread; Cook Book;PSM LS Cook Book;Baby DiyA ;Mighty ZM's Bloggg;Papatreasure;Papa... by Mighty ZM
  Reply With Quote
Old 23rd May 2007, 09:25 PM   #8
Salas is online now Salas  Greece
diyAudio Chief Moderator
 
Salas's Avatar
 
Join Date: Oct 2002
Location: Athens-Greece
Default SRPP

Here is SRPP since I have 4 tubes available. Nice for an audio comparison between previous and this one.
Attached Images
File Type: jpg 6v6srpp.jpg (34.9 KB, 11724 views)
  Reply With Quote
Old 23rd May 2007, 09:55 PM   #9
diyAudio Member
 
Join Date: May 2005
Location: Stittsville, Ontario, Canada
Default 6V6 models

Quote:
Does anybody have a 6V6 model in some sim soft package?
Try these models. They work on LTSpice.

*
* 6V6 tube has same curves as 6AQ5
* capacitances are slightly different
*
.SUBCKT 6V6 A S G K
+ PARAMS: Vn=4.683375986 Exd=1.498943398 Kd=5.985681E-04 Mua=135.8092472 Mug=0.792313597 Mus=7.857142857 Kp=7.41E-04
+ Ks=0.7455 Ex=1.429346869
+ Cgk=9.0P Cgs=8.0P Cga=0.7P Cak=7.5P
Eat at 0 VALUE={limit(0.636*ATAN(V(A,K)/{Vn}),0,1e6)} ; arctangent shaping
Eme me 0 VALUE={PWR(LIMIT(V(A,K),0,2000),{Exd})*{Kd}} ; the diode line
Egs gs1 0 VALUE={LIMIT(V(A,K)/{Mua}+V(S,K)/{Mus}+V(G,K)/{Mug},0,1E6)} ;the basic voltage
Egs2 gs2 0 VALUE={PWRS(V(gs1),{Ex})*{Kp}} ;raise to the power and mult by perveance
Ecath cc 0 VALUE={LIMIT(V(gs2)*V(at),0,V(me))} ;shaped per Eat and the diode line
*
* Calculate anode current
*
Ga A K VALUE={V(cc)}
*
* Calculate screen current
*
Escrn sc 0 VALUE={{Ks}*V(gs2)*(1.1-V(at))}; reverse arctangent shaping
Gs S K VALUE={V(sc)}
*
* Grid current

R1 G 5 1K ; FOR GRID CURRENT
D3 5 K Dx ; FOR GRID CURRENT
.MODEL Dx D(IS=1N RS=1 CJO=10PF TT=1N)
* Capacitances
C1 G K {Cgk}
C2 G S {Cgs}
C3 G A {Cga}
C4 A K {Cak}
.ENDS 6V6



*********************
*
* 6V6
* 28 Nov 2004
* new model based on measurements
* parameters revised 29 Nov 2004
*
**********************
.subckt 6V6GT A S G K
XV1 A S G K Pentode2
+ PARAMS: Ex=1.41031468452635 Mug=11.7888046293233 Mus=36.3212284562041 Kg1=1084.30402294001 Kp=36.0452435978759
+ Kvb=899.32403046434 Go=-0.467417459629955 Kd=0.000106867654972877 Exd=1.26175320982325 Exsd=0.425953018509995
+ C1=-2.85604234699625 A1=-5.68835011136307E-05 B1=3.49035244298882 X1=0.015108363529097 Y1=0.00926342558705693 Sr=0.198544592645026
+ Cgk=9P Cgs=5P Cga=0.7P Cak=7.5P
.ends 6V6GT


*******************
*
*
* This model is for pentodes with remote cutoff grid characteristics and with
* knees that blend into a smooth line, ie a diode line, typical of Beam type tubes.
*
* this model therefore uses Korens method for total current, and diode lines.
*
* default parameters are for the 6V6
*
* RCM 2004 November 28
* 2004 Nov 29 revised capture ratio formula to correct problem when Vg > Vp or Vg > Vs
*
************************
.Subckt Pentode2 A S G K
+ Params: Ex=1.42596448566733 Mug=11.7822188645457 Mus=27.5137445137459 Kg1=1447.15506010676 Kp=36.3066403677756
+ Kvb=756.918578086785 Go=-0.557407825110845 Kd=0.000103636138847149 Exd=1.26335466904983 Exsd=0.431363489073363
+ C1= -0.940657929992395 A1=-0.000127738832949614 B1=1.72299135911867 X1=0.0345083152949822 Y1= 0.0177418846473534 Sr=0.0471284218217744
+ Cgk=9P Cgs=5P Cga=0.7P Cak=7.5P

* calculate the total space current based on Koren's triode equations,
* but with an equivalent triode plate volatage equal to the pentode Vs + Vp/Mus
En1 n1 0 VALUE={(V(A,K)/Mus+V(S,K))/Kp*LN(1+EXP(Kp*(1/Mug+(V(G,K)-Go)/SQRT(Kvb+(V(A,K)/Mus+V(S,K))**2))))}
Esc sc 0 VALUE={ (PWR(V(n1),Ex)+PWRS(V(n1), Ex))/(Kg1) }

* calculate the plate current capture ratio
Ecr cr 0 Value={If(V(A,K)<=0,0,C1+A1*V(A,K)+B1*((limit(V(A, G),1,1e6)**X1)/(limit(V(S,G),1,1e6)**Y1)))}

* the tentative plate current is total space current multiplied by capture ratio
Ept pt 0 Value={V(sc)*V(cr)}

* calculate the diode line current
Ed d 0 value={Kd*V(A,K)**Exd*V(S,K)**Exsd}

* the actual Plate current is the lesser of pt and d
Ep p 0 value={Min(V(d),V(pt))}
Ga A K value={V(p)}

* calculate the screen current capture ratio
* if Vg <= 0 then the screen gets all the remaining current, otherwise the grid gets some
Escr scr 0 value={Limit(if(V(G,K)>0,1-Sr*V(G,K),1),0,1)}

* screen current is anything not captured by the plate, multiplied by screen capture ratio
Esg sg 0 value={(V(sc)-V(p))*V(scr)}
Gs S K value={V(sg)}

* grid current is anything not captured by the plate or the screen
Gg G K value={V(sc)-v(p)-V(sg)}

* interelectrode capacitances
C1 G K {Cgk}
C2 G S {Cgs}
C3 G A {Cga}
C4 A K {Cak}
.ENDS Pentode2
__________________
Robert McLean
  Reply With Quote
Old 23rd May 2007, 10:06 PM   #10
Salas is online now Salas  Greece
diyAudio Chief Moderator
 
Salas's Avatar
 
Join Date: Oct 2002
Location: Athens-Greece
Thanks! I will see if they work in Circuit Maker.
  Reply With Quote

Reply


Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Similar Threads
Thread Thread Starter Forum Replies Last Post
Help me design my DAC/Line Preamp. kuroguy Tubes / Valves 7 2nd April 2009 08:31 PM
preamp line ctt richwalters Tubes / Valves 1 7th March 2008 04:34 PM
Preamp for Line In and Mic blur Instruments and Amps 1 4th January 2007 04:02 PM
Line stage preamp, based on SY's "Heretical Unity gain line stage" Danko Tubes / Valves 23 18th July 2005 04:07 AM
Line preamp for 2A3 amp Petman Tubes / Valves 0 24th May 2002 03:11 PM


New To Site? Need Help?

All times are GMT. The time now is 02:48 AM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2014 DragonByte Technologies Ltd.
Copyright 1999-2014 diyAudio

Content Relevant URLs by vBSEO 3.3.2