BF862 LTspice model?

[rhythmsandy]

Is this good?

*
* MODIFIED BF862 SPICE MODEL 7.8.2014
*
.MODEL BF862U NJF
+ VTO = -0.75
+ BETA = 0.033
+ LAMBDA = 0.033
+ RD = 0.8
+ RS = 7.0
+ CGS = 8p
+ CGD = 7.5p
+ PB = 0.5
+ FC = 0.5
+ KF = 87.5E-18
+ AF = 1
+ M = 0.6
*

 

[vzaichenko]

The one I've got is taken from NXP web site:

* BF862 SPICE MODEL MARCH 2007 NXP SEMICONDUCTORS
* ENVELOPE SOT23
* JBF862: 1, Drain, 2,Gate, 3,Source
.SUBCKT BF862 1 2 3
Ld 1 4 L= 1.1nH
Ls 3 6 L= 1.25nH
Lg 2 5 L= 0.78nH
Rg 5 7 R= 0.535 Ohm
Cds 1 3 C= 0.0001pF
Cgs 2 3 C= 1.05pF
Cgd 1 2 C= 0.201pF
Co 4 6 C= 0.35092pF
Q1 4 7 6 JBF862
.model JBF862 NJF(Beta=47.800E-3 Betatce=-.5 Rd=.8 Rs=7.5000 Lambda=37.300E-3 Vto=-.57093
+ Vtotc=-2.0000E-3 Is=424.60E-12 Isr=2.995p N=1 Nr=2 Xti=3 Alpha=-1.0000E-3
+ Vk=59.97 Cgd=7.4002E-12 M=.6015 Pb=.5 Fc=.5 Cgs=8.2890E-12 Kf=87.5E-18
+ Af=1)
.ENDS BF862

>BF862 SPICE MODEL<

Cheers,
Valery

 

[greenm01]

LTSPICE BF862

The one I've got is taken from NXP web site

I keep getting an error with the NXP model:

"Missing model value for Q:j1a:1"

Any ideas?

Regards,
Mason

 

[cxk]

Fixed BF862 model for LTSpice

I keep getting an error with the NXP model:

"Missing model value for Q:j1a:1"

I got the same error with LTSpice. Because this thread is one of the few that comes up for this issue, I'd like to share how I fixed that:
The problem is with NXP's model file using lines like

Rg 5 7 R= 0.535 Ohm

instead of

Rg 5 7 0.535Ohm

Additionally, LTSpice does not like a JFET Model referenced with a Transistor designator starting with Q.
The complete model file with the changes looks like this (no values have been changed):

*   BF862 SPICE MODEL MARCH 2007 NXP SEMICONDUCTORS
*   ENVELOPE    SOT23
*   JBF862: 1, Drain,  2,Gate,  3,Source
.SUBCKT BF862 1 2 3
  Ld  1 4   1.1nH
  Ls  3 6   1.25nH
  Lg  2 5   0.78nH
  Rg  5 7   0.535Ohm
  Cds 1 3   0.0001pF
  Cgs 2 3   1.05pF
  Cgd 1 2   0.201pF
  Co  4 6   0.35092pF
  J1  4 7 6 JBF862
  
.model JBF862 NJF(Beta=47.800E-3 Betatce=-.5 Rd=.8 Rs=7.5000 Lambda=37.300E-3 Vto=-.57093
+ Vtotc=-2.0000E-3 Is=424.60E-12 Isr=2.995p N=1 Nr=2 Xti=3 Alpha=-1.0000E-3
+ Vk=59.97 Cgd=7.4002E-12 M=.6015 Pb=.5 Fc=.5 Cgs=8.2890E-12 Kf=87.5E-18
+ Af=1)
.ENDS BF862

* END OF MODELLING

Hope this helps someone to figure it out a bit faster than it took me...
Regards,
Chris

 

[AndrewT]

Cxk, nice bit of detective work.
Thanks.

Can Cds really be as low as 0.0001pF?

Why do we need the .model values and the .subcircuit?

 

[cxk]

Can Cds really be as low as 0.0001pF?
Why do we need the .model values and the .subcircuit?

While probably only someone from NXP can definitely answer that, it seems that they "added" the effects of the SOT23 package through the .SUBCKT to the core transistor model (perhaps measured on the die without package). The transistor is aimed at RF circuits (car audio), so package parameters could be important for that application. They also have s-parameters available for this part.
Whether the package parameters matter depends on your application. However, since it is pretty easy to use the subcircuit instead of the model I would just use the manufacturer library as it is.

As for Cds, keep in mind that this is also in parallel to the series of Cgd and Cgs. Perhaps they just needed some very small value, as the effect was already modeled with Cgd, Cgs. But I'm no expert at this, maybe someone else can shed some more light onto that.

I cannot comment on the quality on the model, but I would prefer a manufacturer's model over one where the source is unknown. There might be some decent 3rd party libraries with even better models, but they tend to charge you for that quality.

Regards,
Chris

 

[Mark Johnson]

... it seems that they "added" the effects of the SOT23 package through the .SUBCKT to the core transistor model (perhaps measured on the die without package). The transistor is aimed at RF circuits (car audio), so package parameters could be important for that application.

