Spice models for Hitachi 2SK216 MOSFETs, and LM317

Bricolo · 2002-11-22 4:17 pm

Does anyone have those ones?

I've found this on the forum and the internet, but they all give me an error with PSPICE

So if anyone has working models, or can tell me how to make mine works, that'll be nice

2SK216

.MODEL M1Mod NMOS Level=1 AF=1 CBD=658P CBS=790P CGBO=852N
+ CGDO=22N CGSO=26.4N CJ=0 CJSW=0 FC=0.5 GAMMA=18.6 IS=250F
+ JS=0 KF=0 KP=80M LAMBDA=521U LD=0 MJ=.46 TOL=30% MJSW=0.5
+ NSS=0 NSUB=0 PB=.8 PHI=.75 RD=.84 RS=.84 RSH=0 TNOM=27
+ TOX=1E-7 TPG=1 UO=600 VTO=15

MODEL 2SK216 NMOS (VTO=-40.5279M KP=20U L=2U W=11.1026M
GAMMA=0 PHI=600M + LAMBDA=1.79284M RD=118.74 CBD=157.257P
CGSO=617.586P CGDO=617.586P TOX=0 + NSUB=0 TPG=1 UO=600
RG=15.7297 RDS=1MEG)

.SUBCKT LM317TI 1 2A 3
*CONNECTIONS INPUT ADJ. OUTPUT
*LM317 VOLTAGE REGULATOR - TI
VFIX 2A 2 .04
J1 1 3 4 JN
Q2 5 5 6 QPL .1
Q3 5 8 9 QNL .2
Q4 8 5 7 QPL .1
Q5 81 8 3 QNL .2
Q6 3 81 10 QPL .2
Q7 12 81 13 QNL .2
Q8 10 5 11 QPL .2
Q9 14 12 10 QPL .2
Q10 16 5 17 QPL .2
Q11 16 14 15 QNL .2
Q12 3 20 16 QPL .2
Q13 1 19 20 QNL .2
Q14 19 5 18 QPL .2
Q15 3 21 19 QPL .2
Q16 21 22 16 QPL .2
Q17 21 3 24 QNL .2
Q18 22 22 16 QPL .2
Q19 22 3 241 QNL 2
Q20 3 25 16 QPL .2
Q21 25 26 3 QNL .2
Q22A 35 35 1 QPL 2
Q22B 16 35 1 QPL 2
Q23 35 16 30 QNL 2
Q24A 27 40 29 QNL .2
Q24B 27 40 28 QNL .2
Q25 1 31 41 QNL 5
Q26 1 41 32 QNL 50
D1 3 4 DZ
D2 33 1 DZ
D3 29 34 DZ
R1 1 6 310
R2 1 7 310
R3 1 11 190
R4 1 17 82
R5 1 18 5.6K
R6 4 8 100K
R7 8 81 130
R8 10 12 12.4K
R9 9 3 180
R10 13 3 4.1K
R11 14 3 5.8K
R12 15 3 72
R13 20 3 5.1K
R14 2 24 12K
R15 24 241 2.4K
R16 16 25 6.7K
R17 16 40 12K
R18 30 41 130
R19 16 31 370
R20 26 27 13K
R21 27 40 400
R22 3 41 160
R23 33 34 18K
R24 28 29 160
R25 28 32 3
R26 32 3 .1
C1 21 3 30PF
C2 21 2 30PF
C3 25 26 5PF
CBS1 5 3 2PF
CBS2 35 3 1PF
CBS3 22 3 1PF
.MODEL JN NJF(BETA=1E-4 VTO=-7)
.MODEL DZ D(BV=6.3)
.MODEL QNL NPN(EG=1.22 BF=80
RB=100 CCS=1.5PF TF=.3NS TR=6NS
CJE=2PF
+ CJC=1PF VAF=100)
.MODEL QPL PNP(BF=40 RB=20 TF=.6NS
TR=10NS CJE=1.5PF CJC=1PF VAF=50)
.ENDS

Pedja · 2002-11-22 5:35 pm

LM317TI

Should work now.

