BUZ90x SPICE models

[teodorom]

Hi,
does anybody have the (P)SPICE models for the power mosfets BUZ900/901 and BUZ905/906 ?
Thanks

[Christer]

According to Charles Hanssen in an earlier thread both Magnatec and Exicon use exactly the same Semelab chips in their lateral MOSFETs, so the Exicon models should work fine.
http://www.diyaudio.com/forums/showt...238#post171238

[cs]

Here they are.
(I got the models directly from Magnatec).

.SUBCKT BUZ901D 1 2 3
* MODEL FORMAT: SPICE Level 1
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source

M1 9 7 8 8 MM L=0.001 W=0.001
* Default values used in M:
* The capacitances are added externally
* Other default values are:
* RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=0.362 LAMBDA=0.06 KP=3.097
RS 8 3 0.178
D1 8 9 MD
.MODEL MD D IS=1.0e-32 N=50 BV=250
+CJO=1.77e-9 VJ=0.1 M=0.28
RDS 8 9 1e+06
RD 9 1 0.265
RG 2 7 42
* Gate Source capacitance Cgs0
CAP1 7 8 900e-12
*************************
* Gate Drain capacitance Cdg0
CAP 7 4 18.7e-12
*************************
* Gate Drain Capacitance Cdgj0
* Modelled as a diode
D2 4 9 MDD
.MODEL MDD D IS=1e-32 N=50
+CJO=75e-12 VJ=0.1 M=0.768
*************************
.ENDS BUZ901D

.SUBCKT BUZ901P 1 2 3

* MODEL FORMAT: SPICE Level 1
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source

M1 9 7 8 8 MM L=0.001 W=0.001
* Default values used in M:
* The capacitances are added externally
* Other default values are:
* RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=0.473 LAMBDA=0.092 KP=1.585
RS 8 3 0.41
D1 8 9 MD
.MODEL MD D IS=1.0e-32 N=50 BV=250
+CJO=1.0e-9 VJ=0.7 M=0.5
RDS 8 9 1e+06
RD 9 1 0.58
RG 2 7 80
* Gate Source capacitance Cgs0
CAP1 7 8 400e-12
*************************
* Gate Drain capacitance Cdg0
CAP 7 4 10.5e-12
*************************
* Gate Drain Capacitance Cdgj0
* Modelled as a diode
D2 4 9 MDD
.MODEL MDD D IS=1e-32 N=50
+CJO=94.8e-12 VJ=0.3 M=1
*************************
.ENDS BUZ901P

.SUBCKT BUZ906d 1 2 3

* MODEL FORMAT: SPICE Level 1
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source

M1 9 7 8 8 MM L=0.001 W=0.001
* Default values used in M:
* The capacitances are added externally
* Other default values are:
* RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM PMOS LEVEL=1 IS=1e-32
+VTO=-0.273 LAMBDA=0.5 KP=0.548
RS 8 3 0.171
D1 9 8 MD
.MODEL MD D IS=1.0e-32 N=50 BV=250
+CJO=1e-9 VJ=0.7 M=0.5
RDS 8 9 1e+06
RD 9 1 0.259
RG 2 7 45
* Gate Source capacitance Cgs0
CAP1 7 8 1.08e-9
*************************
* Gate Drain capacitance Cdg0
CAP 7 4 36e-12
*************************
* Gate Drain Capacitance Cdgj0
* Modelled as double diode
D2 9 10 MDD
D3 4 10 MDD
.MODEL MDD D IS=1e-32 N=50
+CJO=762e-12 VJ=0.1 M=1
*************************
.ENDS BUZ906d

.SUBCKT BUZ906P 1 2 3
* MODEL FORMAT: SPICE Level 1
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source

M1 9 7 8 8 MM L=0.001 W=0.001
* Default values used in M:
* The capacitances are added externally
* Other default values are:
* RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM PMOS LEVEL=1 IS=1e-32
+VTO=-0.426 LAMBDA=0.073 KP=0.673
RS 8 3 0.342
D1 9 8 MD
.MODEL MD D IS=1.0e-32 N=50 BV=250
+CJO=1.45e-9 VJ=0.446 M=0.377
RDS 8 9 1e+06
RD 9 1 0.523
RG 2 7 45.2
* Gate Source capacitance Cgs0
CAP1 7 8 696e-12
*************************
* Gate Drain capacitance Cdg0
CAP 7 4 15.2e-12
*************************
* Gate Drain Capacitance Cdgj0
* Modelled as a diode
D2 9 4 MDD
.MODEL MDD D IS=1e-32 N=50
+CJO=27.6e-12 VJ=0.817 M=0.871
*************************
.ENDS BUZ906P

[teodorom]

... however I'm getting crazy in trying to make it work in Cadence ORCad PSPICE. I'm not really an expert of (P)SPICE.
Could you please give me some little help ?
Thank you

[Christer]

I don't know that particular version of Spice, but please not that the models are subcircuit models, not standard MOSFET models. I don't know what implications that has in your version of Spice, but if you search the forum there shoudl at least be info on how to use them in LTSpice, which may or may not help you.

[Ouroboros]

Those particular subcircuits are the ones I used with TINA and they compiled and ran perfectly. Be warned that there can be a very large device-to-device variation on BUZ90x devices (see the variation in threshold voltage shown on the data sheet) and these subcircuits don't accurately model this.

[Christer]

Originally posted by Ouroboros
Those particular subcircuits are the ones I used with TINA and they compiled and ran perfectly. Be warned that there can be a very large device-to-device variation on BUZ90x devices (see the variation in threshold voltage shown on the data sheet) and these subcircuits don't accurately model this.

No Spice models can handle device-to-device variations as far as I know. One simply has to use several model of the same device.

More precisely, when using subcircuits, it may be possible to vary some, but not most, parameters if using DC sweep analysis. But that is anyway only useful for Q points and similar.

[teodorom]

I succeeded in using the models you provided in PSPICE.
Thanks to all !