Soft start pcb using a triac

[nigelwright7557]

Latest little project.
A triac based soft start pcb.
Uses a 8 pin PIC micro to read a thermistor for temp then outputs corresponding PWM to two fans.
Can power up to 2000 watts amps.
Ignore extra holes in heat sink, I forgot to use cutting oil when drilling and broke off the drill.

An externally hosted image should be here but it was not working when we last tested it.

An externally hosted image should be here but it was not working when we last tested it.

 

[AndrewT]

Uses a 8 pin PIC micro

where do we buy this ready to be soldered/socketed in?

 

[nigelwright7557]

where do we buy this ready to be soldered/socketed in?

Source code:

;INTH0.ASM
;**********
;INTERNAL OSC, INTERNAL MCLR, POWER UP TIMER ON

;
;ON POWER UP WAIT ONE SECOND
;IF MAINS IS THERE RAMP UP PHASE ANGLE UNTIL FULLY ON AND KEEP ON UNTIL MAINS FAILS



LIST R=DEC
LIST P=PIC12F508
;INCLUDE REGISTER DEFINITIONS
INCLUDE P12F508.INC



;_MCLRE_ON EQU H'0FFF'
;_MCLRE_OFF EQU H'0FEF'

;_CP_ON EQU H'0FF7'
;_CP_OFF EQU H'0FFF'

;_WDT_ON EQU H'0FFF'
;_WDT_OFF EQU H'0FFB'

;_LP_OSC EQU H'0FFC'
;_XT_OSC EQU H'0FFD'
;_IntRC_OSC EQU H'0FFE'
;_ExtRC_OSC EQU H'0FFF'



__CONFIG _MCLRE_OFF & _WDT_OFF & _CP_OFF & _IntRC_OSC

INCLUDE MACRO.ASM

;ACCESSES REGISTER BANK BIT
#DEFINE RB0 STATUS,5
;
#DEFINE TRIAC GPIO,0
#DEFINE SWITCH GPIO,1 ;
#DEFINE MAINS GPIO,2 ;
#DEFINE LED GPIO,5 ;


STATEA EQU 6
FIRSTA EQU 0


;***********************
FIRSTRAM EQU 7 ;JUST POINTER TO FIRST RAM LOCATION
DEL1 EQU 7
DEL2 EQU 8
WAITTIME EQU 9
LOOPCOUNT EQU 10
MAINSFLAG EQU 11
TIMEOUTL EQU 12
TIMEOUTH EQU 13
LASTMAINS EQU 14

LASTRAM EQU 1FH
;;;;;;;;;;;;;;;;;;;;;
ORG 0
MOVWF OSCCAL
MOVLW FIRSTA
MOVWF GPIO

CLRWDT

MOVLW STATEA
TRIS GPIO

MOVLW 0C0H ;WEAK PULL UPS OFF & WAKE UP ON PIN CHANGE OFF
OPTION


CALL WAIT1SEC ;LET POWER SUPPLY CAP CHARGE UP.

;;;;;;;;;;;;;;;;;;;;;;;


MLOOP BCF LED
BCF TRIAC

CALL WAITMAINSEDGETIMEOUT
BC MLOOP

MOVLW 8
MOVWF WAITTIME

LOOP1

CALL TOGGLELED

MOVLW 24
BTFSC SWITCH
MOVLW 48
MOVWF LOOPCOUNT

LOOP2
MOVF WAITTIME,W
CALL WAITWMS

CALL WAITMAINSEDGETIMEOUTZ ;WAIT MAINS EDGE WITH TIMEOUT WITH TRIAC ON
BC MLOOP

DECFSZ LOOPCOUNT,F
GOTO LOOP2

DECFSZ WAITTIME,F
GOTO LOOP1


RUNLOOP
BCF LED ;KEEP LED OFF TO SAVE POWER

CALL WAITMAINSEDGETIMEOUTZ ;WAIT MAINS EDGE WITH TIMEOUT WITH TRIAC ON
BNC RUNLOOP

GOTO MLOOP
;******************************
WAITMAINSEDGETIMEOUT
CLRF MAINSFLAG
MOVLW 4
BTFSC MAINS
MOVWF MAINSFLAG
;
MOVLW LOW 1071 ;15MS TIMEOUT
MOVWF TIMEOUTL
MOVLW HIGH 1071
MOVWF TIMEOUTH
WM1 MOVF GPIO,W ;14 US LOOP
ANDLW 4
XORWF MAINSFLAG,W
BNZ MAINSCHANGED

DEC16 TIMEOUTL ;(4US)
MOVF TIMEOUTL,W
IORWF TIMEOUTH,W
BNZ WM1

SETC
RETLW 0


MAINSCHANGED
CLRC

RETLW 0
;********************
;WAIT MAINS EDGE WITH TRIAC ON
WAITMAINSEDGETIMEOUTZ
CLRF MAINSFLAG
MOVLW 4
BTFSC MAINS
MOVWF MAINSFLAG
;
MOVLW LOW 1071 ;15MS TIMEOUT
MOVWF TIMEOUTL
MOVLW HIGH 1071
MOVWF TIMEOUTH
BSF TRIAC
WM1Z
MOVF GPIO,W ;14 US
ANDLW 4
XORWF MAINSFLAG,W
BNZ MAINSCHANGEDZ

DEC16 TIMEOUTL ;(4US)
MOVF TIMEOUTL,W
IORWF TIMEOUTH,W
BNZ WM1Z

BCF TRIAC
SETC
RETLW 0


MAINSCHANGEDZ
BCF TRIAC
CLRC
RETLW 0
;********************
WAIT1MS MOVLW 1
GOTO WAITWMS
MS250 MOVLW 250
;ALSO ENTERED HERE
WAITWMS MOVWF DEL1
MS MOVLW 249
MOVWF DEL2
DD NOP
DECFSZ DEL2,F
GOTO DD
DECFSZ DEL1,F
GOTO MS
RETLW 0
;***********************
WAIT1SEC
CALL MS250
CALL MS250
CALL MS250
GOTO MS250
;*************************
TEST
BSF RB0
MOVLW 0
MOVWF GPIO
BCF RB0

TEST1
CLRWDT
MOVLW 0
MOVWF GPIO
MOVLW 255
MOVWF GPIO
GOTO TEST1
;***********************
WAIT100US
MOVLW 25
MOVWF DEL2
DD100 NOP
DECFSZ DEL2,F
GOTO DD100
RETLW 0
;**********************
TOGGLELED BTFSC LED
GOTO WAS1
WAS0 BSF LED
RETLW 0
WAS1 BCF LED
RETLW 0
;**********************


END

 

[Mooly]

Have you tried this for real on a large toroid for example ?

My (admittedly limited) experiments on trying triac control with a large inductive load failed with frequently spectacular exploding fuses as the triac created asymmetry and consequent high magnetic remanence in the core resulting in massive sudden current flow. The growling and noises from the toroid were impressive though.

 

[nigelwright7557]

The triac doesn't increase the phase angle all the time, it ramps it up slowly to stop asymmetry.
As long as the positive and negative phase angles are the same there shouldn't be a problem.

 

[Mooly]

I didn't use a PIC, mine was all done in the analogue domain, so as long as it works reliably then that's great, all Kudos to you

Just be sure its foolproof, time after time after time, restarts, mains glitches and so.