diyAudio

diyAudio (http://www.diyaudio.com/forums/)
-   Software Tools (http://www.diyaudio.com/forums/software-tools/)
-   -   LTSpice tube models (http://www.diyaudio.com/forums/software-tools/224965-ltspice-tube-models.html)

Osvaldo de Banfield 4th December 2012 01:21 PM

LTSpice tube models
 
Hi all friend here!.

I want to know if any of you have the following tube models or know where can I find them. In the Norman Kohen they aren't and Google didn't give any answer.
They are:

ECF801 - EC900 - EF184 - EF183

Many Thanks to all.

Best Regards.

cogsncogs 4th December 2012 02:58 PM

tubemodel_3.01_win.zip

EF184 would be 6EJ7 in the above zip.

EC900/6HA5

* 6HA5 LTSpice model
* Koren model (5 parameters): mean fit error 1.27016mA
* Traced by Wayne Clay on 9/6/07 using Curve Captor v0.9
* from GE datasheet
.subckt 6HA5 P G K
Bp P K I=
+ (0.0007088605362m)*uramp(V(P,K)*ln(1.0+exp((0.0105 0076569)+
+ (0.01050076569)*(16410.47684)*V(G,K)/sqrt((7.516756983k)+
+ (V(P,K))**2)))/(0.01050076569))**(1.177167506)
Cgp G P 0.56p ; 0.2p added
Cgk G K 5p ; 0.7p added
Cpk P K 3.1p ; 0.2p added
.ends 6HA5

Osvaldo de Banfield 4th December 2012 03:25 PM

Many thanks, boy!!!:hohoho:

cogsncogs 4th December 2012 03:26 PM

Here's more 6ha5 models:
http://www.diyaudio.com/forums/tubes...lar-tubes.html

cogsncogs 4th December 2012 03:32 PM

6HM5

Code:

* 6HM5_k8 LTSpice model
.subckt 6HM5_k8  P G K
    Bp  P K  I=(0.001154846006m)*uramp(V(P,K)*ln(1.0+(-0.0008415623491)+exp((0.05049252985)+(0.05049252985)*((5446.000628)+(178663.8165m)*V(G,K))*V(G,K)/sqrt((-0.2140185688)**2+(V(P,K)-(-162.56846))**2)))/(0.05049252985))**(1.356125726)
.ends 6HM5_k8

Code:

* 6HM5 LTSpice model
* Koren model (5 parameters): mean fit error 1.20978mA
* Traced by Wayne Clay on 9/9-07 using Curve Captor v0.9
* from GE datasheet
.subckt 6HM5-k5  P G K
    Bp  P K  I=
+ (0.0005835219273m)*uramp(V(P,K)*ln(1.0+exp((0.005618954395)+
+ (0.005618954395)*(31322.45425)*V(G,K)/sqrt((8.885069314k)+
+ (V(P,K))**2)))/(0.005618954395))**(1.124019828)
  Cgp G P 0.54p ; 0.2p added
  Cgk G K 5.2p ; 0.7p added
  Cpk P K 3.2p ; 0.2p added
.ends 6HM5-k5


Osvaldo de Banfield 4th December 2012 03:35 PM

Ok, thanks again!!. Do you know any model for pentagrid tubes? (for make a audio compressor/expander) such as a 6BE6,6CS6, ECH83? Hot to manage two input signals? And for a 6BN6??? (very difficult I believe)

cogsncogs 4th December 2012 04:14 PM

I don't have any good ones for those tubes. Here's 6BE6 and 6CS6 models that use an op-amp symbol. To use 3f4 in LTSpice you may have to change ^ to **.

Code:

*Vacuum Tube pentagrid  (sharp cutoff)
.SUBCKT X6CS6close G 3 S K A
*model written to use op-amp symbol +in=g1,-in=g3, +supply=g2g4, -supply=kg5, out=plate
*work in progress, not final
* Calculate contribution to cathode current
*
*the number at the right end determines sharpness of knee
Bat    at  0    V=0.636*ATAN(V(A,K)/8)
*the URAMP(V(S,K)/# mostly determines peak plate current, grid line spacing nearly constant
*the number at the right end determines slope of grid lines (plate resistance)
Bgs    gs  0    V=URAMP(V(S,K)*1.6164+V(G,K)*24.75+V(A,K)/9000)
Bgss    gss  0    V=URAMP(V(S,K)*0.0005+V(3,K)*0.0075+V(A,K)/9000)
*the exponent sets the linearity of grid line spacing, and big impact on peak plate currrent
Bgs2    gs2 0    V=V(gs)^1.5
Bgs3    gs3 0    V=V(gss)^1.5
Bcath    cc  0    V=V(gs2)*V(at)
Ban          an  0        V=V(gs2)*V(at)*(V(gs3))
*
* Calculate anode current, grid line spacing adjust and peak plate current
*
Ba    A  K    I=0.345E-3*V(an)
*
* Calculate screen current
*
Bscrn    sc  0    V=V(gs2)*(1.0-V(at))
Bs    S  K    I=(URAMP(0.64E-3*V(sc)-(1.45E-3*(V(an)))))*0.29*(V(at))
*
* Grid current (approximation - does not model low va/vs)
*
Bg    G  K    I=(URAMP(V(G,K)+1)^1.5)*50E-6
*
* Capacitances
*
Cg1    G    K    5.5p
Cak    A    K    7.5p
Cg3          3              S              7p
Cg1g3      G            3              0.36p
Cg1a    G    A    0.07p

.ENDS X6CS6close


*****************************

Code:

*Vacuum Tube pentagrid (g3 remote cutoff)
.SUBCKT X6BE6close G 3 S K A
*model written to use op-amp symbol +in=g1,-in=g3, +supply=g2g4, -supply=kg5, out=plate
*work in progress, not final
* Calculate contribution to cathode current
*
*the number at the right end determines sharpness of knee
Bat    at  0    V=0.636*ATAN(V(A,K)/8)
*the URAMP(V(S,K)/# mostly determines peak plate current, grid line spacing nearly constant
*the number at the right end determines slope of grid lines (plate resistance)
Bgs    gs  0    V=URAMP(V(S,K)*1.6164+V(G,K)*24.75+V(A,K)/9000)
Bgss    gss  0    V=URAMP(V(S,K)*0.0005+V(3,K)*0.0045+V(A,K)/9000)
*the exponent sets the linearity of grid line spacing, and big impact on peak plate currrent
Bgs2    gs2 0    V=V(gs)^1.5
Bgs3    gs3 0    V=V(gss)^2.7
Bcath    cc  0    V=V(gs2)*V(at)
Ban          an  0        V=V(gs2)*V(at)*(V(gs3))
*
* Calculate anode current, grid line spacing adjust and peak plate current
*
Ba    A  K    I=0.345E-2*V(an)
*
* Calculate screen current
*
Bscrn    sc  0    V=V(gs2)*(1.0-V(at))
Bs    S  K    I=(URAMP(2.34E-4*V(sc)-(0.95E-2*(V(an)))))*0.29*(V(at))
*
* Grid current (approximation - does not model low va/vs)
*
Bg    G  K    I=(URAMP(V(G,K)+1)^1.5)*50E-6
*
* Capacitances
*
Cg1    G    K    3p
Cak    A    K    8p
Cg3          3              S              7p
Cg1g3      G            3              0.15p
Cg1a    G    A    0.1p

.ENDS X6BE6close

***************************************


Osvaldo de Banfield 4th December 2012 05:08 PM

Hey, what a master! Thank you once.

Osvaldo de Banfield 5th December 2012 11:48 AM

Has anybody the model for 6gj7/ecf801?

Thank you.

cogsncogs 6th December 2012 04:06 PM

1 Attachment(s)
Hi Osvaldo, try this in LTSpice. It has the 6HM5 model I posted in this thread. When you use the model be sure the name of the subckt matches the name/value of the component and the inc file you place on the schematic.

Wayne ;)


All times are GMT. The time now is 03:17 AM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2014 DragonByte Technologies Ltd.
Copyright 1999-2014 diyAudio


Content Relevant URLs by vBSEO 3.3.2