Need help regarding soft start

anatech · 2016-11-01 5:19 pm

Hi Andrew,
That's why I use an MOV across the transformer primary windings. Even just this part will extend the life of power switches quite a lot. It eliminates the turn-off arc.

Hi Nigel,
I've seen plenty of burned out power switches through time, but in my personal experience, not even one power switch replacement when there is a soft start circuit. Maybe things are different at 230 VAC? Lower current, but maybe a bigger turn-off wallop?

-Chris

AndrewT · 2016-11-02 9:17 am

I have not tried the MOV at the transformer.
I see you mention it a few times in posts.

I will try it on my Mains powered equipment. If it saves just one switch replacement, then it pays for itself.

All we need now are the subjectivists telling us how great their amplifiers sound with this modification !

anatech · 2016-11-02 6:38 pm

Hi Andrew,
Normally it doesn't conduct, so its out of circuit. Only when you have a voltage surge will it operate. So make sure the MOV you select isn't too close to the operating mains voltage. I used to use a 130 VAC MOV here. Now that is very close to the operating voltages in North America. When I was installing them the AC voltage was running about 117 volts (measured). I think the next firing voltage would be 150 VDC for me. You're lucky that the 240 VAC customers have dropped to 230 VAC. I wonder if people who were at 220 VAC had any problems once 230 VAC was standardized?

Anyway Andrew, I think you'll like having the MOV in there if you have any equipment that goes "snap" at turnoff. I do know that customers that got the MOV early in my career didn't require new power switches when a lot of the equipment did (Marantz).

-Chris

Mooly · 2016-11-02 8:03 pm

For UK mains you need a 275 vac device of 'high Joules' rating. These things are cheap to, around £0.50

This is from the Epcos range.

anatech · 2016-11-03 12:27 am

Hi Mooly,
Thanks for looking that up.

-Chris

tauro0221 · 2016-11-03 1:47 am

Hi,
Another advantage by ramping the AC on power ON/OFF like Nigel mentioned it is that you will reduces the inrush current to a minimum. I do the same thing using a micro to minimizes the inrush current . No need of resistors, MOV or relays. It is a simple circuit when you use a micro.

nigelwright7557 · 2016-11-03 1:51 am

Here is the circuit.
Basic power supply of mains.
PIC to control triac.
Mains reference input.
Opto-isolator to drive triac gate.
The code is pretty simple for the pic.

An externally hosted image should be here but it was not working when we last tested it.

anatech · 2016-11-03 1:53 am

Hi tauro0221,

No need of resistors, MOV or relays. It is a simple circuit when you use a micro.

How is that supposed to work? Not unless you're using the built in soft start of a switching regulator ...

-Chris

anatech · 2016-11-03 1:55 am

Nigel,
Is that directly connected to the mains?

-Chris

nigelwright7557 · 2016-11-03 2:03 am

anatech said:
Nigel,
Is that directly connected to the mains?

-Chris

Yes.
It doesnt need to be isolated as its not connected to the secondary side.

The PIC basically just waits for mains zero crossing and slow ramps up the phase angle until triac is on for full cycle.

PIC code:

;INTERNAL OSC, INTERNAL MCLR, POWER UP TIMER ON

;
;ON POWER UP WAIT ONE SECOND
;IF MAINS IS THER RAMP UP PHASE ANGLE UNTIL FULLY ON AND KEEP ON UNTIL MAISN FAILS

LIST R=DEC
LIST P=PIC12F508
;INCLUDE REGISTER DEFINITIONS
INCLUDE P12F508.INC

;_MCLRE_ON EQU H'0FFF'
;_MCLRE_OFF EQU H'0FEF'

;_CP_ON EQU H'0FF7'
;_CP_OFF EQU H'0FFF'

;_WDT_ON EQU H'0FFF'
;_WDT_OFF EQU H'0FFB'

;_LP_OSC EQU H'0FFC'
;_XT_OSC EQU H'0FFD'
;_IntRC_OSC EQU H'0FFE'
;_ExtRC_OSC EQU H'0FFF'

__CONFIG _MCLRE_OFF & _WDT_OFF & _CP_OFF & _IntRC_OSC

INCLUDE MACRO.ASM

;ACCESSES REGISTER BANK BIT
#DEFINE RB0 STATUS,5
;
#DEFINE TRIAC GPIO,0
#DEFINE SWITCH GPIO,1 ;
#DEFINE MAINS GPIO,2 ;
#DEFINE LED GPIO,5 ;

STATEA EQU 6
FIRSTA EQU 0

;***********************
FIRSTRAM EQU 7 ;JUST POINTER TO FIRST RAM LOCATION
DEL1 EQU 7
DEL2 EQU 8
WAITTIME EQU 9
LOOPCOUNT EQU 10
MAINSFLAG EQU 11
TIMEOUTL EQU 12
TIMEOUTH EQU 13
LASTMAINS EQU 14

LASTRAM EQU 1FH
;;;;;;;;;;;;;;;;;;;;;
ORG 0
MOVWF OSCCAL
MOVLW FIRSTA
MOVWF GPIO

CLRWDT

MOVLW STATEA
TRIS GPIO

MOVLW 0C0H ;WEAK PULL UPS OFF & WAKE UP ON PIN CHANGE OFF
OPTION

CALL WAIT1SEC ;LET POWER SUPPLY CAP CHARGE UP.

;;;;;;;;;;;;;;;;;;;;;;;

MLOOP BCF LED
BCF TRIAC

CALL WAITMAINSEDGETIMEOUT
BC MLOOP

MOVLW 8
MOVWF WAITTIME