.SUBCKT LM317TI 1 2A 3
*CONNECTIONS INPUT ADJ. OUTPUT
*LM317 VOLTAGE REGULATOR - TI
VFIX 2A 2 .04
J1 1 3 4 JN
Q2 5 5 6 QPL .1
Q3 5 8 9 QNL .2
Q4 8 5 7 QPL .1
Q5 81 8 3 QNL .2
Q6 3 81 10 QPL .2
Q7 12 81 13 QNL .2
Q8 10 5 11 QPL .2
Q9 14 12 10 QPL .2
Q10 16 5 17 QPL .2
Q11 16 14 15 QNL .2
Q12 3 20 16 QPL .2
Q13 1 19 20 QNL .2
Q14 19 5 18 QPL .2
Q15 3 21 19 QPL .2
Q16 21 22 16 QPL .2
Q17 21 3 24 QNL .2
Q18 22 22 16 QPL .2
Q19 22 3 241 QNL 2
Q20 3 25 16 QPL .2
Q21 25 26 3 QNL .2
Q22A 35 35 1 QPL 2
Q22B 16 35 1 QPL 2
Q23 35 16 30 QNL 2
Q24A 27 40 29 QNL .2
Q24B 27 40 28 QNL .2
Q25 1 31 41 QNL 5
Q26 1 41 32 QNL 50
D1 3 4 DZ
D2 33 1 DZ
D3 29 34 DZ
R1 1 6 310
R2 1 7 310
R3 1 11 190
R4 1 17 82
R5 1 18 5.6K
R6 4 8 100K
R7 8 81 130
R8 10 12 12.4K
R9 9 3 180
R10 13 3 4.1K
R11 14 3 5.8K
R12 15 3 72
R13 20 3 5.1K
R14 2 24 12K
R15 24 241 2.4K
R16 16 25 6.7K
R17 16 40 12K
R18 30 41 130
R19 16 31 370
R20 26 27 13K
R21 27 40 400
R22 3 41 160
R23 33 34 18K
R24 28 29 160
R25 28 32 3
R26 32 3 .1
C1 21 3 30PF
C2 21 2 30PF
C3 25 26 5PF
CBS1 5 3 2PF
CBS2 35 3 1PF
CBS3 22 3 1PF
.MODEL JN NJF(BETA=1E-4 VTO=-7)
.MODEL DZ D(BV=6.3)
.MODEL QNL NPN(EG=1.22 BF=80 RB=100 CCS=1.5PF TF=.3NS TR=6NS CJE=2PF
+ CJC=1PF VAF=100)
.MODEL QPL PNP(BF=40 RB=20 TF=.6NS TR=10NS CJE=1.5PF CJC=1PF VAF=50)
.ENDS

Pedja · 2002-11-22 6:25 pm

2SK216

This should work too. The point is when you have the parameters in the next line, you should have “+” at the start of the line. Or, if you don’t have a problems with the unwrapped lines, go with the whole model in one line and without “+”.Check again (I’m NOT using this model).

Also, one dot (“.”), added at the start.

.MODEL 2SK216 NMOS (VTO=-40.5279M KP=20U L=2U W=11.1026M GAMMA=0 PHI=600M
+ LAMBDA=1.79284M RD=118.74 CBD=157.257P CGSO=617.586P CGDO=617.586P TOX=0
+ NSUB=0 TPG=1 UO=600 RG=15.7297 RDS=1MEG)

Pedja

Bricolo · 2002-11-22 8:01 pm

"ERROR -- Model 216 used by M_Q1 is undefined "

jackinnj · 2002-11-22 9:30 pm

LM117HV Model from Multisim

IADJ 1 4 48.4U
VREF 4 3 1.2782
RC 1 14 0.742
DBK 14 13 DLM117HV__VOLTAGE_REGULATOR__1
CBC 13 15 2.479N
RBC 15 5 247
QP 13 5 2 QLM117HV__VOLTAGE_REGULATOR__1
RB2 6 5 124
DSC 6 11 DLM117HV__VOLTAGE_REGULATOR__1
ESC 11 2 POLY (2) (13,5) (6,5) 2.85
+ 0 0 0 -70.1M
DFB 6 12 DLM117HV__VOLTAGE_REGULATOR__1
EFB 12 2 POLY(2) (13,5) (6,5) 3.92
+ -135M 0 1.21M -70.1M
RB1 7 6 1
EB 7 2 8 2 2.56
CPZ 10 2 0.796U
DPU 10 2 DLM117HV__VOLTAGE_REGULATOR__1
RZ 8 10 .104
RP 9 8 100
EP 9 2 4 2 103.6
RI 2 4 100MEG
.MODEL QLM117HV__VOLTAGE_REGULATOR__1 NPN (IS=30F BF=50
+ VAF=14.27 NF=1.604)
.MODEL DLM117HV__VOLTAGE_REGULATOR__1 D (IS=30F N=1.604)

Bricolo · 2002-11-22 9:38 pm

ERROR -- Model QLM117HV__VOLTAGE_REGULATOR__1 used by Q_Q1 is undefined

:xeye:

Pjotr · 2002-11-22 9:45 pm

Hi Bricolo,

The dot is missing before the model statement. This will work:

