Go Back   Home > Forums > Amplifiers > Power Supplies

Please consider donating to help us continue to serve you.

Ads on/off / Custom Title / More PMs / More album space / Advanced printing & mass image saving
Reply
 
Thread Tools Search this Thread
Old 17th January 2006, 03:37 PM   #1
DaBit is offline DaBit  Netherlands
diyAudio Member
 
Join Date: Aug 2005
Send a message via ICQ to DaBit
Default Designing transformer leakage inductance

That HID ballast is the ultimate opportunity to play around with some SMPS topologies.

I had the ballast going using a push-pull switch-mode current source and a H-bridge for feeding the bulb AC current. Now, that is a very straightforward architecture, but unfortunatly is is also quite bulky. UCC28085-based current-mode push-pull, bridge rectifier, inductor, capacitor, current source inner feedback loop, H-bridge, H-bridge control and finally the outer loop which steers the current source depending on the lamp warmup status. And then the igniter, of course. Quite hard to get all that into a very small package, even if the control logic is mounted on vertical PCB's and the power logic on the horizontal carrier.


Much, much simpler is a resonant scheme:

Click the image to open in full size.

The resonant tank is formed by the leakage inductance (primary and secondary tranformed to primary) and capacitor.

This can be made to work under ZVS and it can generate the high voltage pulses by lowering the switching frequency. For example: here is a LTSpice simulation with an 1:16 transformer with a leakage inductance of 500nH (and ~6uH magnetizing inductance, which would equal 3 primary turns on an ETD34, N87 ferrite), a 220nF capacitor and a 120 Ohm load on the transformer secondary. Switching frequency is 285kHz with 50% duty cycle.

Click the image to open in full size.

My fingers are itching to try this, but I have no idea how I can design a transformer for a certain leakage inductance. How to do this? I can increase leakage inductance by simply adding more space between primary and secondary, but I have no idea what a doubling of the distance does to the magnetizing inductance, and how to calculate it's magnitude.

If this cannot be calculated easily, I guess I can also use a small inductance (air-core inductor?) in series with the transformer, right?
  Reply With Quote
Old 17th January 2006, 04:44 PM   #2
Eva is offline Eva  Spain
diyAudio Member
 
Eva's Avatar
 
Join Date: Oct 2003
Location: Near the sea
Send a message via MSN to Eva
The easiest way to get it is to add an inductor in series with the secondary winding, or maybe even with the primary. However, note that I've tried a similar approach (push-pull actually) to light and dim compact fluorescent lamps directly from 12V without additional switching stages, and the major drawback that I've found is very high peak currents (up to 15A peak to light a 23W lamp!!).
  Reply With Quote
Old 17th January 2006, 05:51 PM   #3
DaBit is offline DaBit  Netherlands
diyAudio Member
 
Join Date: Aug 2005
Send a message via ICQ to DaBit
Quote:
Originally posted by Eva
[B]The easiest way to get it is to add an inductor in series with the secondary winding, or maybe even with the primary.
OK, that seems the easiest way anyway.

Quote:
However, note that I've tried a similar approach (push-pull actually) to light and dim compact fluorescent lamps directly from 12V without additional switching stages, and the major drawback that I've found is very high peak currents (up to 15A peak to light a 23W lamp!!).
Do you know why? The simulation results show a peak drain current of somewhat less than 24A. Not too bad, considering the output power of 90W or so. I have used the IRF540NS model for the MOSFET and a somewhat less ideal model for the transformer (Lm, Lleak, wire resistance). The capacitor is perfect since I lack decent capacitor models.

The entire simulation is based on rough calculations and fiddling a bit instead of proper calculations. I suppose it can be better, but I wanted to get a feel for these things first.

How would I see the push-pull variant of this resonant thing? Standard push-pull with two switches pulling the ends of a center-tapped primary to ground, the center tap conencted to +V, and a capacitor between the ends of the center-tapped primary?
  Reply With Quote
Old 17th January 2006, 08:08 PM   #4
DaBit is offline DaBit  Netherlands
diyAudio Member
 