LOOP1

CALL TOGGLELED

MOVLW 25
BTFSC SWITCH
MOVLW 50
MOVWF LOOPCOUNT

LOOP2
MOVF WAITTIME,W
CALL WAITWMS

CALL WAITMAINSEDGETIMEOUTZ ;WAIT MAINS EDGE WITH TIMEOUT WITH TRIAC ON
BC MLOOP

DECFSZ LOOPCOUNT,F
GOTO LOOP2

DECFSZ WAITTIME,F
GOTO LOOP1

RUNLOOP
BCF LED ;KEEP LED OFF TO SAVE POWER

CALL WAITMAINSEDGETIMEOUTZ ;WAIT MAINS EDGE WITH TIMEOUT WITH TRIAC ON
BNC RUNLOOP

GOTO MLOOP
;******************************
WAITMAINSEDGETIMEOUT
CLRF MAINSFLAG
MOVLW 4
BTFSC MAINS
MOVWF MAINSFLAG
;
MOVLW LOW 1071 ;15MS TIMEOUT
MOVWF TIMEOUTL
MOVLW HIGH 1071
MOVWF TIMEOUTH
WM1 MOVF GPIO,W ;14 US LOOP
ANDLW 4
XORWF MAINSFLAG,W
BNZ MAINSCHANGED

DEC16 TIMEOUTL ;(4US)
MOVF TIMEOUTL,W
IORWF TIMEOUTH,W
BNZ WM1

SETC
RETLW 0

MAINSCHANGED
CLRC

RETLW 0
;********************
;WAIT MAINS EDGE WITH TRIAC ON
WAITMAINSEDGETIMEOUTZ
CLRF MAINSFLAG
MOVLW 4
BTFSC MAINS
MOVWF MAINSFLAG
;
MOVLW LOW 1071 ;15MS TIMEOUT
MOVWF TIMEOUTL
MOVLW HIGH 1071
MOVWF TIMEOUTH
BSF TRIAC
WM1Z
MOVF GPIO,W ;14 US
ANDLW 4
XORWF MAINSFLAG,W
BNZ MAINSCHANGEDZ

DEC16 TIMEOUTL ;(4US)
MOVF TIMEOUTL,W
IORWF TIMEOUTH,W
BNZ WM1Z

BCF TRIAC
SETC
RETLW 0

MAINSCHANGEDZ
BCF TRIAC
CLRC
RETLW 0
;********************
WAIT1MS MOVLW 1
GOTO WAITWMS
MS250 MOVLW 250
;ALSO ENTERED HERE
WAITWMS MOVWF DEL1
MS MOVLW 249
MOVWF DEL2
DD NOP
DECFSZ DEL2,F
GOTO DD
DECFSZ DEL1,F
GOTO MS
RETLW 0
;***********************
WAIT1SEC
CALL MS250
CALL MS250
CALL MS250
GOTO MS250
;*************************
TEST
BSF RB0
MOVLW 0
MOVWF GPIO
BCF RB0

TEST1
CLRWDT
MOVLW 0
MOVWF GPIO
MOVLW 255
MOVWF GPIO
GOTO TEST1
;***********************
WAIT100US
MOVLW 25
MOVWF DEL2
DD100 NOP
DECFSZ DEL2,F
GOTO DD100
RETLW 0
;**********************
TOGGLELED BTFSC LED
GOTO WAS1
WAS0 BSF LED
RETLW 0
WAS1 BCF LED
RETLW 0
;**********************

END

anatech · 2016-11-03 2:08 am

Hi Nigel,
Many thanks! Cool little circuit.

The one problem I have run into is that the triac must fire exactly the same on each positive or negative cycle or you will have high, high current draw from the effective DC.

-Chris

nigelwright7557 · 2016-11-03 2:11 am

anatech said:
Hi Nigel,

The one problem I have run into is that the triac must fire exactly the same on each positive or negative cycle or you will have high, high current draw from the effective DC.

-Chris

Yes DC will upset the transformer.
The PIC outputs same pulse to positive and negative cycles but then increases phase angle on each loop.

The main downside of the system is you need a heat sink for the triac.
The more the VA of the transformer the bigger heat sink is required.
When I was testing it I used a 2Kwatt room heater.

anatech · 2016-11-03 2:13 am

Hi Nigel,
That makes perfect sense. Is the turn-off sudden? If so, a Varistor across the transformer primary might be a good idea.

-Chris

nigelwright7557 · 2016-11-03 2:16 am

The PIC will see the mains reference signal has gone and immediately stop outputting pulses to the triac. So it will turn off at zero crossing.

tauro0221 · 2016-11-03 2:39 am

Hi,
To Nigel Do you fire the triac only at the zero crossing or you ramp the ac at various angle of the AC? That it is the way I do. I slowly ramp the AC on power ON/OFF.

nigelwright7557 · 2016-11-03 2:45 am

It starts off firing towards end of cycle and slowly moves back so the triac is more on as time goes on.
Once the power up cycle is over the triac is permanently on.

This means there is a little EMI on power up but after power up cycle the transformer is permanently powered.

gannaji · 2016-11-03 5:15 am

tauro0221 said:
Hi,
To Nigel Do you fire the triac only at the zero crossing or you ramp the ac at various angle of the AC? That it is the way I do. I slowly ramp the AC on power ON/OFF.

Please can you provide details as Nigel has done, like a circuit diagram etc.?

Need help regarding soft start

Administrator

R.I.P.

Administrator

Administrator

Attachments

Administrator

Member

Member

Administrator

Administrator

Member

Administrator

Member

Administrator

Member

Member

Member

Member