Yes that's correct. The main value-add when you bother to construct a modeling .SUBCKT, is to include the series inductances, for which there are no user adjustable modeling parameters in the .MODEL equations. While they were at it they included several other package and bondwire parasitics, including gate resistance and pin capacitances.

 

[AndrewT]

If they went to the bother and cost of working out the package parasitics, then that may indicate that the device model was accurate enough to make that effort worthwhile.
I'd like to suggest that this subcircuit+model should be reliable for audio medeling, but I know next to nothing about LTspice.

 

[john_ellis]

The transistor is designed for RF applications, which means that parasitic inductances in the package are very likely to be important. One of the reasons the small outline packages have displaced TO-5 for RF (apart from other general industry-wide obsolescence) is that the bond wires are much shorter, and so parasitic inductances less. The Cds may be a figure obtained from the pin spacing on the package for example.

 

[Mark Johnson]

The Cds may be a figure obtained from the pin spacing on the package for example.

More likely, the junior engineer who prepared the .SUBCKT, performed copy-and-paste from another NXP product's .SUBCKT and then modified the numerical values. Perhaps her instructions were to do exactly this -- so that all single discrete FET .SUBCKTs would look the same, making it easier for senior engineers to eyeball many of them in a short time, and call out the ones that seem fishy.

 

[scott wurcer]

I got the same error with LTSpice. Because this thread is one of the few that comes up for this issue, I'd like to share how I fixed that:
The problem is with NXP's model file using lines like

instead of


Additionally, LTSpice does not like a JFET Model referenced with a Transistor designator starting with Q.
The complete model file with the changes looks like this (no values have been changed):

*   BF862 SPICE MODEL MARCH 2007 NXP SEMICONDUCTORS
*   ENVELOPE    SOT23
*   JBF862: 1, Drain,  2,Gate,  3,Source
.SUBCKT BF862 1 2 3
  Ld  1 4   1.1nH
  Ls  3 6   1.25nH
  Lg  2 5   0.78nH
  Rg  5 7   0.535Ohm
  Cds 1 3   0.0001pF
  Cgs 2 3   1.05pF
  Cgd 1 2   0.201pF
  Co  4 6   0.35092pF
  J1  4 7 6 JBF862
  
.model JBF862 NJF(Beta=47.800E-3 Betatce=-.5 Rd=.8 Rs=7.5000 Lambda=37.300E-3 Vto=-.57093
+ Vtotc=-2.0000E-3 Is=424.60E-12 Isr=2.995p N=1 Nr=2 Xti=3 Alpha=-1.0000E-3
+ Vk=59.97 Cgd=7.4002E-12 M=.6015 Pb=.5 Fc=.5 Cgs=8.2890E-12 Kf=87.5E-18
+ Af=1)
.ENDS BF862

* END OF MODELLING

Hope this helps someone to figure it out a bit faster than it took me...
Regards,
Chris

Yes this is a SOT23 package overlaid on the BF862. Package parasitics have no voltage or temperature coefficients to speak off so they must be outside the semiconductor model. The C's inside will have the usual ~V^1/3 power voltage coefficient.

This is a level 1 model and good for only the very basic behavior, it will not model distortion from Vds variation particularly well.

 

[jborden]

Yes this is a SOT23 package overlaid on the BF862. Package parasitics have no voltage or temperature coefficients to speak off so they must be outside the semiconductor model. The C's inside will have the usual ~V^1/3 power voltage coefficient.

This is a level 1 model and good for only the very basic behavior, it will not model distortion from Vds variation particularly well.

Is there a better model available?

 

[Mark Johnson]

This is a level 1 model and good for only the very basic behavior, it will not model distortion from Vds variation particularly well.

Is there a better model available?

Level 1 is the Schichmann-Hodges model, which has a terribly non-physical, but very easy to calculate, behavior in the pentode region where Vds is large: its I-V curve is a perfect straight line. I simulated the BF862 JFET in LTSPICE, which uses a Level 1 model. Results are shown below; click on the figure to see it full size.

30 minutes of internet searching leads me to conclude that LTSPICE, TINA-TI, and PSPICE only offer this one model for JFETs. The unbelievably expensive competitor program HSPICE does include a Level 2 model for JFETs, which improves modeling accuracy in the pentode region and in the subthreshold region. But HSPICE costs hundreds of thousands of dollars. And after you buy HSPICE you get to fit its model parameters yourself, because nobody else has done this yet on the BF862.

 

[spookydd]

I recall discussions on other threads about putting together some kind of repository of confirmed valid models.

I've been thinking about this again, as I was attempting to make up little test rigs for various types of parts, and verify some models against their datasheet.

Wouldn't it be nice to have a forum reserved for this? Where we could all share on the best test rigs to use and then test and verify models, to then post them all in the same place where they could be shared.
People could test the models as thoroughly as possible, and as more have verified those models, once posted, they could be deemed valid.

Many are using small libraries already fairly well verified, such as the one from our revered guru Cordell, and others, and the library could grow and be there to be found easily in a centralized place.

Plus some people are well versed in the inner workings of those models and are capable of tweaking them to better fit the datasheets.
This would allow more models to become better and verified, before being "officially" confirmed good.

Many models are floating around that aren't so good, but could perhaps become much better after tweaking, and standard test rigs could help verify proper model compliance.

Sharing the test rigs can allow sharing the work, so many models could be verified and become known good, if many people do this.

How about that?