Join Date: Aug 2005
Send a message via ICQ to DaBit
A friend of mine generated a transformer using Magnetics Designer. I specified ETD29 geometry with 1mm gap (I happen to have such a core lying around), Epcos N87 material, 7 primary turns and 112 secondary turns. It seems that Magnetics Designer is capable of calculating leakage inductance since it shows up in the SPICE file he sent me. I have no idea what else he used for input.

Then, I tuned the inductor at the secondary side in SPICE. 82uH seems to work nicely.

Waveforms look like the screenshot above. Looks like it might be able to work.

(Lt)SPICE file. I have included the IRF540 subckt (although it is not the most suitable MOSFET) and transformer subckt so the file is standalone in case anyone is interested:

Code:
* ZVS ballast test

.SUBCKT irf540ns 1 2 3
M1 9 7 8 8 MM L=100u W=100u
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=3.55958 LAMBDA=0.000888191 KP=28.379
+CGSO=1.23576e-05 CGDO=1.77276e-08
RS 8 3 0.0251193
D1 3 1 MD
.MODEL MD D IS=1.13149e-09 RS=0.0078863 N=1.32265 BV=100
+IBV=0.00025 EG=1.17475 XTI=3.00167 TT=0
+CJO=7.95433e-10 VJ=0.5 M=0.374991 FC=0.5
RDS 3 1 4e+06
RD 9 1 0.00623556
RG 2 7 4.10175
D2 4 5 MD1
.MODEL MD1 D IS=1e-32 N=50
+CJO=1.75616e-09 VJ=0.513551 M=0.614054 FC=1e-08
D3 0 5 MD2
.MODEL MD2 D IS=1e-10 N=0.40002 RS=3e-06
RL 5 10 1
FI2 7 9 VFI2 -1
VFI2 4 0 0
EV16 10 0 9 7 1
CAP 11 10 3.86673e-09
FI1 7 9 VFI1 -1
VFI1 11 6 0
RCAP 6 10 1
D4 0 6 MD3
.MODEL MD3 D IS=1e-10 N=0.40002
.ENDS


.SUBCKT trafo 1 2 3 4
** ** ** **
** ** ** **
Rdc1	N41	N61	3.572m
Lmag	N41	2	6.217u
Rac1	N61	1	75.46m
Lac1	N61	1	26.79n
** ** ** **
L12	N41	in2	143.9n
C1_2	in2	2	-4.175n
C2_23	2	4	23.85p
C3_23	2	N42	65.18p
Efwd2	N82	4	in2	2	16.00
Vsens2	N82	N42	
Ffbk2	in2	2	Vsens2	16.00
Rdc2	N42	N62	1.398
Rac2	N62	3	31.25
Lac2	N62	3	10.53u
.ENDS 

V1   N12V   0         12 Rser=0.001
V2   gd_br  0         PULSE(0 12 0 30n 30n 1.75u 3.5u)
R1   gd_br  mosgate        10
XQ1  mosdrain     mosgate    0   irf540ns
Cr   mosdrain     0         220n
Lrp  mosdrain     trafopri  1f
Xtr1 trafopri     N12V trafo_sec 0 trafo
Lrs   trafo_sec     vlamp 82u
R2   vlamp     N12V      120

.tran 50u
.backanno
.end
Sorry for no schematic; I prefer to write these small things in text. Faster than drawing.
  Reply With Quote

Reply


Hide this!Advertise here!
Thread Tools Search this Thread
Search this Thread:

Advanced Search

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Similar Threads
Thread Thread Starter Forum Replies Last Post
How to measure leakage inductance percy Power Supplies 17 29th August 2008 09:57 PM
Audio Transformer Inductance Question kelticwizard Everything Else 1 9th April 2007 05:28 AM
Transformer saturation & leakage Lucius Planars & Exotics 8 8th April 2007 08:14 PM
Power Transformer leakage audio_moksha Tubes / Valves 22 9th March 2007 10:12 PM
Designing Transformer-Coupled Circuits... korneluk Tubes / Valves 0 14th December 2006 12:38 AM


New To Site? Need Help?

All times are GMT. The time now is 05:14 PM.


vBulletin Optimisation provided by vB Optimise (Pro) - vBulletin Mods & Addons Copyright © 2014 DragonByte Technologies Ltd.
Copyright 1999-2014 diyAudio

Content Relevant URLs by vBSEO 3.3.2