Spice models

[FBJ]

Thanks for the jfet spice models.
But would anyone happen to have any mosfet spice models. Like the Hitachi mosfets-2sj162 and 2sk1058. I went to the Hitachi web site but I didn't see anything about spice models.

[JoeBob]

What I want to know, is where do you guys get your models? I've also been looking for ZTX450 and ZTX550 models everywhere with no luck.

[HarryHaller]

*ZETEX ZTX450 Spice model Last revision 4/90
*
.MODEL ZTX450 NPN IS =3.941445E-14 BF =175 VAF=109.45 NF =1 IKF=.8
+ISE=7.4025E-15 NE =1.3 BR =20.5 VAR=14.25 NR =.974 IKR=.1 ISC=3.157E-13
+NC =1.2 RB =1.1 RE =.1259 RC =.0539 CJE=63E-12 TF =.75E-9 CJC=15.8E-12
+TR =85E-9 VJC=.505 MJC=.39
*
*ZETEX ZTX550 Spice model Last revision 24/7/01
*
.MODEL ZTX550 PNP IS =3.2E-14 BF =170 VAF=45 NF =0.977 IKF=1.25 ISE=7E-15
+NE =1.35 BR =50 VAR=50 NR =.986 IKR=0.15 ISC=0.9E-14 NC =1.08 RB =0.16
+RE =0.195 RC =0.185 CJE=104E-12 TF =0.7E-9 CJC=30.5E-12 TR =3E-9 VJC=0.395
+MJC=0.415

http://www.zetex.com/3.0/spice/zmodels.lib

10 minutes, started on www.altavista.com search for Zetex. Seach for spice on zetex site got menu with Applications and then menu with Spice models. Where did you look?

H.H.

[JoeBob]

I searched google for ZTX450 and spice, found nothing. I tried searching the Zetex website, yet got errors when I pressed the search button. I also tried another search engine and the only hits I got were "Buy SPICE model library for $XX USD here!".

Thanks though Harry.

[FBJ]

Any HELP for me Harry?

[HarryHaller]

*SRC=2SK1058;MSK1058;MOSFETs N;Power >100V;160V 7A
*SYM=POWMOSN
.SUBCKT MSK1058 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm N-Channel Power MOSFET 08-06-1993
M1 1 2 3 3 DMOS L=1U W=1U
RD 100 1 80.4M
RS 30 3 5.28M
RG 20 2 21.4
CGS 2 3 410P
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 128P
R1 13 0 1
D1 12 13 DLIM
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 100 DSUB
LS 30 40 7.5N
LD 10 100 4N
.MODEL DMOS NMOS (LEVEL=3 THETA=85M VMAX=163K ETA=2.2M VTO=.2 KP=.999)
.MODEL DCGD D (CJO=128P VJ=.6 M=.68)
.MODEL DSUB D (IS=29N N=1.5 RS=61.4M BV=160 CJO=802P VJ=.8 M=.42 TT=252N)
.MODEL DLIM D (IS=100U)
.ENDS


*SRC=2SJ162;MSJ162;MOSFETs P;Power >100V;160V 7A
*SYM=POWMOSP
.SUBCKT MSJ162 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm P-Channel Power MOSFET 08-06-1993
M1 1 2 3 3 DMOS L=1U W=1U
RD 100 1 110.4M
RS 30 3 25.28M
RG 20 2 17.4
CGS 2 3 760P
EGD 12 0 1 2 1
VFB 14 0 0
FFB 1 2 VFB 1
CGD 13 14 467P
R1 13 0 1
D1 12 13 DLIM
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 100 3 DSUB
LS 30 40 7.5N
LD 10 100 4N
.MODEL DMOS PMOS (LEVEL=3 THETA=90M VMAX=183K ETA=6.5M VTO=-.2 KP=1.109)
.MODEL DCGD D (CJO=467P VJ=.6 M=.68)
.MODEL DSUB D (IS=29N N=1.5 RS=61.4M BV=160 CJO=900P VJ=.8 M=.42 TT=252N)
.MODEL DLIM D (IS=100U)
.ENDS

*SRC=2SJ50;MSJ50;MOSFETs P;Power >100V;160V 7A
*SYM=POWMOSP
.SUBCKT MSJ50 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm P-Channel Power MOSFET 08-07-1993
M1 1 2 3 3 DMOS L=1U W=1U
RD 10 1 80.4M
RS 30 3 5.28M
RG 20 2 15.4
CGS 2 3 860P
EGD 12 0 1 2 1
VFB 14 0 0
FFB 1 2 VFB 1
CGD 13 14 513P
R1 13 0 1
D1 12 13 DLIM
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 10 3 DSUB
LS 30 40 7.5N
.MODEL DMOS PMOS (LEVEL=3 THETA=60M VMAX=533K ETA=5.5M VTO=-.34 KP=.599)
.MODEL DCGD D (CJO=513P VJ=.6 M=.68)
.MODEL DSUB D (IS=29N N=1.5 RS=61.4M BV=160 CJO=1.12N VJ=.8 M=.42 TT=252N)
.MODEL DLIM D (IS=100U)
.ENDS

*SRC=2SK135;MSK135;MOSFETs N;Power >100V;160V 7A
*SYM=POWMOSN
.SUBCKT MSK135 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm N-Channel Power MOSFET 08-07-1993
M1 1 2 3 3 DMOS L=1U W=1U
RD 100 1 80.4M
RS 30 3 5.28M
RG 20 2 21.4
CGS 2 3 590P
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 128P
R1 13 0 1
D1 12 13 DLIM
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 100 DSUB
LS 30 40 12.5N
LD 10 100 5N
.MODEL DMOS NMOS (LEVEL=3 THETA=80M VMAX=233K ETA=2M VTO=.25 KP=.817)
.MODEL DCGD D (CJO=128P VJ=.6 M=.68)
.MODEL DSUB D (IS=29N N=1.5 RS=61.4M BV=160 CJO=1.46N VJ=.8 M=.42 TT=252N)
.MODEL DLIM D (IS=100U)
.ENDS

[FBJ]

Thank you very MUCH, HarryHaller.

[Aud_Mot]

JoeBob,

I am in the same situation. I had my wife call Toshiba in Japan (she is Japanese) and ask for thier SPICE models. They would supply them to me, ONLY if I promised not to share them. I wouldn't and they didn't.

I have to belive that The Japanese use SPICE and they must have models for thier own devices, but I couldn't get my hands on any of them.

To any Japanese people out there reading this forum: HELP!

One possible solution: IF you can find a cross reference of Japanese to American (western) standard part numbers. EG: a 2SC2240 = a 2Nxxxx. (or MJxxxx, TIPxx, etc) Then use the western model for your simulation. Any reliable cross reference should be close enough to use for a SPICE simulation.

You can get the Specs (in .pdf files form) for all the Japanese part numbers off the Toshiba web site.

Another possible solution: SPICE, Practical Device Modeling by Ron Kielkowski. Make sure you ge a copy with the diskette. Then create your own devices models.

Good Luck and let me know if you get a solution.

Aud_Mot

[HarryHaller]

http://www.magnatec-uk.co.uk/mosdata.shtml