.MODEL 2SK216 NMOS (Level=1
+ VTO=-40.5279M
+ KP=20U
+ L=2U
+ W=11.1026M
+ GAMMA=0
+ PHI=600M
+ LAMBDA=1.79284M
+ RD=118.74
+ CBD=157.257P
+ CGSO=617.586P
+ CGDO=617.586P
+ TOX=0
+ NSUB=0
+ TPG=1
+ UO=600
+ RG=15.7297
+ RDS=1MEG)

The other 2SK216 model is useless, it is far off the real curves. By the way where on the internet did you found it? I am also looking a long time for realistic models for this Hitachi mosfet’s and its sister part the 2SJ79 as well. Attached the transfer curve of the above model. It is realistic up to Id of 120 mA. It seems to me one fiddled it out by hand.

Bricolo · 2002-11-22 10:05 pm

always the same error in pspice :/

what am I doing wrong?

Pjotr · 2002-11-22 10:30 pm

Dunno,

Did you save it in a library that is known by your pspice program?
No typo errors?

By the way can you forward me the url of the sites where you found the fet models? Thanks.

Peter

Pedja · 2002-11-22 10:35 pm

Bricolo, no doubt, the models work. You have a problem with the program, not with models. I use MicroCap, not familiar with PSpice, but I guess you did not add these models the right way.

Btw Pjotr, the answer you gave was already here...

Pedja

Pjotr · 2002-11-22 10:54 pm

Oops sorry Pedja,

I overlooked it. :ashamed:

Bricolo · 2002-11-23 8:58 am

what the he** am I doing wrong?!

I just open pspice model editor, create a new model list, a new model into it, paste the text you gave me
I save the file, create the capture parts

and try to use this model in the shematic

then, when I want to run a simulation, I always get the same error :'(

UltimateX86 · 2005-04-24 10:19 pm

bricolo, c'est pour quel soft que tu cherchais cette lib de 2SK216 ?

je cherche le 2SJ79 et 2SK216 pour B2 SPICE

MERCI

Bricolo · 2005-04-24 11:50 pm

Normalement, un modele spice c'est universel

le 79 j'ai pas, pour le 216 j'ai utilise un des modeles donnés ici

Le probleme c'est que la version student de pspice accepte pas de modeles externes, j'utilise simetrix maintenant et tout marche tres bien

UltimateX86 · 2005-04-25 12:02 am

y a plusieur model donné ici .... tu as utilisé le quel ?

Bricolo · 2005-04-25 10:39 am

.MODEL 2SK216 NMOS (Level=1
+ Gamma=0
+ Tox=0
+ Uo=600
+ Phi=600M
+ KP=20U
+ L=2U
+ VTO=-40.5279M
+ RD=118.74
+ RDS=1MEG
+ CBD=157.257P
+ CGSO=617.586P
+ CGDO=617.586P
+ RG=15.7297
+ LAMBDA=1.79284M
+ NSUB=0
+ TPG=1
+ W=11.1026M
* Delta=
* Eta=
* Theta=
* Kappa=
* Vmax=
* Xj=
* Is=
* N=
* Tt=
* Pb=
* Mj=
* Fc=
* W=
* Rs=

Geoff · 2005-04-25 12:18 pm

Bricolo

Send me an email and I will foward my library of voltage regulator models which includes models for the LM317 from Nat Semi, Motorola and TI. I use these in SIMetrix Intro which requires Spice 2 or PSpice format so you may have more luck with getting them to work.

Geoff

Bricolo · 2005-04-25 10:13 pm

Hi Geoff, thanks for the offer

Is it too big to zip it and attach it here? I'm sure I'm not the only one who needs a 317 model.

BTW, does someone have an accurate TL431 model?

Geoff · 2005-04-25 11:45 pm

Bricolo

As I said, email me if you want the three LM317 models (plus others).

Have you searched for the TL431 model? It is/was available at TI's website:

*****************************************************************************
* TL431 MACROMODEL ***************3-26-92************************************
* REV N/A ****************************************************************DBB
*****************************************************************************
* REFERENCE
* | ANODE
* | | CATHODE
* | | |
.SUBCKT TL431 1 2 3
V1 6 7 DC 1.4V
I1 2 4 1E-3
R1 1 2 1.2E6
R2 4 2 RMOD 2.495E3
R3 5 7 .2
D1 3 6 DMOD1
D2 2 3 DMOD1
D3 2 7 DMOD2
E1 5 2 POLY(2) (4,2) (1,2) 0 710 -710
.MODEL RMOD RES (TC1=1.4E-5 TC2=-1E-6)
.MODEL DMOD1 D (RS=.3)
.MODEL DMOD2 D (RS=1E-6)
.ENDS

Geoff

Spice models for Hitachi 2SK216 MOSFETs, and LM317

Member

Member

Member

Member

Member

Member

Member

Attachments

Member

Member

Member

Member

Member

Member

Member

Member

Member

Member

Member

Member